[gentoo-commits] gentoo-x86 commit in dev-util/dialog: dialog-1.2.20150528.ebuild ChangeLog dialog-1.2.20140219.ebuild dialog-1.2.20150125.ebuild dialog-1.2.20140911.ebuild

[Jeroen Roovers (jer)]

jer         15/06/01 04:41:55

  Modified:             ChangeLog
  Added:                dialog-1.2.20150528.ebuild
  Removed:              dialog-1.2.20140219.ebuild
                        dialog-1.2.20150125.ebuild
                        dialog-1.2.20140911.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key A792A613)

Revision  Changes    Path
1.234                dev-util/dialog/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/dialog/ChangeLog?rev=1.234&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/dialog/ChangeLog?rev=1.234&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/dialog/ChangeLog?r1=1.233&r2=1.234

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-util/dialog/ChangeLog,v
retrieving revision 1.233
retrieving revision 1.234
diff -u -r1.233 -r1.234
--- ChangeLog	27 May 2015 12:23:30 -0000	1.233
+++ ChangeLog	1 Jun 2015 04:41:55 -0000	1.234
@@ -1,6 +1,13 @@
 # ChangeLog for dev-util/dialog
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/dialog/ChangeLog,v 1.233 2015/05/27 12:23:30 zlogene Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/dialog/ChangeLog,v 1.234 2015/06/01 04:41:55 jer Exp $
+
+*dialog-1.2.20150528 (01 Jun 2015)
+
+  01 Jun 2015; Jeroen Roovers <jer@g.o> -dialog-1.2.20140219.ebuild,
+  -dialog-1.2.20140911.ebuild, -dialog-1.2.20150125.ebuild,
+  +dialog-1.2.20150528.ebuild:
+  Version bump.
 
   27 May 2015; Mikle Kolyada <zlogene@g.o> dialog-1.2.20150225.ebuild:
   arm stable wrt bug #547766



1.1                  dev-util/dialog/dialog-1.2.20150528.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/dialog/dialog-1.2.20150528.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/dialog/dialog-1.2.20150528.ebuild?rev=1.1&content-type=text/plain

Index: dialog-1.2.20150528.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/dialog/dialog-1.2.20150528.ebuild,v 1.1 2015/06/01 04:41:55 jer Exp $

EAPI=5
inherit eutils multilib versionator

MY_PV="$(get_version_component_range 1-2)-$(get_version_component_range 3)"
S=${WORKDIR}/${PN}-${MY_PV}
DESCRIPTION="tool to display dialog boxes from a shell"
HOMEPAGE="http://invisible-island.net/dialog/dialog.html"
SRC_URI="ftp://invisible-island.net/${PN}/${PN}-${MY_PV}.tgz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd"
IUSE="examples minimal nls static-libs unicode"

RDEPEND="
	>=sys-libs/ncurses-5.2-r5[unicode?]
"
DEPEND="
	${RDEPEND}
	nls? ( sys-devel/gettext )
	!minimal? ( sys-devel/libtool )
	!<=sys-freebsd/freebsd-contrib-8.9999
"

src_prepare() {
	sed -i -e '/LIB_CREATE=/s:${CC}:& ${LDFLAGS}:g' configure || die
	sed -i '/$(LIBTOOL_COMPILE)/s:$: $(LIBTOOL_OPTS):' makefile.in || die
}

src_configure() {
	econf \
		--disable-rpath-hack \
		$(use_enable nls) \
		$(use_with !minimal libtool) \
		--with-libtool-opts=$(usex static-libs '' '-shared') \
		--with-ncurses$(usex unicode w '')
}

src_install() {
	use minimal && default || emake DESTDIR="${D}" install-full

	use examples && dodoc -r samples

	dodoc CHANGES README

	prune_libtool_files
}