[gentoo-commits] gentoo-x86 commit in dev-python/pylint: ChangeLog pylint-0.15.2.ebuild

[Patrick Lauer (patrick)]

patrick     09/01/24 17:42:16

  Modified:             ChangeLog
  Added:                pylint-0.15.2.ebuild
  Log:
  Bump to 0.15.2, fixes #254653
  (Portage version: 2.2_rc23/cvs/Linux x86_64)

Revision  Changes    Path
1.46                 dev-python/pylint/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-python/pylint/ChangeLog?rev=1.46&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-python/pylint/ChangeLog?rev=1.46&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-python/pylint/ChangeLog?r1=1.45&r2=1.46

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/pylint/ChangeLog,v
retrieving revision 1.45
retrieving revision 1.46
diff -u -r1.45 -r1.46
--- ChangeLog	21 Oct 2008 17:28:23 -0000	1.45
+++ ChangeLog	24 Jan 2009 17:42:16 -0000	1.46
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/pylint
-# Copyright 2000-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/pylint/ChangeLog,v 1.45 2008/10/21 17:28:23 hawking Exp $
+# Copyright 2000-2009 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/pylint/ChangeLog,v 1.46 2009/01/24 17:42:16 patrick Exp $
+
+*pylint-0.15.2 (24 Jan 2009)
+
+  24 Jan 2009; Patrick Lauer <patrick@g.o> +pylint-0.15.2.ebuild:
+  Bump to 0.15.2, fixes #254653
 
   21 Oct 2008; Ali Polatel <hawking@g.o> pylint-0.14.0.ebuild:
   Fix astng dependency, #236455.



1.1                  dev-python/pylint/pylint-0.15.2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-python/pylint/pylint-0.15.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-python/pylint/pylint-0.15.2.ebuild?rev=1.1&content-type=text/plain

Index: pylint-0.15.2.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/pylint/pylint-0.15.2.ebuild,v 1.1 2009/01/24 17:42:16 patrick Exp $

inherit distutils eutils

DESCRIPTION="PyLint is a tool to check if a Python module satisfies a coding standard"
SRC_URI="ftp://ftp.logilab.org/pub/pylint/${P}.tar.gz"
HOMEPAGE="http://www.logilab.org/projects/pylint/"

IUSE="tk"
SLOT="0"
KEYWORDS="~amd64 ~ia64 ~ppc ~sparc ~x86"
LICENSE="GPL-2"
DEPEND=">=dev-python/logilab-common-0.21.0
		>=dev-python/astng-0.17.2
		tk? ( >=dev-lang/tk-8.4.9 )"

DOCS="doc/*.txt"

pkg_setup() {
	if use tk && ! built_with_use dev-lang/python tk; then
		eerror "You have USE='tk' enabled."
		eerror "Python has not been compiled with tkinter support."
		eerror "Please re-emerge python with the 'tk' USE-flag set."
		die "Missing USE-flag for dev-lang/python"
	fi
}

src_unpack() {
	unpack ${A}
	cd "${S}"

	# Make the test that tries to import gtk a bit less strict
	epatch "${FILESDIR}/${PN}-0.10.0-extra-gtk-disable.patch"

	# Make pylint-gui print a gentoo-specific message if Tkinter is missing
	epatch "${FILESDIR}/${PN}-0.11.0-gui-no-tkinter.patch"
}

src_install() {
	distutils_src_install
	# do not install the test suite (we ran it from src_test already
	# and it makes .py[co] generation very noisy because there are
	# files with SyntaxErrors in there)
	python_version
	rm -rf "${D}"/usr/lib*/python${PYVER}/site-packages/pylint/test

	doman man/pylint.1
	dohtml doc/*.html
}

src_test() {
	# The tests will not work properly from the source dir, so do a
	# temporary install:
	"${python}" setup.py install --home="${T}/test" || die "test copy failed"
	# dir needs to be this or the tests fail
	cd "${T}/test/lib/python/pylint/test"

	# These fail, have not been able to track down why.
	rm rpythoninput/func_unsupported_protocol.py || die "rm failed"
	rm func_test_rpython.py || die "rm failed"
	PYTHONPATH="${T}/test/lib/python" "${python}" runtests.py || \
		die "tests failed"
	cd "${S}"
	rm -rf "${T}/test"
}

pkg_postinst() {
	distutils_pkg_postinst
	elog 'A couple of important configuration settings (like "disable-msg")'
	elog 'moved from the "MASTER" to "MESSAGES CONTROL" section.'
	elog 'See "pylint --help".'
}