[gentoo-commits] repo/gentoo:master commit in: app-portage/elogv/

[Sebastian Pipping]

commit:     aa8d33ba7b5b83a6dd5cdb2ea0bec36b0c2c108a
Author:     Sebastian Pipping <sping <AT> gentoo <DOT> org>
AuthorDate: Sat Nov 30 18:56:37 2019 +0000
Commit:     Sebastian Pipping <sping <AT> gentoo <DOT> org>
CommitDate: Sat Nov 30 18:56:37 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=aa8d33ba

app-portage/elogv: py38 + missing dependency

Closes: https://bugs.gentoo.org/701584
Signed-off-by: Sebastian Pipping <sping <AT> gentoo.org>
Package-Manager: Portage-2.3.80, Repoman-2.3.19

 app-portage/elogv/elogv-0.7.8-r2.ebuild | 55 +++++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)

diff --git a/app-portage/elogv/elogv-0.7.8-r2.ebuild b/app-portage/elogv/elogv-0.7.8-r2.ebuild
new file mode 100644
index 00000000000..04a1a84d43f
--- /dev/null
+++ b/app-portage/elogv/elogv-0.7.8-r2.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{5,6,7,8} )
+PYTHON_REQ_USE="ncurses"
+inherit distutils-r1
+
+DESCRIPTION="Curses based utility to parse the contents of elogs created by Portage"
+HOMEPAGE="https://github.com/gentoo/elogv"
+SRC_URI="https://github.com/gentoo/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
+
+RDEPEND="sys-apps/portage[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}"
+
+DOCS=( README )
+
+src_install() {
+	distutils-r1_src_install
+
+	# unset LINGUAS => install all languages
+	# empty LINGUAS => install none
+	local i
+	if [[ -n "${LINGUAS+x}" ]] ; then
+		for i in $(ls "${ED}"/usr/share/locale/) ; do
+			if ! has ${i} ${LINGUAS} ; then
+				rm -rf "${ED}"/usr/share/{locale,man}/${i}
+			fi
+		done
+	fi
+}
+
+pkg_postinst() {
+	elog "Optional dependencies:"
+	elog "  dev-python/pyliblzma (for xz compressed elog files)"
+	elog
+	elog "In order to use this software, you need to activate"
+	elog "Portage's elog features.  Required is"
+	elog "		 PORTAGE_ELOG_SYSTEM=\"save\" "
+	elog "and at least one out of "
+	elog "		 PORTAGE_ELOG_CLASSES=\"warn error info log qa\""
+	elog "More information on the elog system can be found"
+	elog "in ${EPREFIX}/usr/share/portage/config/make.conf.example"
+	elog
+	elog "To operate properly this software needs the directory"
+	elog "${PORT_LOGDIR:-${EPREFIX}/var/log/portage}/elog created, belonging to group portage."
+	elog "To start the software as a user, add yourself to the portage"
+	elog "group."
+	elog
+}