[gentoo-commits] repo/gentoo:master commit in: dev-libs/libnl/

[Jeroen Roovers]

commit:     0949f29f406e8219ced96371db7549723eb88132
Author:     Jeroen Roovers <jer <AT> gentoo <DOT> org>
AuthorDate: Mon Dec 30 12:02:45 2019 +0000
Commit:     Jeroen Roovers <jer <AT> gentoo <DOT> org>
CommitDate: Mon Dec 30 12:03:04 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=0949f29f

dev-libs/libnl: Add live ebuild for SLOT=1.1

Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Jeroen Roovers <jer <AT> gentoo.org>

 dev-libs/libnl/libnl-1.1.9999.ebuild | 57 ++++++++++++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)

diff --git a/dev-libs/libnl/libnl-1.1.9999.ebuild b/dev-libs/libnl/libnl-1.1.9999.ebuild
new file mode 100644
index 00000000000..e9ef685bf11
--- /dev/null
+++ b/dev-libs/libnl/libnl-1.1.9999.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit git-r3 multilib toolchain-funcs
+
+DESCRIPTION="Libraries providing APIs to netlink protocol based Linux kernel interfaces"
+HOMEPAGE="http://www.infradead.org/~tgr/libnl/"
+EGIT_REPO_URI="https://github.com/tgraf/libnl-1.1-stable"
+LICENSE="LGPL-2.1"
+SLOT="1.1"
+KEYWORDS=""
+IUSE="doc static-libs"
+
+DEPEND="doc? ( app-doc/doxygen )"
+DOCS=( ChangeLog )
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.1-vlan-header.patch
+	"${FILESDIR}"/${PN}-1.1-flags.patch
+	"${FILESDIR}"/${PN}-1.1.3-offsetof.patch
+)
+
+src_prepare() {
+	default
+
+	sed -i \
+		-e '/@echo/d' \
+		Makefile.rules {lib,src,tests}/Makefile || die
+	sed -i \
+		-e 's|-g ||g' \
+		Makefile.opts.in || die
+
+	if ! use static-libs; then
+		sed -i lib/Makefile -e '/OUT_AR/d' || die
+	fi
+
+	rm -f lib/libnl.a
+}
+
+src_compile() {
+	emake AR=$(tc-getAR)
+
+	if use doc ; then
+		cd "${S}/doc"
+		emake gendoc
+	fi
+}
+
+src_install() {
+	default
+
+	if use doc ; then
+		cd "${S}/doc"
+		docinto html
+		dodoc -r html/*
+	fi
+}