[gentoo-commits] gentoo-x86 commit in net-misc/chrony: chrony-1.29-r2.ebuild ChangeLog

[Jeroen Roovers (jer)]

jer         13/11/22 15:48:04

  Modified:             ChangeLog
  Added:                chrony-1.29-r2.ebuild
  Log:
  Install configuration files in /etc/chrony.
  
  (Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key A792A613)

Revision  Changes    Path
1.118                net-misc/chrony/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/chrony/ChangeLog?rev=1.118&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/chrony/ChangeLog?rev=1.118&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/chrony/ChangeLog?r1=1.117&r2=1.118

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/chrony/ChangeLog,v
retrieving revision 1.117
retrieving revision 1.118
diff -u -r1.117 -r1.118
--- ChangeLog	21 Nov 2013 16:46:34 -0000	1.117
+++ ChangeLog	22 Nov 2013 15:48:04 -0000	1.118
@@ -1,6 +1,11 @@
 # ChangeLog for net-misc/chrony
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/chrony/ChangeLog,v 1.117 2013/11/21 16:46:34 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/chrony/ChangeLog,v 1.118 2013/11/22 15:48:04 jer Exp $
+
+*chrony-1.29-r2 (22 Nov 2013)
+
+  22 Nov 2013; Jeroen Roovers <jer@g.o> +chrony-1.29-r2.ebuild:
+  Install configuration files in /etc/chrony.
 
   21 Nov 2013; Jeroen Roovers <jer@g.o> chrony-1.29-r1.ebuild:
   Stable for HPPA (bug #491702).



1.1                  net-misc/chrony/chrony-1.29-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/chrony/chrony-1.29-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/chrony/chrony-1.29-r2.ebuild?rev=1.1&content-type=text/plain

Index: chrony-1.29-r2.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/chrony/chrony-1.29-r2.ebuild,v 1.1 2013/11/22 15:48:04 jer Exp $

EAPI=5
inherit eutils systemd toolchain-funcs

DESCRIPTION="NTP client and server programs"
HOMEPAGE="http://chrony.tuxfamily.org/"
SRC_URI="http://download.tuxfamily.org/${PN}/${P/_/-}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~arm ~hppa ~mips ~ppc ~sparc ~x86"
IUSE="caps ipv6 +readline +rtc selinux"

RDEPEND="
	caps? ( sys-libs/libcap )
	readline? ( >=sys-libs/readline-4.1-r4 )
	selinux? ( sec-policy/selinux-chronyd )
"
DEPEND="
	${RDEPEND}
	sys-apps/texinfo
"

S="${WORKDIR}/${P/_/-}"

src_prepare() {
	sed -i \
		-e 's:/etc/chrony\.:/etc/chrony/chrony.:g' \
		-e 's:/var/run:/run:g' \
		conf.c chrony.texi.in chrony.txt examples/* faq.txt || die
}

src_configure() {
	tc-export CC

	# not an autotools generated script
	./configure \
		$(usex caps '' --disable-linuxcaps) \
		$(usex ipv6 '' --disable-ipv6) \
		$(usex readline '' --disable-readline) \
		$(usex rtc '' --disable-rtc) \
		--docdir=/usr/share/doc/${PF} \
		--infodir=/usr/share/info \
		--mandir=/usr/share/man \
		--prefix=/usr \
		--sysconfdir=/etc/chrony \
		--without-nss \
		--without-tomcrypt \
		${EXTRA_ECONF} \
		|| die
}

src_compile() {
	emake all docs
}

src_install() {
	default
	rm "${D}"/usr/share/doc/${PF}/COPYING || die
	doinfo chrony.info*

	newinitd "${FILESDIR}"/chronyd.init chronyd
	newconfd "${FILESDIR}"/chronyd.conf chronyd

	insinto /etc/${PN}
	newins examples/chrony.conf.example chrony.conf
	newins examples/chrony.keys.example chrony.keys

	keepdir /var/{lib,log}/chrony

	insinto /etc/logrotate.d
	newins "${FILESDIR}"/chrony.logrotate chrony

	systemd_newunit "${FILESDIR}"/chronyd.service-r1 chronyd.service
	systemd_enable_ntpunit 50-chrony chronyd.service
}