[gentoo-commits] repo/gentoo:master commit in: sys-apps/fwupd/

[Lars Wendler]

commit:     455b4ba53f531f90991c87b5c0ffd71b278ece1e
Author:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
AuthorDate: Mon Apr 27 11:35:57 2020 +0000
Commit:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
CommitDate: Mon Apr 27 11:57:20 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=455b4ba5

sys-apps/fwupd: Bump to version 1.4.1

Package-Manager: Portage-2.3.99, Repoman-2.3.22
Signed-off-by: Lars Wendler <polynomial-c <AT> gentoo.org>

 sys-apps/fwupd/Manifest           |   1 +
 sys-apps/fwupd/fwupd-1.4.1.ebuild | 158 ++++++++++++++++++++++++++++++++++++++
 2 files changed, 159 insertions(+)

diff --git a/sys-apps/fwupd/Manifest b/sys-apps/fwupd/Manifest
index e5a784b78a0..16de0d90cbf 100644
--- a/sys-apps/fwupd/Manifest
+++ b/sys-apps/fwupd/Manifest
@@ -1,3 +1,4 @@
 DIST fwupd-1.2.11.tar.gz 1945646 BLAKE2B 4eb6d5008d0e515880147a94b2632ed70b5f7ab1891775ac121347653c06bf4403ab7f4a1fe160000a6195d360fe06d64c8971dd53c1538aeac40d155f59979a SHA512 a8d6a76ac59937547c6866d414e95a67779574901b0a15ecfde763f49b434b284be2ade1194179225785006e5f93836667469d08f32d4c87fc85927aa0bfe9de
 DIST fwupd-1.3.8.tar.gz 2246170 BLAKE2B b55df322c64947bcccc7bf05daaec2c5b2f646a4e53d757482dcd4d33e94d725315e6456bf69d5dbca3ef870437e1cc2a861537fc7af9b059497f119f08477de SHA512 0f0aa380adc5e167e49db4261b50bee9c905786afcd44b5fe221f42a77306219d40888989e0b16448535eaf077baed12de56b6cca42f91fca09c4a8384f243e4
 DIST fwupd-1.3.9.tar.gz 2254260 BLAKE2B ead64be3eca00fd2d045fb6c5ccd42d8913fa056736e6ae039feef70b6edababe50fb0552db39bf057750d3f0d2224b18b7ecf5a5a408a1f1ac3023d89687f68 SHA512 b81ef1f683082e4c49ab8acd8848118fed1383d4e3e73967daaa68927e553a5bc4973004d3dd26b268b901c5deb1f9238a98537d24cfd957162f508c9622e1e4
+DIST fwupd-1.4.1.tar.gz 2301866 BLAKE2B 057c7cdc4449aa67540719e6b7b1f073e8b247aa80dd99cb4b1c4ebf7c368c5089ddc25200bb0a42706196e3025c21a5d09f5f507d52e5c0fc5fc6d5c1eacd46 SHA512 abec0c2d66bd7e256cefa5e0ce59bbf339ea2ffb6173671c7f6cf8893b0931c16c48c47153507bc1af3f31157dba8bddf566bba1b62b8a722fa1f50780a1f921

diff --git a/sys-apps/fwupd/fwupd-1.4.1.ebuild b/sys-apps/fwupd/fwupd-1.4.1.ebuild
new file mode 100644
index 00000000000..eef144460fc
--- /dev/null
+++ b/sys-apps/fwupd/fwupd-1.4.1.ebuild
@@ -0,0 +1,158 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+
+inherit linux-info meson python-single-r1 vala xdg toolchain-funcs
+
+DESCRIPTION="Aims to make updating firmware on Linux automatic, safe and reliable"
+HOMEPAGE="https://fwupd.org"
+SRC_URI="https://github.com/hughsie/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="agent amt consolekit dell gtk-doc elogind minimal introspection +man nvme redfish synaptics systemd test thunderbolt tpm uefi"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}
+	^^ ( consolekit elogind minimal systemd )
+	dell? ( uefi )
+	minimal? ( !introspection )
+"
+RESTRICT="!test? ( test )"
+
+BDEPEND="$(vala_depend)
+	virtual/pkgconfig
+	gtk-doc? ( dev-util/gtk-doc )
+	introspection? ( dev-libs/gobject-introspection )
+	man? (
+		app-text/docbook-sgml-utils
+		sys-apps/help2man
+	)
+	test? (
+		thunderbolt? ( dev-util/umockdev )
+		net-libs/gnutls[tools]
+	)
+"
+DEPEND="${PYTHON_DEPS}
+	>=app-arch/gcab-1.0
+	app-arch/libarchive:=
+	dev-db/sqlite
+	>=dev-libs/glib-2.45.8:2
+	dev-libs/json-glib
+	dev-libs/libgpg-error
+	dev-libs/libgudev:=
+	>=dev-libs/libgusb-0.2.9[introspection?]
+	>=dev-libs/libjcat-0.1.0
+	>=dev-libs/libxmlb-0.1.13
+	$(python_gen_cond_dep '
+		dev-python/pillow[${PYTHON_MULTI_USEDEP}]
+		dev-python/pycairo[${PYTHON_MULTI_USEDEP}]
+		dev-python/pygobject:3[cairo,${PYTHON_MULTI_USEDEP}]
+	')
+	>=net-libs/libsoup-2.51.92:2.4[introspection?]
+	virtual/libelf:0=
+	virtual/udev
+	consolekit? ( >=sys-auth/consolekit-1.0.0 )
+	dell? (
+		sys-libs/efivar
+		>=sys-libs/libsmbios-2.4.0
+	)
+	elogind? ( sys-auth/elogind )
+	!minimal? (
+		>=sys-auth/polkit-0.103
+	)
+	nvme? ( sys-libs/efivar )
+	redfish? ( sys-libs/efivar )
+	systemd? ( >=sys-apps/systemd-211 )
+	tpm? ( app-crypt/tpm2-tss )
+	uefi? (
+		app-crypt/tpm2-tss
+		media-libs/fontconfig
+		media-libs/freetype
+		sys-boot/gnu-efi
+		sys-boot/efibootmgr
+		>=sys-libs/efivar-33
+		x11-libs/cairo
+	)
+"
+# Block sci-chemistry/chemical-mime-data for bug #701900
+RDEPEND="
+	!<sci-chemistry/chemical-mime-data-0.1.94-r4
+	${DEPEND}
+	sys-apps/dbus
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-1.3.9-logind_plugin.patch"
+)
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+	if use nvme; then
+		kernel_is -ge 4 4 || die "NVMe support requires kernel >= 4.4"
+	fi
+}
+
+src_prepare() {
+	default
+	# c.f. https://github.com/fwupd/fwupd/issues/1414
+	sed -e "/test('thunderbolt-self-test', e, env: test_env, timeout : 120)/d" \
+		-i plugins/thunderbolt/meson.build || die
+	vala_src_prepare
+}
+
+src_configure() {
+	local emesonargs=(
+		--localstatedir "${EPREFIX}"/var
+		-Dbuild="$(usex minimal standalone all)"
+		$(meson_use agent)
+		$(meson_use amt plugin_amt)
+		$(meson_use consolekit)
+		$(meson_use dell plugin_dell)
+		$(meson_use elogind)
+		$(meson_use gtk-doc gtkdoc)
+		$(meson_use man)
+		$(meson_use nvme plugin_nvme)
+		$(meson_use redfish plugin_redfish)
+		$(meson_use synaptics plugin_synaptics)
+		$(meson_use systemd)
+		$(meson_use test tests)
+		$(meson_use thunderbolt plugin_thunderbolt)
+		$(meson_use tpm plugin_tpm)
+		$(meson_use uefi plugin_uefi)
+		# Although our sys-apps/flashrom package now provides
+		# libflashrom.a, meson still can't find it
+		-Dplugin_flashrom="false"
+		# Dependencies are not available (yet?)
+		-Dplugin_modem_manager="false"
+	)
+	export CACHE_DIRECTORY="${T}"
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	if ! use minimal ; then
+		sed "s@%SEAT_MANAGER%@$(usex elogind elogind consolekit)@" \
+			"${FILESDIR}"/${PN}-r1 \
+			> "${T}"/${PN} || die
+		doinitd "${T}"/${PN}
+
+		if ! use systemd ; then
+			# Don't timeout when fwupd is running (#673140)
+			sed '/^IdleTimeout=/s@=[[:digit:]]\+@=0@' \
+				-i "${ED}"/etc/${PN}/daemon.conf || die
+		fi
+	fi
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	elog "In case you are using openrc as init system"
+	elog "and you're upgrading from <fwupd-1.1.0, you"
+	elog "need to start the fwupd daemon via the openrc"
+	elog "init script that comes with this package."
+}