[gentoo-commits] repo/gentoo:master commit in: dev-python/aiohttp/

[Michał Górny]

commit:     c1f77173a669ce9d8f1b0daf9895639a271764a0
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sat Sep  7 06:34:20 2019 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sat Sep  7 06:37:53 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c1f77173

dev-python/aiohttp: Bump to 3.6.0

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/aiohttp/Manifest             |  1 +
 dev-python/aiohttp/aiohttp-3.6.0.ebuild | 80 +++++++++++++++++++++++++++++++++
 2 files changed, 81 insertions(+)

diff --git a/dev-python/aiohttp/Manifest b/dev-python/aiohttp/Manifest
index 65bba973f49..66c1600d99e 100644
--- a/dev-python/aiohttp/Manifest
+++ b/dev-python/aiohttp/Manifest
@@ -1,2 +1,3 @@
 DIST aiohttp-2.3.10.tar.gz 848324 BLAKE2B c32a7be3f3d9ba0bd1308c5bea779a10e177b9c018a03fb3cf95d1a1392180f3b4ea294dc23e2e946cc1065d16d212a169ec262a79034ae94b3a5067fbaf362c SHA512 e4ea725bbd3d7d749f2ec21eea1ff9f5c836fbeaa17ad72f77e378c69b008448e57503175bee6adff86110f65edc915cb6368df3011d1d9d61cf47718b086be0
 DIST aiohttp-3.5.4.tar.gz 1097647 BLAKE2B 27d3631cf33cc5052deecfeca23f6c052fce344d9a889b0c0c0e68d9dcc19eb56e2ef2496f025c795dea4f906a59ae579ecd489188f8c56bc41255b4f450f4bf SHA512 9bc31457029f7db5bbfe1e213c1f428bf90ac96d83b6d2c8838261a3910ab9f7632a4299618377acb1bed04b0cbb4b4f6d9ee814495c05f210ed9bb4f4c61714
+DIST aiohttp-3.6.0.tar.gz 1110800 BLAKE2B 30c583c5d9079dcc3481b917b51c09e40572228a2df3acab468036f22a75fbb21963805bc37d353c82cc81fddc6da85e9ae9fa6b4a0eb0c305de5428f48a05b2 SHA512 90a0c55b5f20fc7cc14d138fca93206a7b64ac069fbd81c77b5373985236c0c09b44bd167be58129ce2e4f2bdefe59891d6d52938f9fe04c462d4aea6af67d9d

diff --git a/dev-python/aiohttp/aiohttp-3.6.0.ebuild b/dev-python/aiohttp/aiohttp-3.6.0.ebuild
new file mode 100644
index 00000000000..069ceaa8985
--- /dev/null
+++ b/dev-python/aiohttp/aiohttp-3.6.0.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{5,6,7} )
+
+inherit distutils-r1
+
+DESCRIPTION="http client/server for asyncio"
+HOMEPAGE="https://pypi.org/project/aiohttp/"
+SRC_URI="mirror://pypi/${P:0:1}/${PN}/${P}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="doc test"
+RESTRICT="!test? ( test )"
+
+CDEPEND="
+	>=dev-python/async_timeout-3.0.0[${PYTHON_USEDEP}]
+	>=dev-python/attrs-17.3.0[${PYTHON_USEDEP}]
+	dev-python/chardet[${PYTHON_USEDEP}]
+	>=dev-python/multidict-4.0.0[${PYTHON_USEDEP}]
+	>=dev-python/yarl-1.0[${PYTHON_USEDEP}]
+	dev-python/idna-ssl[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep 'dev-python/typing-extensions[${PYTHON_USEDEP}]' \
+		python3_{5,6})
+"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-python/cython[${PYTHON_USEDEP}]
+	doc? (
+		>=dev-python/alabaster-0.6.2[${PYTHON_USEDEP}]
+		dev-python/sphinxcontrib-asyncio[${PYTHON_USEDEP}]
+		dev-python/sphinxcontrib-blockdiag[${PYTHON_USEDEP}]
+		dev-python/sphinxcontrib-newsfeed[${PYTHON_USEDEP}]
+		dev-python/sphinxcontrib-spelling[${PYTHON_USEDEP}]
+		dev-python/sphinx[${PYTHON_USEDEP}]
+		dev-python/sphinx-aiohttp-theme[${PYTHON_USEDEP}]
+	)
+	test? (
+		${CDEPEND}
+		dev-python/async_generator[${PYTHON_USEDEP}]
+		dev-python/brotlipy[${PYTHON_USEDEP}]
+		>=dev-python/pytest-3.4.0[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/pytest-timeout[${PYTHON_USEDEP}]
+		dev-python/trustme[${PYTHON_USEDEP}]
+		www-servers/gunicorn[${PYTHON_USEDEP}]
+	)
+"
+RDEPEND="${CDEPEND}"
+
+DOCS=( CHANGES.rst CONTRIBUTING.rst CONTRIBUTORS.txt HISTORY.rst README.rst )
+
+python_prepare_all() {
+	# FIXME
+	rm tests/test_pytest_plugin.py || die
+	sed -i -e 's:test_testcase_no_app:_&:' tests/test_test_utils.py || die
+
+	# remove pointless dep on pytest-cov
+	sed -i -e '/addopts/s/--cov=aiohttp//' pytest.ini || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	pytest -vv || die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+
+	distutils-r1_python_install_all
+}