[gentoo-commits] repo/gentoo:master commit in: net-libs/libtorrent-rasterbar/

[Mikle Kolyada]

commit:     65d2c5f9e403f227cb07405ae1d4dd5a243d1894
Author:     Mikle Kolyada <zlogene <AT> gentoo <DOT> org>
AuthorDate: Wed Mar 11 06:55:43 2020 +0000
Commit:     Mikle Kolyada <zlogene <AT> gentoo <DOT> org>
CommitDate: Wed Mar 11 06:55:43 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=65d2c5f9

net-libs/libtorrent-rasterbar: Version bump (v1.2.5)

Package-Manager: Portage-2.3.89, Repoman-2.3.20
Signed-off-by: Mikle Kolyada <zlogene <AT> gentoo.org>

 net-libs/libtorrent-rasterbar/Manifest             |   1 +
 .../libtorrent-rasterbar-1.2.5.ebuild              | 112 +++++++++++++++++++++
 2 files changed, 113 insertions(+)

diff --git a/net-libs/libtorrent-rasterbar/Manifest b/net-libs/libtorrent-rasterbar/Manifest
index 06fbbd29edc..609d19944ea 100644
--- a/net-libs/libtorrent-rasterbar/Manifest
+++ b/net-libs/libtorrent-rasterbar/Manifest
@@ -2,3 +2,4 @@ DIST libtorrent-rasterbar-1.1.13.tar.gz 3896007 BLAKE2B b94f843437be348b10082f19
 DIST libtorrent-rasterbar-1.1.14.tar.gz 4040571 BLAKE2B 38ea1a71e46bf18c9beeb869280e4949b199ab58c32f41e63f1c15c7c32db0d256b741ea707350e9e153695b9cc28e0a95385944bf76dbd5eb2055e66bb0f919 SHA512 b640ada016f8e68a3fb0e033dd33ab79b345b0f691aa722c4256b8cd8524c6e55067ccd1f11584984bbb82c0f64151f0b5223bd2b8431b899ffca46d2d31fff5
 DIST libtorrent-rasterbar-1.2.3.tar.gz 3591081 BLAKE2B 9766a21c948997b35c6d209940a2d2cfd76b130f1a9d1f611e07d3eeb27f634a3c5eca12c92261139200084b9678913d85f6a56f98ab6894e5def761615c39ad SHA512 11a81c9f4b968ed360740553f8d856a2fad4eb2f6962f6403394e0a4a6b198ef6f04ce92d11fc6bed9aa979c84efd03fb396027dfe6603f394104b4302e04d82
 DIST libtorrent-rasterbar-1.2.4.tar.gz 3598403 BLAKE2B 7a9a6b3244137fff785d0bd82dc0b1900b9e8c673f1cf9492bbde2c8f14d0a9d4ac3e4835eb9721bb9fa388d1a5d0635f2ffeb0f2a6f5a61f4fda7f89d6a10e3 SHA512 d24901acc0f462b6ff873f9aea880bf44698165db5343e8437b1dd7d7f20dfa6e7fe1e72a44a518fff5f2167a48552ec359696bb682c82e86012737177e082d3
+DIST libtorrent-rasterbar-1.2.5.tar.gz 3603956 BLAKE2B b537ce709fb7941551d50cca8a29543f9735bad25cf33ecf99fc21e54a4ae4e24207e13800888111aec813dfea6811c702c2a1247e415eee8532d967ab8dfdb1 SHA512 2139f09fa20ce8e04a3e3340408abd744e58e1bd698d8509c2d0f166147a3894b36aa3e7e65574750d986259002d4dbd2b7e5052125d41d300116a810bbfaff8

diff --git a/net-libs/libtorrent-rasterbar/libtorrent-rasterbar-1.2.5.ebuild b/net-libs/libtorrent-rasterbar/libtorrent-rasterbar-1.2.5.ebuild
new file mode 100644
index 00000000000..2e6c5ab5e93
--- /dev/null
+++ b/net-libs/libtorrent-rasterbar/libtorrent-rasterbar-1.2.5.ebuild
@@ -0,0 +1,112 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7} )
+PYTHON_REQ_USE="threads(+)"
+DISTUTILS_OPTIONAL=true
+DISTUTILS_IN_SOURCE_BUILD=true
+
+inherit autotools distutils-r1
+
+MY_PV=$(ver_rs 1-2 '_')
+MY_P=${PN/-rasterbar}-${MY_PV}
+
+DESCRIPTION="C++ BitTorrent implementation focusing on efficiency and scalability"
+HOMEPAGE="https://libtorrent.org https://github.com/arvidn/libtorrent"
+SRC_URI="https://github.com/arvidn/libtorrent/archive/${MY_P}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0/10"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~sparc ~x86"
+IUSE="debug +dht doc examples libressl python +ssl static-libs test"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-libs/boost:=[threads]
+	virtual/libiconv
+	examples? ( !net-p2p/mldonkey )
+	python? (
+		${PYTHON_DEPS}
+		dev-libs/boost:=[python,${PYTHON_USEDEP}]
+	)
+	ssl? (
+		!libressl? ( dev-libs/openssl:0= )
+		libressl? ( dev-libs/libressl:= )
+	)
+"
+DEPEND="${RDEPEND}
+	sys-devel/libtool
+"
+
+S="${WORKDIR}/${PN/-rasterbar}-${MY_P}"
+
+src_prepare() {
+	mkdir "${S}"/build-aux/ || die
+	touch "${S}"/build-aux/config.rpath || die
+	eautoreconf
+
+	default
+
+	# bug 578026
+	# prepend -L${S}/... to ensure bindings link against the lib we just built
+	sed -i -e "s|^|-L${S}/src/.libs |" bindings/python/link_flags.in || die
+
+	# prepend -I${S}/... to ensure bindings use the right headers
+	sed -i -e "s|^|-I${S}/src/include |" bindings/python/compile_flags.in || die
+
+	use python && distutils-r1_src_prepare
+}
+
+src_configure() {
+
+	local myeconfargs=(
+		$(use_enable debug)
+		$(use_enable debug export-all)
+		$(use_enable debug logging)
+		$(use_enable dht)
+		$(use_enable examples)
+		$(use_enable ssl encryption)
+		$(use_enable static-libs static)
+		$(use_enable test tests)
+		--with-libiconv
+	)
+	econf "${myeconfargs[@]}"
+
+	if use python; then
+		python_configure() {
+			econf "${myeconfargs[@]}" \
+				--enable-python-binding \
+				--with-boost-python="boost_${EPYTHON/./}"
+		}
+		distutils-r1_src_configure
+	fi
+}
+
+src_compile() {
+	default
+
+	python_compile() {
+		cd "${BUILD_DIR}/../bindings/python" || die
+		distutils-r1_python_compile
+	}
+	use python && distutils-r1_src_compile
+}
+
+src_install() {
+	use doc && HTML_DOCS+=( "${S}"/docs )
+
+	default
+
+	python_install() {
+		cd "${BUILD_DIR}/../bindings/python" || die
+		distutils-r1_python_install
+	}
+	use python && distutils-r1_src_install
+
+	find "${D}" -name '*.la' -delete || die
+}