[gentoo-commits] repo/gentoo:master commit in: kde-apps/ark/

[Andreas Sturmlechner]

commit:     24802dd6cef7a60ca68ff9c34e6594c73035a7b9
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Mon Nov 29 16:03:16 2021 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Mon Nov 29 16:52:29 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=24802dd6

kde-apps/ark: 21.11.90 version bump

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 kde-apps/ark/Manifest            |  1 +
 kde-apps/ark/ark-21.11.90.ebuild | 80 ++++++++++++++++++++++++++++++++++++++++
 2 files changed, 81 insertions(+)

diff --git a/kde-apps/ark/Manifest b/kde-apps/ark/Manifest
index 356545762b05..afbbd3838066 100644
--- a/kde-apps/ark/Manifest
+++ b/kde-apps/ark/Manifest
@@ -1 +1,2 @@
 DIST ark-21.08.3.tar.xz 2769868 BLAKE2B 8e208bb9067bbde43e311aa88cd16bbf2957b434906b42114c08c518e301a89231627450885e3c145452fd538106b173a881da7d0100c670612cd08c3c342500 SHA512 4b434669e369636774df84d48ea277860886db29055f26d40f0ba08242eec9a6e6d7727b3e405148809e86db1e06f5517bf35ceefd17a722173c4de915f1eae9
+DIST ark-21.11.90.tar.xz 2771372 BLAKE2B 4aba62a9a788845b9bebd86d03fdbe98223ab95527e19556dcb57cfc359a99c80e6321fdad95b1aeb565418f1bd2159559303c25bdc00568172d9718ac512f1c SHA512 19f399bc639b11fba776afc57de40351cf7dc1372c1bc630373a46853c2f1e836428a739f22914642c58297771edcae7d4f962f4bd9c4f307b18294970f8ce03

diff --git a/kde-apps/ark/ark-21.11.90.ebuild b/kde-apps/ark/ark-21.11.90.ebuild
new file mode 100644
index 000000000000..49b1f4b18340
--- /dev/null
+++ b/kde-apps/ark/ark-21.11.90.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="optional"
+KFMIN=5.88.0
+QTMIN=5.15.2
+VIRTUALX_REQUIRED="test"
+inherit ecm kde.org optfeature
+
+DESCRIPTION="File archiver by KDE"
+HOMEPAGE="https://apps.kde.org/ark/ https://utils.kde.org/projects/ark/"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="zip"
+
+RDEPEND="
+	app-arch/libarchive:=[bzip2,lzma,zlib]
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/karchive-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kitemmodels-${KFMIN}:5
+	>=kde-frameworks/kjobwidgets-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/kpty-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	sys-libs/zlib
+	zip? ( >=dev-libs/libzip-1.2.0:= )
+"
+DEPEND="${RDEPEND}
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+	test? ( >=dev-libs/libzip-1.2.0:= )
+"
+BDEPEND="
+	sys-devel/gettext
+	test? ( amd64? ( app-arch/rar ) x86? ( app-arch/rar ) )
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package zip LibZip)
+	)
+
+	ecm_src_configure
+}
+
+src_test() {
+	local myctestargs=(
+		# bug 822177: may segfault or hang indefinitely
+		-E "(kerfuffle-addtoarchivetest)"
+	)
+
+	ecm_src_test
+}
+
+pkg_postinst() {
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		optfeature "rar archive creation/extraction" app-arch/rar
+		optfeature "rar archive extraction only" app-arch/unar app-arch/unrar
+		optfeature "7-Zip archive support" app-arch/p7zip
+		optfeature "lrz archive support" app-arch/lrzip
+		optfeature "markdown support in text previews" kde-misc/markdownpart:${SLOT} kde-misc/kmarkdownwebview:${SLOT}
+	fi
+	ecm_pkg_postinst
+}