[gentoo-commits] repo/gentoo:master commit in: dev-python/tox/

[Michał Górny]

commit:     a561843f78523a9930977330633a3b40846aa1e7
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sat Jan  9 07:43:51 2021 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sat Jan  9 08:07:45 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a561843f

dev-python/tox: Bump to 3.21.0

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/tox/Manifest          |  1 +
 dev-python/tox/tox-3.21.0.ebuild | 68 ++++++++++++++++++++++++++++++++++++++++
 2 files changed, 69 insertions(+)

diff --git a/dev-python/tox/Manifest b/dev-python/tox/Manifest
index 227bee587f6..69a8ff56b75 100644
--- a/dev-python/tox/Manifest
+++ b/dev-python/tox/Manifest
@@ -1 +1,2 @@
 DIST tox-3.20.1.tar.gz 297516 BLAKE2B 2a13059bce229f30670e247b17ffd03d4b0d907b2fa7eb7d2f6848ada8d81e1a0aad983748c4346dfa61877f88edd22e4616ed20efcbd15da34fdc1c87b4439a SHA512 0989cc3dfd25eb3d1236d973d490f12c81273c93e84140b54342217eb73dd944f446c7ce9fe228b644d764b94300f1c6ccaf94e442d0e34835d05de84cccabd6
+DIST tox-3.21.0.tar.gz 300962 BLAKE2B 360aedb86ef1f918e73f726af238d8fdb20c3217b45ef068ec833b14e17af018c1115a2df43b441b9a4af802c4aee2fcaa9bac8f519028dd05b112902c47b2ce SHA512 50041660839cc081d491f867db74c6e95c93b81b2264785b3ccf7b80fbf3a1250028755ddc4243a285ebd005e12f897001d6ea7efd45d0278ce3cb14f7021572

diff --git a/dev-python/tox/tox-3.21.0.ebuild b/dev-python/tox/tox-3.21.0.ebuild
new file mode 100644
index 00000000000..9a3af74ecf8
--- /dev/null
+++ b/dev-python/tox/tox-3.21.0.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=rdepend
+PYTHON_COMPAT=( python3_{6..9} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="virtualenv-based automation of test activities"
+HOMEPAGE="https://tox.readthedocs.io https://github.com/tox-dev/tox https://pypi.org/project/tox/"
+SRC_URI="https://github.com/tox-dev/tox/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+# doc disabled because of missing deps in tree
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-python/filelock[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/importlib_metadata-1.1[${PYTHON_USEDEP}]
+	' python3_{5,6,7} pypy3)
+	dev-python/packaging[${PYTHON_USEDEP}]
+	>=dev-python/pluggy-0.12[${PYTHON_USEDEP}]
+	dev-python/pip[${PYTHON_USEDEP}]
+	dev-python/py[${PYTHON_USEDEP}]
+	>=dev-python/six-1.14[${PYTHON_USEDEP}]
+	dev-python/toml[${PYTHON_USEDEP}]
+	>=dev-python/virtualenv-16.0.0[${PYTHON_USEDEP}]"
+# TODO: figure out how to make tests work without the package being
+# installed first.
+BDEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	test? (
+		${RDEPEND}
+		>=dev-python/flaky-3.4.0[${PYTHON_USEDEP}]
+		>=dev-python/freezegun-0.3.11[${PYTHON_USEDEP}]
+		>=dev-python/pytest-4.0.0[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		=dev-python/tox-${PV}-${PR}[${PYTHON_USEDEP}]
+	)"
+
+src_configure() {
+	export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+}
+
+python_test() {
+	local deselect=(
+		# broken without Internet
+		tests/unit/session/test_provision.py::test_provision_non_canonical_dep
+		tests/integration/test_provision_int.py::test_provision_interrupt_child
+
+		# expects python2 to exist
+		tests/unit/interpreters/test_interpreters.py::test_tox_get_python_executable
+	)
+
+	[[ ${EPYTHON} != pypy3 ]] && deselect+=(
+		# TODO?
+		tests/unit/interpreters/test_interpreters.py::test_find_alias_on_path
+	)
+
+	distutils_install_for_testing --via-root
+	pytest -vv --no-network ${deselect[@]/#/--deselect } || die "Testsuite failed under ${EPYTHON}"
+}