[gentoo-commits] gentoo-x86 commit in net-misc/tinc: tinc-1.0.24-r2.ebuild tinc-1.1_pre10-r1.ebuild ChangeLog tinc-1.0.24-r1.ebuild tinc-1.1_pre10.ebuild

[Anthony G. Basile (blueness)]

blueness    14/09/27 15:02:09

  Modified:             ChangeLog
  Added:                tinc-1.0.24-r2.ebuild tinc-1.1_pre10-r1.ebuild
  Removed:              tinc-1.0.24-r1.ebuild tinc-1.1_pre10.ebuild
  Log:
  Fix bashism, bug #523862
  
  (Portage version: 2.2.8-r2/cvs/Linux x86_64, signed Manifest commit with key 0xF52D4BBA)

Revision  Changes    Path
1.49                 net-misc/tinc/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/tinc/ChangeLog?rev=1.49&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/tinc/ChangeLog?rev=1.49&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/tinc/ChangeLog?r1=1.48&r2=1.49

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/tinc/ChangeLog,v
retrieving revision 1.48
retrieving revision 1.49
diff -u -r1.48 -r1.49
--- ChangeLog	17 Jul 2014 05:47:19 -0000	1.48
+++ ChangeLog	27 Sep 2014 15:02:09 -0000	1.49
@@ -1,6 +1,14 @@
 # ChangeLog for net-misc/tinc
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/tinc/ChangeLog,v 1.48 2014/07/17 05:47:19 dlan Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/tinc/ChangeLog,v 1.49 2014/09/27 15:02:09 blueness Exp $
+
+*tinc-1.1_pre10-r1 (27 Sep 2014)
+*tinc-1.0.24-r2 (27 Sep 2014)
+
+  27 Sep 2014; Anthony G. Basile <blueness@g.o> +tinc-1.0.24-r2.ebuild,
+  +tinc-1.1_pre10-r1.ebuild, -tinc-1.0.24-r1.ebuild, -tinc-1.1_pre10.ebuild,
+  files/tincd-r1:
+  Fix bashism, bug #523862
 
 *tinc-1.1_pre10 (17 Jul 2014)
 *tinc-1.0.24-r1 (17 Jul 2014)



1.1                  net-misc/tinc/tinc-1.0.24-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/tinc/tinc-1.0.24-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/tinc/tinc-1.0.24-r2.ebuild?rev=1.1&content-type=text/plain

Index: tinc-1.0.24-r2.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/tinc/tinc-1.0.24-r2.ebuild,v 1.1 2014/09/27 15:02:09 blueness Exp $

EAPI="5"
inherit systemd

DESCRIPTION="tinc is an easy to configure VPN implementation"
HOMEPAGE="http://www.tinc-vpn.org/"
SRC_URI="http://www.tinc-vpn.org/packages/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~arm ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos"
IUSE="+lzo uml vde +zlib"

DEPEND="dev-libs/openssl
	lzo? ( dev-libs/lzo:2 )
	zlib? ( sys-libs/zlib )"
RDEPEND="${DEPEND}
	vde? ( net-misc/vde )"

src_configure() {
	econf \
		--enable-jumbograms \
		--disable-tunemu  \
		$(use_enable lzo) \
		$(use_enable uml) \
		$(use_enable vde) \
		$(use_enable zlib)
}

src_install() {
	emake DESTDIR="${D}" install
	dodir /etc/tinc
	dodoc AUTHORS NEWS README THANKS
	doconfd "${FILESDIR}"/tinc.networks
	newconfd "${FILESDIR}"/tincd.conf tincd
	newinitd "${FILESDIR}"/tincd-r1 tincd
	systemd_newunit "${FILESDIR}"/tincd_at.service "tincd@.service"
}

pkg_postinst() {
	elog "This package requires the tun/tap kernel device."
	elog "Look at http://www.tinc-vpn.org/ for how to configure tinc"
}



1.1                  net-misc/tinc/tinc-1.1_pre10-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/tinc/tinc-1.1_pre10-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/tinc/tinc-1.1_pre10-r1.ebuild?rev=1.1&content-type=text/plain

Index: tinc-1.1_pre10-r1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/tinc/tinc-1.1_pre10-r1.ebuild,v 1.1 2014/09/27 15:02:09 blueness Exp $

EAPI="5"

MY_PV=${PV/_/}
MY_P=${PN}-${MY_PV}

PYTHON_COMPAT=( python2_7 )
inherit eutils systemd python-any-r1

DESCRIPTION="tinc is an easy to configure VPN implementation"
HOMEPAGE="http://www.tinc-vpn.org/"
SRC_URI="http://www.tinc-vpn.org/packages/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~arm ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos"
IUSE="+lzo +ncurses +openssl gcrypt gui +readline uml vde +zlib"

DEPEND="dev-libs/openssl
	lzo? ( dev-libs/lzo:2 )
	ncurses? ( sys-libs/ncurses )
	readline? ( sys-libs/readline )
	zlib? ( sys-libs/zlib )"
RDEPEND="${DEPEND}
	vde? ( net-misc/vde )
	${PYTHON_DEPS}
	gui? ( $(python_gen_any_dep '
	dev-python/wxpython[${PYTHON_USEDEP}]
	') )"

REQUIRED_USE="^^ ( openssl gcrypt )"

S="${WORKDIR}/${MY_P}"

src_configure() {
	econf \
		--enable-jumbograms \
		--disable-tunemu  \
		--with-windows2000 \
		--disable-silent-rules \
		$(use_enable lzo) \
		$(use_enable ncurses curses) \
		$(use_enable readline) \
		$(use_enable uml) \
		$(use_enable vde) \
		$(use_enable zlib) \
		$(use_with openssl) \
#		$(use_with gcrypt libgcrypt), upstream not ready
}

src_install() {
	emake DESTDIR="${D}" install
	dodir /etc/tinc
	dodoc AUTHORS NEWS README THANKS
	doconfd "${FILESDIR}"/tinc.networks
	newconfd "${FILESDIR}"/tincd.conf tincd
	newinitd "${FILESDIR}"/tincd-r1 tincd
	systemd_newunit "${FILESDIR}"/tincd_at.service "tincd@.service"

	if use gui; then
		python_fix_shebang "${ED}"/usr/bin/tinc-gui
	else
		rm -f "${ED}"/usr/bin/tinc-gui || die
	fi
}

pkg_postinst() {
	elog "This package requires the tun/tap kernel device."
	elog "Look at http://www.tinc-vpn.org/ for how to configure tinc"
}