[gentoo-commits] repo/gentoo:master commit in: dev-libs/efl/

[Mike Frysinger]

commit:     d4e1d228529cebe60c821c0af956bfa2295c241a
Author:     Mike Frysinger <vapier <AT> gentoo <DOT> org>
AuthorDate: Fri Oct  9 12:43:00 2015 +0000
Commit:     Mike Frysinger <vapier <AT> gentoo <DOT> org>
CommitDate: Fri Oct  9 12:50:15 2015 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d4e1d228

dev-libs/efl: version bump to 1.15.2 #562434

 dev-libs/efl/Manifest          |   1 +
 dev-libs/efl/efl-1.15.2.ebuild | 252 +++++++++++++++++++++++++++++++++++++++++
 2 files changed, 253 insertions(+)

diff --git a/dev-libs/efl/Manifest b/dev-libs/efl/Manifest
index 224a8b3..a6e04d0 100644
--- a/dev-libs/efl/Manifest
+++ b/dev-libs/efl/Manifest
@@ -3,3 +3,4 @@ DIST efl-1.12.2.tar.bz2 46808743 SHA256 aa1a6b95de3d92dda819e1245254e3d9c0d68f77
 DIST efl-1.13.1.tar.xz 40332672 SHA256 7e06e11678063fd74522f8fc56eb3d0235e9d7f889639e2ecff4bb663a2568d6 SHA512 29324acdeffa287f4ef9c72938cfc18ab4f8ae40a0b2ddbdeccb323361bfe10da43b65a419561e04a7c2c148b1a9bc820a71ad735fbf2988940e982b73e2b2f5 WHIRLPOOL 10639471666c7aae6283f4ff442b10fea7e5159f36207a676030a9a6961e86faee72026b1bdd4c512f0831db7a945dbf53e2e3da67defb4527d3adc72ee52756
 DIST efl-1.15.0.tar.xz 43130156 SHA256 5d9580e9ba961fc64222d54a73849c730477c209dde89cc123dde14f22d532bc SHA512 59f28ddee01b4b5f1d7117a9e4c051e7074fbd5712dae7d9f99f0a4d09d41963cc411eeec664f3e1c57e84ad6ebde9c58ddcc9931eef0468817a90fe96a1dfdd WHIRLPOOL 113a0da4c0f2a7b22bcfd12b2f83a85a999979ec97a423cd53310e9ef9d15d8f1d0db5dd035bc931116d4a79b435144366c1930ffe3f11d48fd439ca37124e36
 DIST efl-1.15.1.tar.xz 43177472 SHA256 56efb5a88328f8ed04552d6e10d7b9ff2d3c7ed9da669ae06d457b9a801554d8 SHA512 72fdb7107ec818f2c97ff88521ca505a1f4b7705a3eede7ab1c22a6d98aa1b4245dac431d95f682c49767a0621a81843c0bd1eb44a98f9fe71380a1c5a253bd7 WHIRLPOOL 19eff46b6e96ff6b80e6d27f516632e7c83b449d39a28a8d595a9871401de9230799bf0bbc926d688c626d20db83f1bab8dad4ef5f07e4086737c3f75a9082a4
+DIST efl-1.15.2.tar.xz 43176564 SHA256 dd738f19f454621a7fa1fdb4c008457c170989f5f0c535edfed7b6773ae6c2a4 SHA512 bee8d7473bac73545ca02180f42614b7ae6ee0628fe8879b35bbf6809353535df8b1fa01f19ddc81d2ee1ecb5e36512b63c3be4b6b982f4efe8e410aa8ad5c56 WHIRLPOOL 380debdded1989412579cbe17d057512acb8381527c6c50606e6e936ea8bd0f1f1077861ca9afbb5661f404eb658c0dc288d991b204fbca72506d7b89f511df2

diff --git a/dev-libs/efl/efl-1.15.2.ebuild b/dev-libs/efl/efl-1.15.2.ebuild
new file mode 100644
index 0000000..fcf0d81
--- /dev/null
+++ b/dev-libs/efl/efl-1.15.2.ebuild
@@ -0,0 +1,252 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+
+MY_P=${P/_/-}
+
+if [[ "${PV}" == "9999" ]] ; then
+	EGIT_SUB_PROJECT="core"
+	EGIT_URI_APPEND="${PN}"
+elif [[ *"${PV}" == *"_pre"* ]] ; then
+	MY_P=${P%%_*}
+	SRC_URI="https://download.enlightenment.org/pre-releases/${MY_P}.tar.xz"
+	EKEY_STATE="snap"
+else
+	SRC_URI="https://download.enlightenment.org/rel/libs/${PN}/${MY_P}.tar.xz"
+	EKEY_STATE="snap"
+fi
+
+inherit enlightenment
+
+DESCRIPTION="Enlightenment Foundation Libraries all-in-one package"
+
+LICENSE="BSD-2 GPL-2 LGPL-2.1 ZLIB"
+IUSE="+bmp debug drm +eet egl fbcon +fontconfig fribidi gif gles glib gnutls gstreamer harfbuzz +ico ibus jpeg2k libressl neon oldlua opengl ssl physics pixman +png +ppm +psd pulseaudio scim sdl sound systemd tga tiff tslib v4l2 valgrind wayland webp X xim xine xpm"
+
+REQUIRED_USE="
+	pulseaudio?	( sound )
+	opengl?		( || ( X sdl wayland ) )
+	gles?		( || ( X wayland ) )
+	gles?		( !sdl )
+	gles?		( egl )
+	sdl?		( opengl )
+	wayland?	( egl !opengl gles )
+	xim?		( X )
+"
+
+RDEPEND="
+	drm? (
+		>=dev-libs/libinput-0.8
+		media-libs/mesa[gbm]
+		>=x11-libs/libdrm-2.4
+		>=x11-libs/libxkbcommon-0.3.0
+	)
+	fontconfig? ( media-libs/fontconfig )
+	fribidi? ( dev-libs/fribidi )
+	gif? ( media-libs/giflib )
+	glib? ( dev-libs/glib:2 )
+	gnutls? ( net-libs/gnutls )
+	!gnutls? (
+		ssl? (
+			!libressl? ( dev-libs/openssl:0 )
+			libressl? ( dev-libs/libressl )
+		)
+	)
+	gstreamer? (
+		media-libs/gstreamer:1.0
+		media-libs/gst-plugins-base:1.0
+	)
+	harfbuzz? ( media-libs/harfbuzz )
+	ibus? ( app-i18n/ibus )
+	jpeg2k? ( media-libs/openjpeg:0 )
+	!oldlua? ( >=dev-lang/luajit-2.0.0 )
+	oldlua? ( dev-lang/lua )
+	physics? ( >=sci-physics/bullet-2.80 )
+	pixman? ( x11-libs/pixman )
+	png? ( media-libs/libpng:0= )
+	pulseaudio? ( media-sound/pulseaudio )
+	scim? ( app-i18n/scim )
+	sdl? (
+		media-libs/libsdl2
+		virtual/opengl
+	)
+	sound? ( media-libs/libsndfile )
+	systemd? ( sys-apps/systemd )
+	tiff? ( media-libs/tiff:0 )
+	tslib? ( x11-libs/tslib )
+	valgrind? ( dev-util/valgrind )
+	wayland? (
+		>=dev-libs/wayland-1.8.0
+		>=x11-libs/libxkbcommon-0.3.1
+		media-libs/mesa[gles2,wayland]
+	)
+	webp? ( media-libs/libwebp )
+	X? (
+		x11-libs/libXcursor
+		x11-libs/libX11
+		x11-libs/libXcomposite
+		x11-libs/libXdamage
+		x11-libs/libXext
+		x11-libs/libXfixes
+		x11-libs/libXinerama
+		x11-libs/libXp
+		x11-libs/libXrandr
+		x11-libs/libXrender
+		x11-libs/libXtst
+		x11-libs/libXScrnSaver
+
+		opengl? (
+			x11-libs/libX11
+			x11-libs/libXrender
+			virtual/opengl
+		)
+
+		gles? (
+			x11-libs/libX11
+			x11-libs/libXrender
+			virtual/opengl
+		)
+	)
+	xine? ( >=media-libs/xine-lib-1.1.1 )
+	xpm? ( x11-libs/libXpm )
+
+	sys-apps/dbus
+	>=sys-apps/util-linux-2.20.0
+	sys-libs/zlib
+	virtual/jpeg
+
+	!dev-libs/ecore
+	!dev-libs/edbus
+	!dev-libs/eet
+	!dev-libs/eeze
+	!dev-libs/efreet
+	!dev-libs/eina
+	!dev-libs/eio
+	!dev-libs/embryo
+	!dev-libs/eobj
+	!dev-libs/ephysics
+	!media-libs/edje
+	!media-libs/emotion
+	!media-libs/ethumb
+	!media-libs/evas
+"
+#external lz4 support currently broken because of unstable ABI/API
+#	app-arch/lz4
+
+#soft blockers added above for binpkg users
+#hard blocks are needed for building
+CORE_EFL_CONFLICTS="
+	!!dev-libs/ecore
+	!!dev-libs/edbus
+	!!dev-libs/eet
+	!!dev-libs/eeze
+	!!dev-libs/efreet
+	!!dev-libs/eina
+	!!dev-libs/eio
+	!!dev-libs/embryo
+	!!dev-libs/eobj
+	!!dev-libs/ephysics
+	!!media-libs/edje
+	!!media-libs/emotion
+	!!media-libs/ethumb
+	!!media-libs/evas
+"
+
+DEPEND="
+	${CORE_EFL_CONFLICTS}
+
+	${RDEPEND}
+	doc? ( app-doc/doxygen )
+"
+
+S=${WORKDIR}/${MY_P}
+
+src_configure() {
+	if use ssl && use gnutls ; then
+		einfo "You enabled both USE=ssl and USE=gnutls, but only one can be used;"
+		einfo "gnutls has been selected for you."
+	fi
+	if use opengl && use gles ; then
+		einfo "You enabled both USE=opengl and USE=gles, but only one can be used;"
+		einfo "opengl has been selected for you."
+	fi
+
+	E_ECONF=(
+		--with-profile=$(usex debug debug release)
+		--with-crypto=$(usex gnutls gnutls $(usex ssl openssl none))
+		--with-x11=$(usex X xlib none)
+		$(use_with X x)
+		--with-opengl=$(usex opengl full $(usex gles es none))
+		--with-glib=$(usex glib)
+		--enable-i-really-know-what-i-am-doing-and-that-this-will-probably-break-things-and-i-will-fix-them-myself-and-send-patches-aba
+
+		$(use_enable bmp image-loader-bmp)
+		$(use_enable bmp image-loader-wbmp)
+		$(use_enable drm)
+		$(use_enable doc)
+		$(use_enable eet image-loader-eet)
+		$(use_enable egl)
+		$(use_enable fbcon fb)
+		$(use_enable fontconfig)
+		$(use_enable fribidi)
+		$(use_enable gif image-loader-gif)
+		$(use_enable gstreamer gstreamer1)
+		$(use_enable harfbuzz)
+		$(use_enable ico image-loader-ico)
+		$(use_enable ibus)
+		$(use_enable jpeg2k image-loader-jp2k)
+		$(use_enable neon)
+		$(use_enable nls)
+		$(use_enable oldlua lua-old)
+		$(use_enable physics)
+		$(use_enable pixman)
+		$(use_enable pixman pixman-font)
+		$(use_enable pixman pixman-rect)
+		$(use_enable pixman pixman-line)
+		$(use_enable pixman pixman-poly)
+		$(use_enable pixman pixman-image)
+		$(use_enable pixman pixman-image-scale-sample)
+		$(use_enable png image-loader-png)
+		$(use_enable ppm image-loader-pmaps)
+		$(use_enable psd image-loader-psd)
+		$(use_enable pulseaudio)
+		$(use_enable scim)
+		$(use_enable sdl)
+		$(use_enable sound audio)
+		$(use_enable systemd)
+		$(use_enable tga image-loader-tga)
+		$(use_enable tiff image-loader-tiff)
+		$(use_enable tslib)
+		$(use_enable v4l2)
+		$(use_enable valgrind)
+		$(use_enable wayland)
+		$(use_enable webp image-loader-webp)
+		$(use_enable xim)
+		$(use_enable xine)
+		$(use_enable xpm image-loader-xpm)
+		--enable-cserve
+		--enable-image-loader-generic
+		--enable-image-loader-jpeg
+
+		--disable-tizen
+		--disable-gesture
+		--disable-gstreamer
+		--enable-xinput2
+		--disable-xinput22
+		--disable-multisense
+		--enable-libmount
+
+		# external lz4 support currently broken because of unstable ABI/API
+		#--enable-liblz4
+	)
+
+	enlightenment_src_configure
+}
+
+src_install() {
+	MAKEOPTS+=" -j1"
+
+	enlightenment_src_install
+}