[gentoo-commits] proj/kde:master commit in: kde-apps/ark/

[Andreas Sturmlechner]

commit:     9009e968d6ce5c7fe620839b1d278ea7bdb76c71
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Thu Nov  3 12:58:46 2022 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Thu Nov  3 14:06:56 2022 +0000
URL:        https://gitweb.gentoo.org/proj/kde.git/commit/?id=9009e968

kde-apps/ark: drop 22.08.3

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 kde-apps/ark/ark-22.08.3.ebuild | 81 -----------------------------------------
 1 file changed, 81 deletions(-)

diff --git a/kde-apps/ark/ark-22.08.3.ebuild b/kde-apps/ark/ark-22.08.3.ebuild
deleted file mode 100644
index 9350b60134..0000000000
--- a/kde-apps/ark/ark-22.08.3.ebuild
+++ /dev/null
@@ -1,81 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-ECM_HANDBOOK="forceoptional"
-ECM_TEST="optional"
-KFMIN=5.96.0
-QTMIN=5.15.5
-VIRTUALX_REQUIRED="test"
-inherit ecm gear.kde.org optfeature
-
-DESCRIPTION="File archiver by KDE"
-HOMEPAGE="https://apps.kde.org/ark/ https://utils.kde.org/projects/ark/"
-
-LICENSE="GPL-2" # TODO: CHECK
-SLOT="5"
-KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86"
-IUSE="zip"
-
-RDEPEND="
-	app-arch/libarchive:=[bzip2,lzma,zlib(+)]
-	>=dev-qt/qtdbus-${QTMIN}:5
-	>=dev-qt/qtgui-${QTMIN}:5
-	>=dev-qt/qtwidgets-${QTMIN}:5
-	>=kde-frameworks/karchive-${KFMIN}:5
-	>=kde-frameworks/kcompletion-${KFMIN}:5
-	>=kde-frameworks/kconfig-${KFMIN}:5
-	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
-	>=kde-frameworks/kcoreaddons-${KFMIN}:5
-	>=kde-frameworks/kcrash-${KFMIN}:5
-	>=kde-frameworks/kdbusaddons-${KFMIN}:5
-	>=kde-frameworks/ki18n-${KFMIN}:5
-	>=kde-frameworks/kio-${KFMIN}:5
-	>=kde-frameworks/kitemmodels-${KFMIN}:5
-	>=kde-frameworks/kjobwidgets-${KFMIN}:5
-	>=kde-frameworks/kparts-${KFMIN}:5
-	>=kde-frameworks/kpty-${KFMIN}:5
-	>=kde-frameworks/kservice-${KFMIN}:5
-	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
-	>=kde-frameworks/kxmlgui-${KFMIN}:5
-	sys-libs/zlib
-	zip? ( >=dev-libs/libzip-1.6.0:= )
-"
-DEPEND="${RDEPEND}
-	>=dev-qt/qtconcurrent-${QTMIN}:5
-	test? ( >=dev-libs/libzip-1.6.0:= )
-"
-# app-arch/rar is binary only
-BDEPEND="
-	sys-devel/gettext
-	elibc_glibc? ( test? ( amd64? ( app-arch/rar ) x86? ( app-arch/rar ) ) )
-"
-
-src_configure() {
-	local mycmakeargs=(
-		$(cmake_use_find_package zip LibZip)
-	)
-
-	ecm_src_configure
-}
-
-src_test() {
-	local myctestargs=(
-		# bug 822177: may segfault or hang indefinitely
-		-E "(kerfuffle-addtoarchivetest)"
-	)
-
-	ecm_src_test
-}
-
-pkg_postinst() {
-	if [[ -z "${REPLACING_VERSIONS}" ]]; then
-		optfeature "rar archive creation/extraction" "app-arch/rar"
-		optfeature "rar archive extraction only" "app-arch/unar" "app-arch/unrar"
-		optfeature "7-Zip archive support" "app-arch/p7zip"
-		optfeature "lrz archive support" "app-arch/lrzip"
-		optfeature "Markdown support in text previews" "kde-misc/markdownpart:${SLOT}"
-	fi
-	ecm_pkg_postinst
-}