[gentoo-commits] repo/gentoo:master commit in: dev-python/pandas/

[Michał Górny]

commit:     5b1966a25a6ab7268fb8490f6c793fe240836faa
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Mon Nov  2 10:30:49 2020 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Mon Nov  2 10:34:21 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5b1966a2

dev-python/pandas: Remove old

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/pandas/Manifest            |   1 -
 dev-python/pandas/pandas-1.1.1.ebuild | 181 ----------------------------------
 2 files changed, 182 deletions(-)

diff --git a/dev-python/pandas/Manifest b/dev-python/pandas/Manifest
index 5134cc5e650..c2f3bfb9f35 100644
--- a/dev-python/pandas/Manifest
+++ b/dev-python/pandas/Manifest
@@ -1,4 +1,3 @@
 DIST pandas-1.0.5.tar.gz 5007108 BLAKE2B 6aff9602f8b1642af1dca70c7c596f2978bfef8ca9bc782d55aeeab85d3768289849ccd0150291c33cab3442d38cedada91fb846abaade1b3905098edb06c06e SHA512 bb9e3ed9988f7b878ac6f9d7c6c054b119acfc4b960ae42ea92436979ef2098289123cac32b176753942a1edb3b6bd35c4eaf05112a25fbf8a89078fd76a2646
-DIST pandas-1.1.1.tar.gz 5213685 BLAKE2B 6604c7def761f8eef4596a9ad6c1afe1f59fdd6181f9cdc9edfa97939a9e668e745ebc0abd8664eda4f864be54740d46e4aa10f32728306b897e397bd6e1f682 SHA512 db93e66956d832da594f04aaa5cb895ea22f66acd0e97ad76f22153f9e872e46845dad5b952b54463ec8ef3e2a73a766eea8d53e980a5508e3a3346429a07999
 DIST pandas-1.1.2.tar.gz 5220166 BLAKE2B 3351bf0e539335b7f13dd6e6590309989c3bd5d36c0fd188808be14a147b828f1a3a14007fc499e2b5f580072b02de8587885629a8ffb1fc70b2577fbd034001 SHA512 a81e9f82b866cc48eaf55c288610b150fe3fa6ba6100c0b13516eb0ce4b569397127b85161e53454d0b2b24f276aa9806baa007a521623aad2345e7b7168cbb5
 DIST pandas-1.1.4.tar.gz 5226971 BLAKE2B 9386eefdd1be566dee7e950d6c791a1127f5736b61a2f062f0cfbf1a83879c68b39fade863ed77acc38f619b681060b0e73ff290fbcba6d8d2d2d3332f4e32e4 SHA512 abc6e23ccc066bd9aaea5688df4803ef2fe2f038df9f45bd59696e94b589174d9bc79bfe6b36315307ab39b31a4e8cf32217f9135ac977320bf29968e12cb271

diff --git a/dev-python/pandas/pandas-1.1.1.ebuild b/dev-python/pandas/pandas-1.1.1.ebuild
deleted file mode 100644
index 347189e6299..00000000000
--- a/dev-python/pandas/pandas-1.1.1.ebuild
+++ /dev/null
@@ -1,181 +0,0 @@
-# Copyright 1999-2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-PYTHON_COMPAT=( python3_{6..9} )
-PYTHON_REQ_USE="threads(+)"
-
-VIRTUALX_REQUIRED="manual"
-DISTUTILS_USE_SETUPTOOLS=rdepend
-
-inherit distutils-r1 flag-o-matic multiprocessing optfeature virtualx
-
-DESCRIPTION="Powerful data structures for data analysis and statistics"
-HOMEPAGE="https://pandas.pydata.org/"
-SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P/_/}.tar.gz"
-S="${WORKDIR}/${P/_/}"
-
-SLOT="0"
-LICENSE="BSD"
-KEYWORDS="~amd64 ~arm ~arm64 x86"
-IUSE="doc full-support minimal test X"
-RESTRICT="!test? ( test )"
-
-RECOMMENDED_DEPEND="
-	>=dev-python/bottleneck-1.2.1[${PYTHON_USEDEP}]
-	>=dev-python/numexpr-2.1[${PYTHON_USEDEP}]
-"
-
-# TODO: add pandas-gbq to the tree
-OPTIONAL_DEPEND="
-	dev-python/beautifulsoup:4[${PYTHON_USEDEP}]
-	dev-python/blosc[${PYTHON_USEDEP}]
-	|| (
-		dev-python/html5lib[${PYTHON_USEDEP}]
-		dev-python/lxml[${PYTHON_USEDEP}]
-	)
-	dev-python/jinja[${PYTHON_USEDEP}]
-	dev-python/matplotlib[${PYTHON_USEDEP}]
-	|| (
-		dev-python/openpyxl[${PYTHON_USEDEP}]
-		dev-python/xlsxwriter[${PYTHON_USEDEP}]
-	)
-	>=dev-python/pytables-3.2.1[${PYTHON_USEDEP}]
-	dev-python/s3fs[${PYTHON_USEDEP}]
-	dev-python/statsmodels[${PYTHON_USEDEP}]
-	$(python_gen_cond_dep '
-		>=dev-python/xarray-0.10.8[${PYTHON_USEDEP}]
-	' python3_{6,7})
-	>=dev-python/sqlalchemy-0.8.1[${PYTHON_USEDEP}]
-	>=dev-python/xlrd-1.0.0[${PYTHON_USEDEP}]
-	dev-python/xlwt[${PYTHON_USEDEP}]
-	>=dev-python/scipy-1.1[${PYTHON_USEDEP}]
-	X? (
-		|| (
-			dev-python/PyQt5[${PYTHON_USEDEP}]
-			x11-misc/xclip
-			x11-misc/xsel
-		)
-	)
-"
-COMMON_DEPEND="
-	>dev-python/numpy-1.15.4[${PYTHON_USEDEP}]
-	dev-python/python-dateutil[${PYTHON_USEDEP}]
-	dev-python/pytz[${PYTHON_USEDEP}]
-"
-DEPEND="${COMMON_DEPEND}
-	>=dev-python/cython-0.29.20-r1[${PYTHON_USEDEP}]
-	doc? (
-		${VIRTUALX_DEPEND}
-		app-text/pandoc
-		dev-python/beautifulsoup:4[${PYTHON_USEDEP}]
-		dev-python/html5lib[${PYTHON_USEDEP}]
-		dev-python/ipython[${PYTHON_USEDEP}]
-		dev-python/lxml[${PYTHON_USEDEP}]
-		dev-python/matplotlib[${PYTHON_USEDEP}]
-		dev-python/nbsphinx[${PYTHON_USEDEP}]
-		>=dev-python/numpydoc-0.9.1[${PYTHON_USEDEP}]
-		>=dev-python/openpyxl-1.6.1[${PYTHON_USEDEP}]
-		>=dev-python/pytables-3.0.0[${PYTHON_USEDEP}]
-		dev-python/pytz[${PYTHON_USEDEP}]
-		dev-python/rpy[${PYTHON_USEDEP}]
-		dev-python/sphinx[${PYTHON_USEDEP}]
-		dev-python/xlrd[${PYTHON_USEDEP}]
-		dev-python/xlwt[${PYTHON_USEDEP}]
-		dev-python/scipy[${PYTHON_USEDEP}]
-		x11-misc/xclip
-	)
-	test? (
-		${VIRTUALX_DEPEND}
-		${RECOMMENDED_DEPEND}
-		${OPTIONAL_DEPEND}
-		dev-python/beautifulsoup:4[${PYTHON_USEDEP}]
-		dev-python/hypothesis[${PYTHON_USEDEP}]
-		dev-python/nose[${PYTHON_USEDEP}]
-		dev-python/openpyxl[${PYTHON_USEDEP}]
-		dev-python/pymysql[${PYTHON_USEDEP}]
-		dev-python/pytest[${PYTHON_USEDEP}]
-		dev-python/pytest-mock[${PYTHON_USEDEP}]
-		dev-python/pytest-xdist[${PYTHON_USEDEP}]
-		dev-python/psycopg:2[${PYTHON_USEDEP}]
-		dev-python/xlsxwriter[${PYTHON_USEDEP}]
-		x11-misc/xclip
-		x11-misc/xsel
-	)
-"
-# dev-python/statsmodels invokes a circular dep
-#  hence rm from doc? ( ), again
-RDEPEND="${COMMON_DEPEND}
-	!minimal? ( ${RECOMMENDED_DEPEND} )
-	full-support? ( ${OPTIONAL_DEPEND} )
-"
-
-python_prepare_all() {
-	# Prevent un-needed download during build
-	sed -e "/^              'sphinx.ext.intersphinx',/d" \
-		-i doc/source/conf.py || die
-
-	# requires package installed
-	sed -e 's:test_register_entrypoint:_&:' \
-		-i pandas/tests/plotting/test_backend.py || die
-
-	sed -e '/extra_compile_args =/s:"-Werror"::' \
-		-i setup.py || die
-
-	distutils-r1_python_prepare_all
-}
-
-python_compile_all() {
-	# To build docs the need be located in $BUILD_DIR,
-	# else PYTHONPATH points to unusable modules.
-	if use doc; then
-		cd "${BUILD_DIR}"/lib || die
-		cp -ar "${S}"/doc . && cd doc || die
-		LANG=C PYTHONPATH=. virtx ${EPYTHON} make.py html
-	fi
-}
-
-src_test() {
-	virtx distutils-r1_src_test
-}
-
-python_test() {
-	local -x LC_ALL=C.UTF-8
-	pushd  "${BUILD_DIR}"/lib > /dev/null || die
-	"${EPYTHON}" -c "import pandas; pandas.show_versions()" || die
-	PYTHONPATH=. pytest pandas -v --skip-slow --skip-network \
-		-n "$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")" \
-		-m "not single" || die "Tests failed with ${EPYTHON}"
-	find . '(' -name .pytest_cache -o -name .hypothesis ')' \
-		-exec rm -r {} + || die
-	popd > /dev/null || die
-}
-
-python_install_all() {
-	if use doc; then
-		dodoc -r "${BUILD_DIR}"/lib/doc/build/html
-		einfo "An initial build of docs is absent of references to statsmodels"
-		einfo "due to circular dependency. To have them included, emerge"
-		einfo "statsmodels next and re-emerge pandas with USE doc"
-	fi
-
-	distutils-r1_python_install_all
-}
-
-pkg_postinst() {
-	optfeature "accelerating certain types of NaN evaluations, using specialized cython routines to achieve large speedups." dev-python/bottleneck
-	optfeature "accelerating certain numerical operations, using multiple cores as well as smart chunking and caching to achieve large speedups" ">=dev-python/numexpr-2.1"
-	optfeature "needed for pandas.io.html.read_html" dev-python/beautifulsoup:4 dev-python/html5lib dev-python/lxml
-	optfeature "for msgpack compression using blosc" dev-python/blosc
-	optfeature "necessary for Amazon S3 access" dev-python/s3fs
-	optfeature "Template engine for conditional HTML formatting" dev-python/jinja
-	optfeature "Plotting support" dev-python/matplotlib
-	optfeature "Needed for Excel I/O" ">=dev-python/openpyxl-1.6.1" dev-python/xlsxwriter dev-python/xlrd dev-python/xlwt
-	optfeature "necessary for HDF5-based storage" ">=dev-python/pytables-3.2.1"
-	optfeature "R I/O support" dev-python/rpy
-	optfeature "Needed for parts of pandas.stats" dev-python/statsmodels
-	optfeature "SQL database support" ">=dev-python/sqlalchemy-0.8.1"
-	optfeature "miscellaneous statistical functions" dev-python/scipy
-	optfeature "necessary to use pandas.io.clipboard.read_clipboard support" dev-python/PyQt5 dev-python/pygtk x11-misc/xclip x11-misc/xsel
-}