[gentoo-commits] gentoo-x86 commit in net-libs/libinfinity: libinfinity-0.5.1.ebuild ChangeLog libinfinity-0.5.0.ebuild

[Kacper Kowalik (xarthisius)]

xarthisius    11/08/02 09:13:43

  Modified:             ChangeLog
  Added:                libinfinity-0.5.1.ebuild
  Removed:              libinfinity-0.5.0.ebuild
  Log:
  Version bump, drop old
  
  (Portage version: 2.2.0_alpha49/cvs/Linux x86_64)

Revision  Changes    Path
1.11                 net-libs/libinfinity/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/libinfinity/ChangeLog?rev=1.11&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/libinfinity/ChangeLog?rev=1.11&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/libinfinity/ChangeLog?r1=1.10&r2=1.11

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-libs/libinfinity/ChangeLog,v
retrieving revision 1.10
retrieving revision 1.11
diff -u -r1.10 -r1.11
--- ChangeLog	30 Apr 2011 09:48:18 -0000	1.10
+++ ChangeLog	2 Aug 2011 09:13:42 -0000	1.11
@@ -1,6 +1,12 @@
 # ChangeLog for net-libs/libinfinity
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/libinfinity/ChangeLog,v 1.10 2011/04/30 09:48:18 xarthisius Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-libs/libinfinity/ChangeLog,v 1.11 2011/08/02 09:13:42 xarthisius Exp $
+
+*libinfinity-0.5.1 (02 Aug 2011)
+
+  02 Aug 2011; Kacper Kowalik <xarthisius@g.o>
+  -libinfinity-0.5.0.ebuild, +libinfinity-0.5.1.ebuild:
+  Version bump, drop old
 
 *libinfinity-0.5.0 (30 Apr 2011)
 



1.1                  net-libs/libinfinity/libinfinity-0.5.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/libinfinity/libinfinity-0.5.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/libinfinity/libinfinity-0.5.1.ebuild?rev=1.1&content-type=text/plain

Index: libinfinity-0.5.1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-libs/libinfinity/libinfinity-0.5.1.ebuild,v 1.1 2011/08/02 09:13:42 xarthisius Exp $

EAPI=4

inherit autotools-utils eutils versionator

MY_PV=$(get_version_component_range 1-2)

DESCRIPTION="An implementation of the Infinote protocol written in GObject-based C."
HOMEPAGE="http://gobby.0x539.de/"
SRC_URI="http://releases.0x539.de/${PN}/${P}.tar.gz"
LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="avahi doc gtk server static-libs"

RDEPEND="dev-libs/glib:2
	dev-libs/libxml2
	net-libs/gnutls
	sys-libs/pam
	>=virtual/gsasl-0.2.21
	avahi? ( net-dns/avahi )
	gtk? ( x11-libs/gtk+:3 )"
DEPEND="${RDEPEND}
	>=dev-util/pkgconfig-0.23
	sys-devel/gettext
	doc? ( dev-util/gtk-doc )"

DOCS=(AUTHORS NEWS README TODO)

pkg_setup() {
	if use server ; then
		enewgroup infinote 100
		enewuser infinote 100 /bin/bash /var/lib/infinote infinote
	fi
}

src_configure() {
	local myeconfargs=(
		$(use_enable doc gtk-doc)
		$(use_with gtk inftextgtk)
		$(use_with gtk infgtk)
		$(use_with gtk gtk3)
		$(use_with server infinoted)
		$(use_with avahi)
		$(use_with avahi libdaemon)
	)
	autotools-utils_src_configure
}

src_install() {
	autotools-utils_src_install

	if use server ; then
		newinitd "${FILESDIR}/infinoted.initd" infinoted
		newconfd "${FILESDIR}/infinoted.confd" infinoted

		keepdir /var/lib/infinote
		fowners infinote:infinote /var/lib/infinote
		fperms 770 /var/lib/infinote

		dosym /usr/bin/infinoted-${MY_PV} /usr/bin/infinoted

		elog "Add local users who should have local access to the documents"
		elog "created by infinoted to the infinote group."
		elog "The documents are saved in /var/lib/infinote per default."
	fi
}