[gentoo-commits] repo/gentoo:master commit in: sys-boot/vboot-utils/

[Zac Medico]

commit:     a599090d15353f23b20fab94cdbbdedffcfbc4aa
Author:     Zac Medico <zmedico <AT> gentoo <DOT> org>
AuthorDate: Thu Jan  3 23:02:45 2019 +0000
Commit:     Zac Medico <zmedico <AT> gentoo <DOT> org>
CommitDate: Thu Jan  3 23:50:08 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a599090d

sys-boot/vboot-utils: version bump to 72_p20181229 with openssl-1.1 support

Reported-by: Harri Nieminen <moiman <AT> posteo.net>
Closes: https://bugs.gentoo.org/673954
Package-Manager: Portage-2.3.53, Repoman-2.3.12
Signed-off-by: Zac Medico <zmedico <AT> gentoo.org>

 sys-boot/vboot-utils/Manifest                      |  1 +
 .../vboot-utils/vboot-utils-72_p20181229.ebuild    | 98 ++++++++++++++++++++++
 2 files changed, 99 insertions(+)

diff --git a/sys-boot/vboot-utils/Manifest b/sys-boot/vboot-utils/Manifest
index de1ea2d3981..7a88e037d44 100644
--- a/sys-boot/vboot-utils/Manifest
+++ b/sys-boot/vboot-utils/Manifest
@@ -1 +1,2 @@
 DIST vboot-utils-59_p20170413.tar.xz 18431260 BLAKE2B 73853f92c5855a1fbcad55c696414317f46a06a69901529dd6da19be2abe4ca0337cf20dddc4f84f1d2a99357bb2f01df115b7d16c45f9af62dcd1b833580d46 SHA512 f92b9aed7a52ac7bab49b624725d4963564a22a03741619ad4ef1bc0a1fdee5123c68f3dad5bef9fb033f94f2a9ae99478c16386758fe4667a361bc91dda8048
+DIST vboot-utils-72_p20181229.tar.xz 18489004 BLAKE2B 444eb0bc2c571ad79d26d473da724016d6d041207beaae161f6c1155768ff9d0b1c8b7b070b828083cc1396266cc77175a75e8067ce22613c75b4d77780dda75 SHA512 41df034dc5498bcbec0d49a472331ceb2fbc2eb3b4173d5c56e920d65ae485382b3d811e5f2c13cf45a1b05a5d6a24197924fa1c76ada9c3aac14fa3c4c363fe

diff --git a/sys-boot/vboot-utils/vboot-utils-72_p20181229.ebuild b/sys-boot/vboot-utils/vboot-utils-72_p20181229.ebuild
new file mode 100644
index 00000000000..3469619cf31
--- /dev/null
+++ b/sys-boot/vboot-utils/vboot-utils-72_p20181229.ebuild
@@ -0,0 +1,98 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit eutils toolchain-funcs
+
+# This is the latest commit in the latest branch.
+GIT_SHA1="a32c930e8c46424a3bba3c296fd78b3e60f50aeb"
+
+DESCRIPTION="Chrome OS verified boot tools"
+HOMEPAGE="https://chromium.googlesource.com/chromiumos/platform/vboot_reference/ http://dev.chromium.org/chromium-os/chromiumos-design-docs/verified-boot"
+# Can't use gitiles directly until b/19710536 is fixed.
+#SRC_URI="https://chromium.googlesource.com/chromiumos/platform/vboot_reference/+archive/${GIT_SHA1}.tar.gz -> ${P}.tar.gz"
+SRC_URI="mirror://gentoo/${P}.tar.xz
+	https://dev.gentoo.org/~zmedico/dist/${P}.tar.xz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~mips ~x86"
+IUSE="libressl minimal static"
+
+LIB_DEPEND="
+	dev-libs/libyaml:=[static-libs(+)]
+	app-arch/xz-utils:=[static-libs(+)]"
+LIB_DEPEND_MINIMAL="
+	!libressl? ( dev-libs/openssl:0=[static-libs(+)] )
+	libressl? ( dev-libs/libressl:0=[static-libs(+)] )
+	sys-apps/util-linux:=[static-libs(+)]
+	dev-libs/libzip:=[static-libs(+)]"
+RDEPEND="!static? (
+		${LIB_DEPEND_MINIMAL//\[static-libs(+)]}
+		!minimal? ( ${LIB_DEPEND//\[static-libs(+)]} )
+	)"
+DEPEND="${RDEPEND}
+	static? (
+		${LIB_DEPEND_MINIMAL}
+		!minimal? ( ${LIB_DEPEND} )
+	)
+	app-crypt/trousers"
+
+S=${WORKDIR}
+
+src_prepare() {
+	default
+	sed -i \
+		-e 's:${DESTDIR}/\(bin\|${LIBDIR}\):${DESTDIR}/usr/\1:g' \
+		-e 's:${DESTDIR}/default:${DESTDIR}/etc/default:g' \
+		-e 's:${TEST_INSTALL_DIR}/bin:${TEST_INSTALL_DIR}/usr/bin:' \
+		-e '/cgpt -D 358400/d' \
+		Makefile || die
+	sed -e 's:^BIN_DIR=${BUILD_DIR}/install_for_test/bin:BIN_DIR=${BUILD_DIR}/install_for_test/usr/bin:' \
+		-i tests/common.sh || die
+	sed -e "s:/mnt/host/source/src/platform/vboot_reference:${S}:" \
+		-i tests/futility/expect_output/* || die
+}
+
+_emake() {
+	local arch=$(tc-arch)
+	emake \
+		V=1 \
+		QEMU_ARCH= \
+		ARCH=${arch} \
+		HOST_ARCH=${arch} \
+		LIBDIR="$(get_libdir)" \
+		DEBUG_FLAGS= \
+		WERROR= \
+		MINIMAL=$(usev minimal) \
+		STATIC=$(usev static) \
+		$(usex elibc_musl HAVE_MUSL=1 "") \
+		"$@"
+}
+
+src_compile() {
+	tc-export CC AR CXX PKG_CONFIG
+	_emake TEST_BINS= all
+}
+
+src_test() {
+	_emake runtests
+}
+
+src_install() {
+	_emake DESTDIR="${ED}" install
+
+	insinto /usr/share/vboot/devkeys
+	doins tests/devkeys/*
+
+	insinto /usr/include/vboot
+	doins host/include/* \
+		firmware/include/gpt.h \
+		firmware/include/tlcl.h \
+		firmware/include/tss_constants.h
+
+	dolib.a build/libvboot_host.a
+
+	dodoc README
+}