[gentoo-commits] repo/gentoo:master commit in: games-strategy/colobot/

[Michał Górny]

commit:     c392566ae167b0792b8a6ab26615886f974f4bee
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sun Aug 22 06:36:31 2021 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sun Aug 22 06:45:27 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c392566a

games-strategy/colobot: Bump to 0.2.0-alpha

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 games-strategy/colobot/Manifest                   |  1 +
 games-strategy/colobot/colobot-0.2.0_alpha.ebuild | 73 +++++++++++++++++++++++
 2 files changed, 74 insertions(+)

diff --git a/games-strategy/colobot/Manifest b/games-strategy/colobot/Manifest
index 7d725fdff60..980ba6938fa 100644
--- a/games-strategy/colobot/Manifest
+++ b/games-strategy/colobot/Manifest
@@ -1 +1,2 @@
 DIST colobot-gold-0.1.12-alpha.tar.gz 1468594 BLAKE2B 2b470e8b074e4a973b751062dca2358396066d8816c2b1b5b44649b798610dccd73ab5fed4086f2aa8d4495f3de69dd8b72b45f97f23f66b18a50fc976bf25ef SHA512 63647a16b376db6544830f96e7d323c0f58003645bf636abd1cab0ffd47b39b0bef47191d584f5156b75324d75dfdfdcabe8b89be565087c37c367ca366f3cbe
+DIST colobot-gold-0.2.0-alpha.tar.gz 1514455 BLAKE2B 9cc1480d342cfa14b12e437c41ce8e65b173cd30ca5f62e574ac17f452e6cd0622b5c2706fcfd427222cf78fce1700cb07b82fac75dd9b4a3ace4389ea3381bc SHA512 9c35ce6da319ef20ff68a9722f0b683adaa2fcada2b89bb322ba5772dfd9371adacd045ae160550780083902c024400c29e1d1f11dcb8b6547ba7d48e401c4c3

diff --git a/games-strategy/colobot/colobot-0.2.0_alpha.ebuild b/games-strategy/colobot/colobot-0.2.0_alpha.ebuild
new file mode 100644
index 00000000000..3897d69816c
--- /dev/null
+++ b/games-strategy/colobot/colobot-0.2.0_alpha.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake xdg-utils
+
+MY_P=colobot-gold-${PV/_/-}
+DESCRIPTION="A real-time strategy game, where you can program your bots"
+HOMEPAGE="https://colobot.info/"
+SRC_URI="https://github.com/colobot/colobot/archive/${MY_P}.tar.gz"
+S=${WORKDIR}/${PN}-${MY_P}
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="devbuild doc +openal test tools"
+RESTRICT="!test? ( test )"
+
+# perl for pod2man
+BDEPEND="
+	app-text/po4a
+	dev-lang/perl
+	sys-devel/gettext"
+DEPEND="
+	dev-games/physfs
+	dev-libs/boost:=
+	media-libs/glew:0
+	media-libs/libogg
+	media-libs/libpng:0=
+	media-libs/libsdl2:=
+	media-libs/libsndfile:=
+	media-libs/libvorbis:=
+	media-libs/sdl2-image
+	media-libs/sdl2-ttf
+	media-sound/vorbis-tools
+	openal? ( media-libs/openal )"
+RDEPEND="${DEPEND}
+	~games-strategy/colobot-data-${PV}"
+
+PATCHES=(
+	# https://github.com/colobot/colobot/pull/1453
+	"${FILESDIR}"/colobot-0.1.12-sndfile-link.patch
+)
+
+src_prepare() {
+	cmake_src_prepare
+
+	# we need to call it explicitly to help Ninja figure out the deps
+	cd desktop || die
+	po4a po4a.cfg || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DDEV_BUILD=$(usex devbuild)
+		-DTESTS=$(usex test)
+		-DTOOLS=$(usex tools)
+		-DINSTALL_DOCS=$(usex doc)
+		-DOPENAL_SOUND=$(usex openal)
+		-DCOLOBOT_INSTALL_BIN_DIR="${EPREFIX}"/usr/bin
+		-DCOLOBOT_INSTALL_LIB_DIR="${EPREFIX}"/usr/$(get_libdir)
+	)
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}