[gentoo-commits] gentoo-x86 commit in sys-apps/attr: attr-2.4.47.ebuild ChangeLog

[Mike Frysinger (vapier)]

vapier      13/05/20 18:43:16

  Modified:             ChangeLog
  Added:                attr-2.4.47.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha170/cvs/Linux x86_64, signed Manifest commit with key FB7C4156)

Revision  Changes    Path
1.146                sys-apps/attr/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/attr/ChangeLog?rev=1.146&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/attr/ChangeLog?rev=1.146&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/attr/ChangeLog?r1=1.145&r2=1.146

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/attr/ChangeLog,v
retrieving revision 1.145
retrieving revision 1.146
diff -u -r1.145 -r1.146
--- ChangeLog	21 Mar 2013 15:11:57 -0000	1.145
+++ ChangeLog	20 May 2013 18:43:16 -0000	1.146
@@ -1,6 +1,11 @@
 # ChangeLog for sys-apps/attr
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/attr/ChangeLog,v 1.145 2013/03/21 15:11:57 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/attr/ChangeLog,v 1.146 2013/05/20 18:43:16 vapier Exp $
+
+*attr-2.4.47 (20 May 2013)
+
+  20 May 2013; Mike Frysinger <vapier@g.o> +attr-2.4.47.ebuild:
+  Version bump.
 
   21 Mar 2013; Jeroen Roovers <jer@g.o> attr-2.4.46-r2.ebuild:
   Stable for HPPA (bug #212517).



1.1                  sys-apps/attr/attr-2.4.47.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/attr/attr-2.4.47.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/attr/attr-2.4.47.ebuild?rev=1.1&content-type=text/plain

Index: attr-2.4.47.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/attr/attr-2.4.47.ebuild,v 1.1 2013/05/20 18:43:16 vapier Exp $

EAPI="4"

inherit eutils toolchain-funcs

DESCRIPTION="Extended attributes tools"
HOMEPAGE="http://savannah.nongnu.org/projects/attr"
SRC_URI="mirror://nongnu/${PN}/${P}.src.tar.gz"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-linux ~arm-linux ~x86-linux"
IUSE="nls static-libs"

DEPEND="nls? ( sys-devel/gettext )
	sys-devel/autoconf"
RDEPEND=""

src_prepare() {
	sed -i \
		-e "/^PKG_DOC_DIR/s:@pkg_name@:${PF}:" \
		-e '/HAVE_ZIPPED_MANPAGES/s:=.*:=false:' \
		include/builddefs.in \
		|| die
	strip-linguas -u po
}

src_configure() {
	unset PLATFORM #184564
	export OPTIMIZER=${CFLAGS}
	export DEBUG=-DNDEBUG

	econf \
		$(use_enable nls gettext) \
		--enable-shared $(use_enable static-libs static) \
		--libexecdir="${EPREFIX}"/usr/$(get_libdir) \
		--bindir="${EPREFIX}"/bin
}

src_install() {
	emake DIST_ROOT="${D}" install install-lib install-dev
	use static-libs || find "${ED}" -name '*.la' -delete
	# the man-pages packages provides the man2 files
	rm -r "${ED}"/usr/share/man/man2 || die

	# we install attr into /bin, so we need the shared lib with it
	gen_usr_ldscript -a attr
}