Get Gentoo!
gentoo.org sites
gentoo.org Wiki Bugs Forums Packages
Planet Archives Sources
Infra Status

Gentoo Archives: gentoo-commits

From: "PaweA Hajdan (phajdan.jr)" <phajdan.jr@g.o>
To: gentoo-commits@l.g.o
Subject: [gentoo-commits] gentoo-x86 commit in www-client/chromium: ChangeLog chromium-17.0.942.0.ebuild chromium-17.0.932.0.ebuild
Date: Fri, 18 Nov 2011 19:20:14
Message-Id: 20111118192004.E570C20033@flycatcher.gentoo.org
1 phajdan.jr 11/11/18 19:20:04
2
3 Modified: ChangeLog
4 Added: chromium-17.0.942.0.ebuild
5 Removed: chromium-17.0.932.0.ebuild
6 Log:
7 Version bump for dev channel release. Remove old.
8
9 (Portage version: 2.1.10.11/cvs/Linux i686)
10
11 Revision Changes Path
12 1.507 www-client/chromium/ChangeLog
13
14 file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/ChangeLog?rev=1.507&view=markup
15 plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/ChangeLog?rev=1.507&content-type=text/plain
16 diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/ChangeLog?r1=1.506&r2=1.507
17
18 Index: ChangeLog
19 ===================================================================
20 RCS file: /var/cvsroot/gentoo-x86/www-client/chromium/ChangeLog,v
21 retrieving revision 1.506
22 retrieving revision 1.507
23 diff -u -r1.506 -r1.507
24 --- ChangeLog 18 Nov 2011 10:32:18 -0000 1.506
25 +++ ChangeLog 18 Nov 2011 19:20:04 -0000 1.507
26 @@ -1,6 +1,12 @@
27 # ChangeLog for www-client/chromium
28 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
29 -# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/ChangeLog,v 1.506 2011/11/18 10:32:18 phajdan.jr Exp $
30 +# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/ChangeLog,v 1.507 2011/11/18 19:20:04 phajdan.jr Exp $
31 +
32 +*chromium-17.0.942.0 (18 Nov 2011)
33 +
34 + 18 Nov 2011; Pawel Hajdan jr <phajdan.jr@g.o>
35 + -chromium-17.0.932.0.ebuild, +chromium-17.0.942.0.ebuild:
36 + Version bump for dev channel release. Remove old.
37
38 18 Nov 2011; Pawel Hajdan jr <phajdan.jr@g.o>
39 -chromium-15.0.874.120.ebuild, chromium-15.0.874.121.ebuild:
40
41
42
43 1.1 www-client/chromium/chromium-17.0.942.0.ebuild
44
45 file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/chromium-17.0.942.0.ebuild?rev=1.1&view=markup
46 plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/chromium-17.0.942.0.ebuild?rev=1.1&content-type=text/plain
47
48 Index: chromium-17.0.942.0.ebuild
49 ===================================================================
50 # Copyright 1999-2011 Gentoo Foundation
51 # Distributed under the terms of the GNU General Public License v2
52 # $Header: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-17.0.942.0.ebuild,v 1.1 2011/11/18 19:20:04 phajdan.jr Exp $
53
54 EAPI="4"
55 PYTHON_DEPEND="2:2.6"
56
57 inherit eutils fdo-mime flag-o-matic gnome2-utils linux-info multilib \
58 pax-utils portability python toolchain-funcs versionator virtualx
59
60 DESCRIPTION="Open-source version of Google Chrome web browser"
61 HOMEPAGE="http://chromium.org/"
62 SRC_URI="http://commondatastorage.googleapis.com/chromium-browser-official/${P}.tar.bz2"
63
64 LICENSE="BSD"
65 SLOT="0"
66 KEYWORDS="~amd64 ~x86"
67 IUSE="bindist cups gnome gnome-keyring kerberos pulseaudio"
68
69 # en_US is ommitted on purpose from the list below. It must always be available.
70 LANGS="am ar bg bn ca cs da de el en_GB es es_LA et fa fi fil fr gu he hi hr
71 hu id it ja kn ko lt lv ml mr nb nl pl pt_BR pt_PT ro ru sk sl sr sv sw ta te th
72 tr uk vi zh_CN zh_TW"
73 for lang in ${LANGS}; do
74 IUSE+=" linguas_${lang}"
75 done
76
77 RDEPEND="app-arch/bzip2
78 cups? (
79 dev-libs/libgcrypt
80 >=net-print/cups-1.3.11
81 )
82 >=dev-lang/v8-3.6.5.1
83 dev-libs/dbus-glib
84 dev-libs/elfutils
85 >=dev-libs/icu-4.4.1
86 >=dev-libs/libevent-1.4.13
87 dev-libs/libxml2[icu]
88 dev-libs/libxslt
89 >=dev-libs/nss-3.12.3
90 gnome? ( >=gnome-base/gconf-2.24.0 )
91 gnome-keyring? ( >=gnome-base/gnome-keyring-2.28.2 )
92 >=media-libs/alsa-lib-1.0.19
93 media-libs/flac
94 virtual/jpeg
95 media-libs/libpng
96 >=media-libs/libwebp-0.1.2
97 media-libs/speex
98 pulseaudio? ( media-sound/pulseaudio )
99 sys-libs/zlib
100 x11-libs/gtk+:2
101 x11-libs/libXinerama
102 x11-libs/libXScrnSaver
103 x11-libs/libXtst
104 kerberos? ( virtual/krb5 )"
105 DEPEND="${RDEPEND}
106 dev-lang/nacl-toolchain-newlib
107 dev-lang/perl
108 dev-lang/yasm
109 dev-python/simplejson
110 >=dev-util/gperf-3.0.3
111 >=dev-util/pkgconfig-0.23
112 >=sys-devel/bison-2.4.3
113 sys-devel/flex
114 >=sys-devel/make-3.81-r2
115 test? ( dev-python/pyftpdlib )"
116 RDEPEND+="
117 !=www-client/chromium-9999
118 x11-misc/xdg-utils
119 virtual/ttf-fonts"
120
121 gyp_use() {
122 if [[ $# -lt 2 ]]; then
123 echo "!!! usage: gyp_use <USEFLAG> <GYPFLAG>" >&2
124 return 1
125 fi
126 if use "$1"; then echo "-D$2=1"; else echo "-D$2=0"; fi
127 }
128
129 egyp() {
130 set -- build/gyp_chromium --depth=. "${@}"
131 echo "${@}" >&2
132 "${@}"
133 }
134
135 # Chromium uses different names for some langs,
136 # return Chromium name corresponding to a Gentoo lang.
137 chromium_lang() {
138 if [[ "$1" == "es_LA" ]]; then
139 echo "es_419"
140 else
141 echo "$1"
142 fi
143 }
144
145 get_bundled_v8_version() {
146 "$(PYTHON -2)" "${FILESDIR}"/extract_v8_version.py v8/src/version.cc
147 }
148
149 get_installed_v8_version() {
150 best_version dev-lang/v8 | sed -e 's@dev-lang/v8-@@g'
151 }
152
153 if ! has chromium-pkg_die ${EBUILD_DEATH_HOOKS}; then
154 EBUILD_DEATH_HOOKS+=" chromium-pkg_die";
155 fi
156
157 chromium-pkg_die() {
158 if [[ "${EBUILD_PHASE}" != "compile" ]]; then
159 return
160 fi
161
162 # Prevent user problems like bug #348235.
163 eshopts_push -s extglob
164 if is-flagq '-g?(gdb)?([1-9])'; then
165 ewarn
166 ewarn "You have enabled debug info (i.e. -g or -ggdb in your CFLAGS/CXXFLAGS)."
167 ewarn "Please try removing -g{,gdb} before reporting a bug."
168 ewarn
169 fi
170 eshopts_pop
171
172 # ccache often causes bogus compile failures, especially when the cache gets
173 # corrupted.
174 if has ccache ${FEATURES}; then
175 ewarn
176 ewarn "You have enabled ccache. Please try disabling ccache"
177 ewarn "before reporting a bug."
178 ewarn
179 fi
180
181 # If the system doesn't have enough memory, the compilation is known to
182 # fail. Print info about memory to recognize this condition.
183 einfo
184 einfo "$(grep MemTotal /proc/meminfo)"
185 einfo "$(grep SwapTotal /proc/meminfo)"
186 einfo
187 }
188
189 pkg_setup() {
190 if [[ "${SLOT}" == "0" ]]; then
191 CHROMIUM_SUFFIX=""
192 else
193 CHROMIUM_SUFFIX="-${SLOT}"
194 fi
195 CHROMIUM_HOME="/usr/$(get_libdir)/chromium-browser${CHROMIUM_SUFFIX}"
196
197 # Make sure the build system will use the right tools, bug #340795.
198 tc-export AR CC CXX RANLIB
199
200 # Make sure the build system will use the right python, bug #344367.
201 python_set_active_version 2
202 python_pkg_setup
203
204 if [[ "${MERGE_TYPE}" == "source" || "${MERGE_TYPE}" == "binary" ]]; then
205 # Fail if the kernel doesn't support features needed for sandboxing,
206 # bug #363907.
207 ERROR_PID_NS="PID_NS is required for sandbox to work"
208 ERROR_NET_NS="NET_NS is required for sandbox to work"
209 CONFIG_CHECK="~PID_NS ~NET_NS"
210 check_extra_config
211 fi
212
213 if use bindist; then
214 elog "bindist enabled: H.264 video support will be disabled."
215 else
216 elog "bindist disabled: Resulting binaries may not be legal to re-distribute."
217 fi
218 }
219
220 src_prepare() {
221 ln -s /usr/$(get_libdir)/nacl-toolchain-newlib \
222 native_client/toolchain/linux_x86_newlib || die
223
224 # zlib-1.2.5.1-r1 renames the OF macro in zconf.h, bug 383371.
225 sed -i '1i#define OF(x) x' \
226 third_party/zlib/contrib/minizip/{ioapi,{,un}zip}.c \
227 chrome/common/zip*.cc || die
228
229 epatch_user
230
231 # Remove most bundled libraries. Some are still needed.
232 find third_party -type f \! -iname '*.gyp*' \
233 \! -path 'third_party/WebKit/*' \
234 \! -path 'third_party/angle/*' \
235 \! -path 'third_party/cacheinvalidation/*' \
236 \! -path 'third_party/cld/*' \
237 \! -path 'third_party/expat/*' \
238 \! -path 'third_party/ffmpeg/*' \
239 \! -path 'third_party/flac/flac.h' \
240 \! -path 'third_party/gpsd/*' \
241 \! -path 'third_party/harfbuzz/*' \
242 \! -path 'third_party/hunspell/*' \
243 \! -path 'third_party/iccjpeg/*' \
244 \! -path 'third_party/jsoncpp/*' \
245 \! -path 'third_party/launchpad_translations/*' \
246 \! -path 'third_party/leveldb/*' \
247 \! -path 'third_party/leveldatabase/*' \
248 \! -path 'third_party/libjingle/*' \
249 \! -path 'third_party/libphonenumber/*' \
250 \! -path 'third_party/libvpx/*' \
251 \! -path 'third_party/lss/*' \
252 \! -path 'third_party/mesa/*' \
253 \! -path 'third_party/modp_b64/*' \
254 \! -path 'third_party/mongoose/*' \
255 \! -path 'third_party/npapi/*' \
256 \! -path 'third_party/openmax/*' \
257 \! -path 'third_party/ots/*' \
258 \! -path 'third_party/protobuf/*' \
259 \! -path 'third_party/scons-2.0.1/*' \
260 \! -path 'third_party/sfntly/*' \
261 \! -path 'third_party/skia/*' \
262 \! -path 'third_party/smhasher/*' \
263 \! -path 'third_party/speex/speex.h' \
264 \! -path 'third_party/sqlite/*' \
265 \! -path 'third_party/tcmalloc/*' \
266 \! -path 'third_party/tlslite/*' \
267 \! -path 'third_party/undoview/*' \
268 \! -path 'third_party/v8-i18n/*' \
269 \! -path 'third_party/webdriver/*' \
270 \! -path 'third_party/webgl_conformance/*' \
271 \! -path 'third_party/webrtc/*' \
272 \! -path 'third_party/zlib/contrib/minizip/*' \
273 -delete || die
274
275 local v8_bundled="$(get_bundled_v8_version)"
276 local v8_installed="$(get_installed_v8_version)"
277 elog "V8 version: bundled - ${v8_bundled}; installed - ${v8_installed}"
278
279 # Remove bundled v8.
280 find v8 -type f \! -iname '*.gyp*' -delete || die
281
282 # The implementation files include v8 headers with full path,
283 # like #include "v8/include/v8.h". Make sure the system headers
284 # will be used.
285 # TODO: find a solution that can be upstreamed.
286 rmdir v8/include || die
287 ln -s /usr/include v8/include || die
288
289 # Make sure the build system will use the right python, bug #344367.
290 # Only convert directories that need it, to save time.
291 python_convert_shebangs -q -r 2 build tools
292 }
293
294 src_configure() {
295 local myconf=""
296
297 # Never tell the build system to "enable" SSE2, it has a few unexpected
298 # additions, bug #336871.
299 myconf+=" -Ddisable_sse2=1"
300
301 # Use system-provided libraries.
302 # TODO: use_system_ffmpeg
303 # TODO: use_system_hunspell (upstream changes needed).
304 # TODO: use_system_ssl (http://crbug.com/58087).
305 # TODO: use_system_sqlite (http://crbug.com/22208).
306 # TODO: use_system_vpx
307 myconf+="
308 -Duse_system_bzip2=1
309 -Duse_system_flac=1
310 -Duse_system_icu=1
311 -Duse_system_libevent=1
312 -Duse_system_libjpeg=1
313 -Duse_system_libpng=1
314 -Duse_system_libwebp=1
315 -Duse_system_libxml=1
316 -Duse_system_speex=1
317 -Duse_system_v8=1
318 -Duse_system_xdg_utils=1
319 -Duse_system_yasm=1
320 -Duse_system_zlib=1"
321
322 # Optional dependencies.
323 # TODO: linux_link_kerberos, bug #381289.
324 myconf+="
325 $(gyp_use cups use_cups)
326 $(gyp_use gnome use_gconf)
327 $(gyp_use gnome-keyring use_gnome_keyring)
328 $(gyp_use gnome-keyring linux_link_gnome_keyring)
329 $(gyp_use kerberos use_kerberos)
330 $(gyp_use pulseaudio use_pulseaudio)"
331
332 # Enable sandbox.
333 myconf+="
334 -Dlinux_sandbox_path=${CHROMIUM_HOME}/chrome_sandbox
335 -Dlinux_sandbox_chrome_path=${CHROMIUM_HOME}/chrome"
336
337 # if host-is-pax; then
338 # # Prevent the build from failing (bug #301880). The performance
339 # # difference is very small.
340 # myconf+=" -Dv8_use_snapshot=0"
341 # fi
342
343 # Our system ffmpeg should support more codecs than the bundled one
344 # for Chromium.
345 # myconf+=" -Dproprietary_codecs=1"
346
347 if ! use bindist; then
348 # Enable H.624 support in bundled ffmpeg.
349 myconf+=" -Dproprietary_codecs=1 -Dffmpeg_branding=Chrome"
350 fi
351
352 local myarch="$(tc-arch)"
353 if [[ $myarch = amd64 ]] ; then
354 myconf+=" -Dtarget_arch=x64"
355 elif [[ $myarch = x86 ]] ; then
356 myconf+=" -Dtarget_arch=ia32"
357 elif [[ $myarch = arm ]] ; then
358 # TODO: check this again after
359 # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=39509 is fixed.
360 append-flags -fno-tree-sink
361
362 myconf+=" -Dtarget_arch=arm -Ddisable_nacl=1 -Dlinux_use_tcmalloc=0"
363 else
364 die "Failed to determine target arch, got '$myarch'."
365 fi
366
367 # Make sure that -Werror doesn't get added to CFLAGS by the build system.
368 # Depending on GCC version the warnings are different and we don't want
369 # the build to fail because of that.
370 myconf+=" -Dwerror="
371
372 # Avoid CFLAGS problems, bug #352457, bug #390147.
373 replace-flags "-Os" "-O2"
374 strip-flags
375
376 egyp ${myconf} || die
377 }
378
379 src_compile() {
380 emake chrome chrome_sandbox chromedriver BUILDTYPE=Release V=1 || die
381 pax-mark m out/Release/chrome
382 if use test; then
383 emake {base,cacheinvalidation,crypto,googleurl,gpu,media,net,printing}_unittests BUILDTYPE=Release V=1 || die
384 pax-mark m out/Release/{base,cacheinvalidation,crypto,googleurl,gpu,media,net,printing}_unittests
385 fi
386 }
387
388 src_test() {
389 # For more info see bug #350349.
390 local mylocale='en_US.utf8'
391 if ! locale -a | grep -q "$mylocale"; then
392 eerror "${PN} requires ${mylocale} locale for tests"
393 eerror "Please read the following guides for more information:"
394 eerror " http://www.gentoo.org/doc/en/guide-localization.xml"
395 eerror " http://www.gentoo.org/doc/en/utf-8.xml"
396 die "locale ${mylocale} is not supported"
397 fi
398
399 # For more info see bug #370957.
400 if [[ $UID -eq 0 ]]; then
401 die "Tests must be run as non-root. Please use FEATURES=userpriv."
402 fi
403
404 # For more info see bug #350347.
405 LC_ALL="${mylocale}" VIRTUALX_COMMAND=out/Release/base_unittests virtualmake \
406 '--gtest_filter=-ICUStringConversionsTest.*'
407
408 LC_ALL="${mylocale}" VIRTUALX_COMMAND=out/Release/cacheinvalidation_unittests virtualmake
409 LC_ALL="${mylocale}" VIRTUALX_COMMAND=out/Release/crypto_unittests virtualmake
410 LC_ALL="${mylocale}" VIRTUALX_COMMAND=out/Release/googleurl_unittests virtualmake
411 LC_ALL="${mylocale}" VIRTUALX_COMMAND=out/Release/gpu_unittests virtualmake
412 LC_ALL="${mylocale}" VIRTUALX_COMMAND=out/Release/media_unittests virtualmake
413
414 # NetUtilTest: bug #361885.
415 # NetUtilTest.GenerateFileName: some locale-related mismatch.
416 # UDP: unstable, active development. We should revisit this later.
417 LC_ALL="${mylocale}" VIRTUALX_COMMAND=out/Release/net_unittests virtualmake \
418 '--gtest_filter=-NetUtilTest.IDNToUnicode*:NetUtilTest.FormatUrl*:NetUtilTest.GenerateFileName:*UDP*'
419
420 LC_ALL="${mylocale}" VIRTUALX_COMMAND=out/Release/printing_unittests virtualmake
421 }
422
423 src_install() {
424 exeinto "${CHROMIUM_HOME}"
425 doexe out/Release/chrome || die
426 doexe out/Release/chrome_sandbox || die
427 fperms 4755 "${CHROMIUM_HOME}/chrome_sandbox"
428
429 doexe out/Release/chromedriver || die
430
431 # Install Native Client files on platforms that support it.
432 insinto "${CHROMIUM_HOME}"
433 case "$(tc-arch)" in
434 amd64)
435 doexe out/Release/nacl_helper{,_bootstrap} || die
436 doins out/Release/nacl_irt_x86_64.nexe || die
437 doins out/Release/libppGoogleNaClPluginChrome.so || die
438 ;;
439 x86)
440 doexe out/Release/nacl_helper{,_bootstrap} || die
441 doins out/Release/nacl_irt_x86_32.nexe || die
442 doins out/Release/libppGoogleNaClPluginChrome.so || die
443 ;;
444 esac
445
446 newexe "${FILESDIR}"/chromium-launcher-r2.sh chromium-launcher.sh || die
447 if [[ "${CHROMIUM_SUFFIX}" != "" ]]; then
448 sed "s:chromium-browser:chromium-browser${CHROMIUM_SUFFIX}:g" \
449 -i "${ED}"/"${CHROMIUM_HOME}"/chromium-launcher.sh || die
450 sed "s:chromium.desktop:chromium${CHROMIUM_SUFFIX}.desktop:g" \
451 -i "${ED}"/"${CHROMIUM_HOME}"/chromium-launcher.sh || die
452 sed "s:plugins:plugins --user-data-dir=\${HOME}/.config/chromium${CHROMIUM_SUFFIX}:" \
453 -i "${ED}"/"${CHROMIUM_HOME}"/chromium-launcher.sh || die
454 fi
455
456 # It is important that we name the target "chromium-browser",
457 # xdg-utils expect it; bug #355517.
458 dosym "${CHROMIUM_HOME}/chromium-launcher.sh" /usr/bin/chromium-browser${CHROMIUM_SUFFIX} || die
459 # keep the old symlink around for consistency
460 dosym "${CHROMIUM_HOME}/chromium-launcher.sh" /usr/bin/chromium${CHROMIUM_SUFFIX} || die
461
462 # Allow users to override command-line options, bug #357629.
463 dodir /etc/chromium || die
464 insinto /etc/chromium
465 newins "${FILESDIR}/chromium.default" "default" || die
466
467 # Support LINGUAS, bug #332751.
468 local pak
469 for pak in out/Release/locales/*.pak; do
470 local pakbasename="$(basename ${pak})"
471 local pakname="${pakbasename%.pak}"
472 local langname="${pakname//-/_}"
473
474 # Do not issue warning for en_US locale. This is the fallback
475 # locale so it should always be installed.
476 if [[ "${langname}" == "en_US" ]]; then
477 continue
478 fi
479
480 local found=false
481 local lang
482 for lang in ${LANGS}; do
483 local crlang="$(chromium_lang ${lang})"
484 if [[ "${langname}" == "${crlang}" ]]; then
485 found=true
486 break
487 fi
488 done
489 if ! $found; then
490 ewarn "LINGUAS warning: no ${langname} in LANGS"
491 fi
492 done
493 local lang
494 for lang in ${LANGS}; do
495 local crlang="$(chromium_lang ${lang})"
496 local pakfile="out/Release/locales/${crlang//_/-}.pak"
497 if [ ! -f "${pakfile}" ]; then
498 ewarn "LINGUAS warning: no .pak file for ${lang} (${pakfile} not found)"
499 fi
500 if ! use linguas_${lang}; then
501 rm "${pakfile}" || die
502 fi
503 done
504
505 insinto "${CHROMIUM_HOME}"
506 doins out/Release/chrome.pak || die
507 doins out/Release/resources.pak || die
508
509 doins -r out/Release/locales || die
510 doins -r out/Release/resources || die
511
512 newman out/Release/chrome.1 chromium${CHROMIUM_SUFFIX}.1 || die
513 newman out/Release/chrome.1 chromium-browser${CHROMIUM_SUFFIX}.1 || die
514
515 # Chromium looks for these in its folder
516 # See media_posix.cc and base_paths_linux.cc
517 # dosym /usr/$(get_libdir)/libavcodec.so.52 "${CHROMIUM_HOME}" || die
518 # dosym /usr/$(get_libdir)/libavformat.so.52 "${CHROMIUM_HOME}" || die
519 # dosym /usr/$(get_libdir)/libavutil.so.50 "${CHROMIUM_HOME}" || die
520 doexe out/Release/libffmpegsumo.so || die
521
522 # Install icons and desktop entry.
523 for SIZE in 16 22 24 32 48 64 128 256 ; do
524 insinto /usr/share/icons/hicolor/${SIZE}x${SIZE}/apps
525 newins chrome/app/theme/chromium/product_logo_${SIZE}.png \
526 chromium-browser${CHROMIUM_SUFFIX}.png || die
527 done
528 local mime_types="text/html;text/xml;application/xhtml+xml;"
529 mime_types+="x-scheme-handler/http;x-scheme-handler/https;" # bug #360797
530 make_desktop_entry \
531 chromium-browser${CHROMIUM_SUFFIX} \
532 "Chromium${CHROMIUM_SUFFIX}" \
533 chromium-browser${CHROMIUM_SUFFIX} \
534 "Network;WebBrowser" \
535 "MimeType=${mime_types}\nStartupWMClass=chromium-browser"
536 sed -e "/^Exec/s/$/ %U/" -i "${ED}"/usr/share/applications/*.desktop || die
537
538 # Install GNOME default application entry (bug #303100).
539 if use gnome; then
540 dodir /usr/share/gnome-control-center/default-apps || die
541 insinto /usr/share/gnome-control-center/default-apps
542 newins "${FILESDIR}"/chromium-browser.xml chromium-browser${CHROMIUM_SUFFIX}.xml || die
543 if [[ "${CHROMIUM_SUFFIX}" != "" ]]; then
544 sed "s:chromium-browser:chromium-browser${CHROMIUM_SUFFIX}:g" -i \
545 "${ED}"/usr/share/gnome-control-center/default-apps/chromium-browser${CHROMIUM_SUFFIX}.xml
546 fi
547 fi
548 }
549
550 pkg_preinst() {
551 gnome2_icon_savelist
552 }
553
554 pkg_postinst() {
555 fdo-mime_desktop_database_update
556 gnome2_icon_cache_update
557
558 # For more info see bug #292201, bug #352263, bug #361859.
559 elog
560 elog "Depending on your desktop environment, you may need"
561 elog "to install additional packages to get icons on the Downloads page."
562 elog
563 elog "For KDE, the required package is kde-base/oxygen-icons."
564 elog
565 elog "For other desktop environments, try one of the following:"
566 elog " - x11-themes/gnome-icon-theme"
567 elog " - x11-themes/tango-icon-theme"
568
569 # For more info see bug #359153.
570 elog
571 elog "Some web pages may require additional fonts to display properly."
572 elog "Try installing some of the following packages if some characters"
573 elog "are not displayed properly:"
574 elog " - media-fonts/arphicfonts"
575 elog " - media-fonts/bitstream-cyberbit"
576 elog " - media-fonts/droid"
577 elog " - media-fonts/ipamonafont"
578 elog " - media-fonts/ja-ipafonts"
579 elog " - media-fonts/takao-fonts"
580 elog " - media-fonts/wqy-microhei"
581 elog " - media-fonts/wqy-zenhei"
582 }
583
584 pkg_postrm() {
585 gnome2_icon_cache_update
586 }
Report Message
Find on MARC Find on Google Groups