[gentoo-commits] repo/gentoo:master commit in: dev-python/oslo-utils/

[Matt Thode]

commit:     ac595048c0f06a3c13a65b5f7b6ea89e10a8a29e
Author:     Matthew Thode <prometheanfire <AT> gentoo <DOT> org>
AuthorDate: Thu Jul  6 16:24:48 2017 +0000
Commit:     Matt Thode <prometheanfire <AT> gentoo <DOT> org>
CommitDate: Thu Jul  6 16:57:37 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ac595048

dev-python/oslo-utils: 3.22.1 bup

Package-Manager: Portage-2.3.6, Repoman-2.3.2

 dev-python/oslo-utils/Manifest                 |  1 +
 dev-python/oslo-utils/oslo-utils-3.22.1.ebuild | 95 ++++++++++++++++++++++++++
 2 files changed, 96 insertions(+)

diff --git a/dev-python/oslo-utils/Manifest b/dev-python/oslo-utils/Manifest
index 8167f33206b..459124c42f0 100644
--- a/dev-python/oslo-utils/Manifest
+++ b/dev-python/oslo-utils/Manifest
@@ -1 +1,2 @@
 DIST oslo-utils-3.22.0.tar.gz 84490 SHA256 aa72be266fee787541c02baa9ac341ec4b1b01b0d5a097db459aee05b27b12fb SHA512 09b53b5a322133ace2d68bba871746b88f709b50385b93bea0c4398ceb6a848a3019f2fc68f0bb645963a95432b9e616e733720ebb57aff61108d8e22bc11e70 WHIRLPOOL b464196269e165db0aaa9807a5e284f5905f5aaf95e6fd66cf3580838eb07611dacc3f69f2d21c7516c75694d6d246cb6c719756fca61b136388875a2e921236
+DIST oslo-utils-3.22.1.tar.gz 84249 SHA256 9825db6337ce10e7c383d2598f87865605d35af15fa9ece7212838ba7d33730e SHA512 afb21f8267f815e192a667fec247ae2e0d8163d7872805d36c4399928b475e34790136810607e8706ea37e32eb31da2fdc2b9defb2e06f7ba0a7235b2de1abc9 WHIRLPOOL 501cb7c18b2997635b5a2ffd91fd472f84168730e2cc76cb13f4937e657448e535d614e9eea64595bce31211af4e1ce0590cb8e313dd31785fe7700c4776585a

diff --git a/dev-python/oslo-utils/oslo-utils-3.22.1.ebuild b/dev-python/oslo-utils/oslo-utils-3.22.1.ebuild
new file mode 100644
index 00000000000..605a8deb92e
--- /dev/null
+++ b/dev-python/oslo-utils/oslo-utils-3.22.1.ebuild
@@ -0,0 +1,95 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} )
+
+inherit distutils-r1 vcs-snapshot
+
+MY_PN=${PN/-/.}
+
+DESCRIPTION="Oslo Utility library"
+HOMEPAGE="https://launchpad.net/oslo"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_PN}-${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="doc test"
+
+CDEPEND=">=dev-python/pbr-1.8[${PYTHON_USEDEP}]"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	${CDEPEND}
+	test? (
+		>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+		>=dev-python/subunit-0.0.18[${PYTHON_USEDEP}]
+		>=dev-python/testrepository-0.0.18[${PYTHON_USEDEP}]
+		>=dev-python/testscenarios-0.4[${PYTHON_USEDEP}]
+		>=dev-python/testtools-1.4.0[${PYTHON_USEDEP}]
+		>=dev-python/oslotest-1.10.0[${PYTHON_USEDEP}]
+		>=dev-python/coverage-4.0.0[${PYTHON_USEDEP}]
+		>=dev-python/mock-2.0.0[${PYTHON_USEDEP}]
+		>=dev-python/oslo-config-3.14.0[${PYTHON_USEDEP}]
+		!~dev-python/oslo-config-3.18.0[${PYTHON_USEDEP}]
+		>=dev-python/bandit-1.1.0[${PYTHON_USEDEP}]
+		>=dev-python/reno-1.8.0[${PYTHON_USEDEP}]
+	)
+	doc? (
+		>=dev-python/oslo-sphinx-4.7.0[${PYTHON_USEDEP}]
+		>=dev-python/sphinx-1.2.1[${PYTHON_USEDEP}]
+		<dev-python/sphinx-1.4[${PYTHON_USEDEP}]
+		>=dev-python/reno-1.8.0[${PYTHON_USEDEP}]
+	)
+"
+RDEPEND="
+	${CDEPEND}
+	>=dev-python/six-1.9.0[${PYTHON_USEDEP}]
+	virtual/python-funcsigs[${PYTHON_USEDEP}]
+	>=dev-python/iso8601-0.1.11[${PYTHON_USEDEP}]
+	>=dev-python/oslo-i18n-2.1.0[${PYTHON_USEDEP}]
+	>=dev-python/monotonic-0.6[${PYTHON_USEDEP}]
+	>=dev-python/pytz-2013.6[${PYTHON_USEDEP}]
+	>=dev-python/netaddr-0.7.13[${PYTHON_USEDEP}]
+	!~dev-python/netaddr-0.7.16[${PYTHON_USEDEP}]
+	>=dev-python/netifaces-0.10.4[${PYTHON_USEDEP}]
+	>=dev-python/debtcollector-1.2.0[${PYTHON_USEDEP}]
+	>=dev-python/pyparsing-2.1.0[${PYTHON_USEDEP}]
+"
+
+python_prepare_all() {
+	sed -i '/^hacking/d' test-requirements.txt || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && esetup.py build_sphinx
+}
+
+# Note: Tests fail due to requiring installation
+#
+# Installation appears to fail due to the use of namespace packages but root
+# cause was never truly established.
+#
+# Tests fail with:
+# ImportError: No module named 'oslo.utils
+
+#RESTRICT="test"
+
+python_test() {
+	distutils_install_for_testing
+
+	cd "${TEST_DIR}"/lib || die
+
+	rm -rf .testrepository || die "couldn't remove '.testrepository' under ${EPTYHON}"
+
+	testr init || die "testr init failed under ${EPYTHON}"
+	testr run || die "testr run failed under ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( doc/build/html/. )
+
+	distutils-r1_python_install_all
+}