[gentoo-commits] gentoo-x86 commit in net-im/emesene: metadata.xml emesene-2.11.4.ebuild emesene-1.6.3.ebuild ChangeLog

[Markos Chandras (hwoarang)]

hwoarang    11/05/29 12:06:54

  Added:                metadata.xml emesene-2.11.4.ebuild
                        emesene-1.6.3.ebuild ChangeLog
  Log:
  Initial commit. Bug #211174 and Bug #256747
  
  (Portage version: 2.2.0_alpha36/cvs/Linux x86_64)

Revision  Changes    Path
1.1                  net-im/emesene/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/emesene/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/emesene/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
<herd>no-herd</herd>
<maintainer>
<email>hwoarang@g.o</email>
<name>Markos Chandras</name>
</maintainer>
<use>
	<flag name='webcam'>Enable support for webcam</flag>
</use>
<longdescription lang="en">
</longdescription>
</pkgmetadata>




1.1                  net-im/emesene/emesene-2.11.4.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/emesene/emesene-2.11.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/emesene/emesene-2.11.4.ebuild?rev=1.1&content-type=text/plain

Index: emesene-2.11.4.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-im/emesene/emesene-2.11.4.ebuild,v 1.1 2011/05/29 12:06:54 hwoarang Exp $

EAPI="3"
PYTHON_DEPEND="2"
PYTHON_USE_WITH="sqlite"
SUPPORT_PYTHON_ABIS="1"
RESTRICT_PYTHON_ABIS="3.*"

inherit distutils eutils

DESCRIPTION="Platform independent MSN Messenger client written in Python+GTK"
HOMEPAGE="http://www.emesene.org"
SRC_URI="http://dev.gentoo.org/~hwoarang/distfiles/${P}.tar.gz"

LICENSE="|| ( GPL-2 GPL-3 LGPL-3 )"
SLOT="2"
KEYWORDS="~amd64 ~x86"
IUSE="jabber"

RDEPEND="dev-python/pygtk:2
	dev-python/papyon
	dev-python/notify-python
	jabber? ( dev-python/xmpppy )"

src_prepare() {
	# do not import dummy session
	sed -i -e  "/import e3dummy/d" ${PN}.py
	# fix .desktop icon to look for emesene-2 executable
	sed -i -e "s:${PN}:${PN}-2:g" \
		${PN}/data/share/applications/${PN}.desktop
	# Use a better meny entry
	sed -i -e "/^Name/s:${PN}-2:Emesene v2:" \
		${PN}/data/share/applications/${PN}.desktop
	distutils_src_prepare
}

src_install() {
	mysymlink(){
		dosym  $(python_get_sitedir)/${PN}/${PN} /usr/bin/${PN}-2 || die
	}
	distutils_src_install
	# fix names
	mv "${D}"/usr/share/applications/${PN}.desktop \
		"${D}"/usr/share/applications/${PN}-2.desktop
	mv "${D}"/usr/share/pixmaps/${PN}.png \
		"${D}"/usr/share/pixmaps/${PN}-2.png
	mv "${D}"/usr/share/pixmaps/${PN}.xpm \
		"${D}"/usr/share/pixmaps/${PN}-2.xpm
	mv "${D}"/usr/share/man/man1/${PN}.1 \
		"${D}"/usr/share/man/man1/${PN}-2.1

	python_execute_function -q mysymlink
}



1.1                  net-im/emesene/emesene-1.6.3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/emesene/emesene-1.6.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/emesene/emesene-1.6.3.ebuild?rev=1.1&content-type=text/plain

Index: emesene-1.6.3.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-im/emesene/emesene-1.6.3.ebuild,v 1.1 2011/05/29 12:06:54 hwoarang Exp $

EAPI="2"
PYTHON_DEPEND="2"

inherit python eutils

DESCRIPTION="Platform independent MSN Messenger client written in Python+GTK"
HOMEPAGE="http://www.emesene.org"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="webcam"

RDEPEND="dev-python/pygtk:2
	dev-python/gst-python
	webcam? ( media-plugins/gst-plugins-meta[v4l2] )"

src_prepare() {
	rm GPL PSF LGPL || die "rm license files failed"

	if ! use webcam; then
		rm -r libmimic || die "rm libmimic dir failed"
	fi
}

src_compile() {
	if use webcam ; then
		$(PYTHON) ./setup.py build_ext -i || die "libmimic compile failed"
	fi
}

src_install() {
	if use webcam; then
		rm -r build || die "rm build failed"
	fi

	insinto /usr/share/${PN}
	doins -r * || die "doins failed"

	fperms a+x /usr/share/${PN}/${PN} || die "fperms failed"
	dosym /usr/share/${PN}/${PN} /usr/bin/${PN} || die "dosym failed"

	doman misc/${PN}.1 || die "doman failed"

	doicon misc/*.{svg,png} || die "doicon failed"

	# install the desktop entry
	domenu misc/${PN}.desktop || die "domenu failed"
}

pkg_postinst() {
	python_mod_optimize /usr/share/${PN}

	elog "If you want to use the spell-checking feature, you should emerge"
	elog "dev-python/gtkspell-python"
	elog
	elog "If you want to use EncryptMessage plugin, you should emerge"
	elog "dev-python/pexpect"
}

pkg_postrm() {
	python_mod_cleanup /usr/share/${PN}
}



1.1                  net-im/emesene/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/emesene/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/emesene/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for net-im/emesene
# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/net-im/emesene/ChangeLog,v 1.1 2011/05/29 12:06:54 hwoarang Exp $

*emesene-2.11.4 (29 May 2011)
*emesene-1.6.3 (29 May 2011)

  29 May 2011; Markos Chandras <hwoarang@g.o> +emesene-1.6.3.ebuild,
  +emesene-2.11.4.ebuild, +metadata.xml:
  Initial commit of emesene packages

  emesene-1.6.3: Bug #211174. Thanks to Fabiano Francesconi (elbryan)
  <fabiano.francesconi@×××××.com>

  emesene-2.11.4: Bug #256747. Thanks to everyone who contributed various
  ebuilds