[gentoo-commits] repo/gentoo:master commit in: media-sound/pragha/

[Michał Górny]

commit:     292b90d607fc17e14e511dee80293c81b98840cb
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Thu Jun 29 16:17:22 2017 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Thu Jun 29 22:21:58 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=292b90d6

media-sound/pragha: Bump to 1.3.3

 media-sound/pragha/Manifest            |  1 +
 media-sound/pragha/pragha-1.3.3.ebuild | 84 ++++++++++++++++++++++++++++++++++
 2 files changed, 85 insertions(+)

diff --git a/media-sound/pragha/Manifest b/media-sound/pragha/Manifest
index cbc9ad28024..a749bae3114 100644
--- a/media-sound/pragha/Manifest
+++ b/media-sound/pragha/Manifest
@@ -1 +1,2 @@
 DIST pragha-1.3.1.tar.bz2 621106 SHA256 49287152f59e5d62b57620f94b228517caaca001873c30c7abd426afacfc8a78 SHA512 17d086d84382c8e417e513c8803ea90612ca9d5c665384299362b3197978a8697faef531996b078e4ce12c52b7fad3be377083622c923775c6c738d5ae6acb93 WHIRLPOOL 1d531e588723623b99aa0bde1d2e1d8407e15cce89112847893ecf50f1fce4709ffb3bb1b5d88ce14a616db2809e81991228262fc12227cacf213d0c85a9c0ae
+DIST pragha-1.3.3.tar.bz2 679754 SHA256 74844eb99df44984206d6c55b15f1b553e9f122ddb0bad00902a7b7935d0a504 SHA512 3dc87d4e75cd9f145c3921af4c09140a705611d72176fd80db2d89048bc22c8edda5f87bce75f26e0cce4f6934c927e814e5c54fec7820116485cf4e04e876a9 WHIRLPOOL 86cd62135bfe477a2ba10038968f695d4fea81eab15f219df1e1b4b76326258f08cbd60e6d344a79a76842456d10cc7c4b6e85cb059e8977a57dab616b5ee61d

diff --git a/media-sound/pragha/pragha-1.3.3.ebuild b/media-sound/pragha/pragha-1.3.3.ebuild
new file mode 100644
index 00000000000..e19e41751b8
--- /dev/null
+++ b/media-sound/pragha/pragha-1.3.3.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit gnome2-utils xdg-utils
+
+DESCRIPTION="A lightweight music player (for Xfce)"
+HOMEPAGE="https://github.com/matiasdelellis/pragha"
+SRC_URI="https://github.com/matiasdelellis/${PN}/releases/download/v${PV}/${P}.tar.bz2"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+glyr grilo +keybinder lastfm libnotify mtp +peas +playlist rygel soup +udev"
+
+COMMON_DEPEND=">=dev-db/sqlite-3.4:3=
+	>=dev-libs/glib-2.36:=
+	>=dev-libs/libcdio-0.90:=
+	>=dev-libs/libcdio-paranoia-0.90:=
+	media-libs/gstreamer:1.0=
+	media-libs/gst-plugins-base:1.0=
+	>=media-libs/libcddb-1.3.0:=
+	>=media-libs/taglib-1.8:=
+	>=x11-libs/gtk+-3.8:3=
+	>=xfce-base/libxfce4ui-4.11:=[gtk3(+)]
+	glyr? ( >=media-libs/glyr-1.0.1:= )
+	grilo? ( >=media-libs/grilo-0.2.10:= )
+	keybinder? ( >=dev-libs/keybinder-0.2.0:3= )
+	lastfm? ( >=media-libs/libclastfm-0.5:= )
+	libnotify? ( >=x11-libs/libnotify-0.7.5:= )
+	mtp? ( >=media-libs/libmtp-1.1.0:= )
+	peas? ( >=dev-libs/libpeas-1.0.0:=[gtk] )
+	playlist? ( >=dev-libs/totem-pl-parser-2.26:= )
+	rygel? ( >=net-misc/rygel-0.20:= )
+	soup? ( >=net-libs/libsoup-2.38:= )
+	udev? ( virtual/libgudev:= )"
+RDEPEND="${COMMON_DEPEND}
+	media-plugins/gst-plugins-meta:1.0"
+DEPEND="${COMMON_DEPEND}
+	dev-util/intltool
+	>=dev-util/xfce4-dev-tools-4.10
+	sys-devel/gettext
+	virtual/pkgconfig"
+REQUIRED_USE="glyr? ( peas )
+	grilo? ( peas )
+	libnotify? ( peas )
+	mtp? ( udev )
+	rygel? ( peas )
+	soup? ( peas )
+	udev? ( peas )"
+
+src_configure() {
+	local myconf=(
+		$(use_enable peas libpeas-1.0)
+		$(use_enable glyr libglyr)
+		$(use_enable lastfm libclastfm)
+		$(use_enable playlist totem-plparser)
+
+		$(use_enable libnotify)
+		$(use_enable keybinder)
+		$(use_enable udev gudev-1.0)
+		$(use_enable mtp libmtp)
+		$(use_enable soup libsoup-2.4)
+		$(use_enable rygel rygel-server-2.2)
+		$(use_enable grilo grilo-0.2)
+	)
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+}