[gentoo-commits] gentoo-x86 commit in kde-base/kalzium: ChangeLog kalzium-4.0.1.ebuild

[Wulf Krueger (philantrop)]

philantrop    08/02/07 00:12:22

  Modified:             ChangeLog
  Added:                kalzium-4.0.1.ebuild
  Log:
  Version bump to KDE 4.0.1.
  (Portage version: 2.1.4.1)

Revision  Changes    Path
1.84                 kde-base/kalzium/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/kde-base/kalzium/ChangeLog?rev=1.84&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/kde-base/kalzium/ChangeLog?rev=1.84&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/kde-base/kalzium/ChangeLog?r1=1.83&r2=1.84

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/kde-base/kalzium/ChangeLog,v
retrieving revision 1.83
retrieving revision 1.84
diff -u -r1.83 -r1.84
--- ChangeLog	31 Jan 2008 15:31:56 -0000	1.83
+++ ChangeLog	7 Feb 2008 00:12:21 -0000	1.84
@@ -1,6 +1,12 @@
 # ChangeLog for kde-base/kalzium
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/kalzium/ChangeLog,v 1.83 2008/01/31 15:31:56 ranger Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kalzium/ChangeLog,v 1.84 2008/02/07 00:12:21 philantrop Exp $
+
+*kalzium-4.0.1 (06 Feb 2008)
+
+  06 Feb 2008; Wulf C. Krueger <philantrop@g.o>
+  +kalzium-4.0.1.ebuild:
+  Version bump to KDE 4.0.1.
 
   31 Jan 2008; Brent Baude <ranger@g.o> kalzium-3.5.8.ebuild:
   Marking kalzium-3.5.8 ppc for bug 207634



1.1                  kde-base/kalzium/kalzium-4.0.1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/kde-base/kalzium/kalzium-4.0.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/kde-base/kalzium/kalzium-4.0.1.ebuild?rev=1.1&content-type=text/plain

Index: kalzium-4.0.1.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/kde-base/kalzium/kalzium-4.0.1.ebuild,v 1.1 2008/02/07 00:12:21 philantrop Exp $

EAPI="1"

KMNAME=kdeedu
inherit kde4-meta

DESCRIPTION="KDE: periodic table of the elements."
KEYWORDS="~amd64 ~x86"
IUSE="cviewer debug htmlhandbook solver test"

COMMONDEPEND=">=kde-base/libkdeedu-${PV}:${SLOT}
	cviewer? ( >=dev-cpp/eigen-1.0.5
		>=sci-chemistry/openbabel-2.1
		virtual/opengl )"
DEPEND="${DEPEND} ${COMMONDEPEND}
	solver? ( dev-ml/facile )"
RDEPEND="${RDEPEND} ${COMMONDEPEND}"

KMEXTRACTONLY="libkdeedu/kdeeduui libkdeedu/libscience"

pkg_setup() {
	use cviewer && QT4_BUILT_WITH_USE_CHECK="${QT4_BUILT_WITH_USE_CHECK} opengl"

	if use solver && ! built_with_use --missing true dev-lang/ocaml ocamlopt; then
		eerror "In order to build the solver for ${PN}, you first need"
		eerror "to have dev-lang/ocaml built with the ocamlopt useflag"
		eerror "in order to get a native code ocaml compiler"
		die "Please install dev-lang/ocaml with ocamlopt support"
	fi
	if use solver && ! built_with_use --missing true dev-ml/facile ocamlopt; then
		eerror "In order to build the solver for ${PN}, you first need"
		eerror "to have dev-ml/facile built with the ocamlopt useflag"
		eerror "in order to get the native code library"
		die "Please install dev-ml/facile with ocamlopt support"
	fi

	kde4-meta_pkg_setup
}

src_compile() {
	if use solver ; then
		# Compile the solver on its own as the cmake-based build is
		# currently broken. Fixes bug 206620.
		cd "${S}/${PN}/src/solver"
		emake || die "compiling the ocaml resolver failed"
		mkdir -p "${WORKDIR}/${PN}_build/${PN}/src/"
		cp * "${WORKDIR}/${PN}_build/${PN}/src/"
	fi

	mycmakeargs="${mycmakeargs}
		$(cmake-utils_use_with cviewer Eigen)
		$(cmake-utils_use_with cviewer OpenBabel2)
		$(cmake-utils_use_with cviewer OpenGL)
		$(cmake-utils_use_with solver OCaml)
		$(cmake-utils_use_with solver Libfacile)"

	kde4-meta_src_compile
}



-- 
gentoo-commits@l.g.o mailing list