[gentoo-commits] gentoo-x86 commit in sci-libs/minuit: ChangeLog minuit-5.27.02.ebuild

[Justin Lecher (jlec)]

jlec        10/05/10 14:57:03

  Modified:             ChangeLog
  Added:                minuit-5.27.02.ebuild
  Log:
  Version Bump
  (Portage version: 2.2_rc67/cvs/Linux x86_64)

Revision  Changes    Path
1.11                 sci-libs/minuit/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-libs/minuit/ChangeLog?rev=1.11&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-libs/minuit/ChangeLog?rev=1.11&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-libs/minuit/ChangeLog?r1=1.10&r2=1.11

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-libs/minuit/ChangeLog,v
retrieving revision 1.10
retrieving revision 1.11
diff -u -r1.10 -r1.11
--- ChangeLog	4 Dec 2009 22:41:48 -0000	1.10
+++ ChangeLog	10 May 2010 14:57:03 -0000	1.11
@@ -1,6 +1,11 @@
 # ChangeLog for sci-libs/minuit
-# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-libs/minuit/ChangeLog,v 1.10 2009/12/04 22:41:48 bicatali Exp $
+# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/sci-libs/minuit/ChangeLog,v 1.11 2010/05/10 14:57:03 jlec Exp $
+
+*minuit-5.27.02 (10 May 2010)
+
+  10 May 2010; Justin Lecher <jlec@g.o> +minuit-5.27.02.ebuild:
+  Version Bump
 
   04 Dec 2009; Sébastien Fabbro <bicatali@g.o>
   -minuit-5.16.00.ebuild, -files/minuit-5.16.00-gcc4.3.patch,



1.1                  sci-libs/minuit/minuit-5.27.02.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-libs/minuit/minuit-5.27.02.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-libs/minuit/minuit-5.27.02.ebuild?rev=1.1&content-type=text/plain

Index: minuit-5.27.02.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-libs/minuit/minuit-5.27.02.ebuild,v 1.1 2010/05/10 14:57:03 jlec Exp $

EAPI=2
inherit eutils toolchain-funcs

MY_PN=Minuit2

DESCRIPTION="A C++ physics analysis tool for function minimization"
HOMEPAGE="http://seal.web.cern.ch/seal/MathLibs/Minuit2/html/index.html"

SRC_URI="http://seal.web.cern.ch/seal/MathLibs/${MY_PN}/${MY_PN}-${PV}.tar.gz
	doc? ( http://seal.cern.ch/documents/minuit/mnusersguide.pdf
		   http://seal.cern.ch/documents/minuit/mntutorial.pdf )"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86 ~amd64"
IUSE="doc openmp"
DEPEND="doc? ( app-doc/doxygen )"
RDEPEND=""

S="${WORKDIR}/${MY_PN}-${PV}"

pkg_setup() {
	if use openmp && [[ $(tc-getCXX)$ == *g++* ]] && \
		! built_with_use sys-devel/gcc openmp; then
		ewarn "You are using gcc built without openmp"
		ewarn "Switch CXX to an OpenMP capable compiler"
		die "Need openmp"
	fi
}

src_configure() {
	econf $(use_enable openmp)
}

src_compile() {
	emake || die "emake failed"
	if use doc; then
		emake docs || die "emake docs failed"
	fi
}

src_test() {
	emake check || die "emake check failed"
	# make check only compiles the tests. run them
	for d in test/Mn*; do
		cd "${S}"/${d}
		for t in test_*; do
			./${t} || die "${t} failed"
		done
	done
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	insinto /usr/share/doc/${PF}/MnTutorial
	doins test/MnTutorial/*.{h,cxx}
	if use doc; then
		insinto /usr/share/doc/${PF}
		doins "${DISTDIR}"/mn*.pdf || die "doins failed"
		dohtml -r doc/html/* || die "dohtml failed"
	fi
}