[gentoo-commits] gentoo-x86 commit in app-backup/snapper: snapper-0.2.6.ebuild ChangeLog

[Yixun Lan (dlan)]

dlan        15/03/01 15:11:43

  Modified:             ChangeLog
  Added:                snapper-0.2.6.ebuild
  Log:
  version bump, bug 539526
  
  (Portage version: 2.2.17/cvs/Linux x86_64, signed Manifest commit with key 0xAABEFD55)

Revision  Changes    Path
1.8                  app-backup/snapper/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-backup/snapper/ChangeLog?rev=1.8&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-backup/snapper/ChangeLog?rev=1.8&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-backup/snapper/ChangeLog?r1=1.7&r2=1.8

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-backup/snapper/ChangeLog,v
retrieving revision 1.7
retrieving revision 1.8
diff -u -r1.7 -r1.8
--- ChangeLog	15 Nov 2014 14:38:53 -0000	1.7
+++ ChangeLog	1 Mar 2015 15:11:43 -0000	1.8
@@ -1,6 +1,11 @@
 # ChangeLog for app-backup/snapper
-# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-backup/snapper/ChangeLog,v 1.7 2014/11/15 14:38:53 dlan Exp $
+# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-backup/snapper/ChangeLog,v 1.8 2015/03/01 15:11:43 dlan Exp $
+
+*snapper-0.2.6 (01 Mar 2015)
+
+  01 Mar 2015; Yixun Lan <dlan@g.o> +snapper-0.2.6.ebuild:
+  version bump, bug 539526
 
 *snapper-0.2.4 (15 Nov 2014)
 



1.1                  app-backup/snapper/snapper-0.2.6.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-backup/snapper/snapper-0.2.6.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-backup/snapper/snapper-0.2.6.ebuild?rev=1.1&content-type=text/plain

Index: snapper-0.2.6.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-backup/snapper/snapper-0.2.6.ebuild,v 1.1 2015/03/01 15:11:43 dlan Exp $

EAPI=5

inherit eutils

DESCRIPTION="Command-line program for btrfs and ext4 snapshot management"
HOMEPAGE="http://snapper.io/"
SRC_URI="ftp://ftp.suse.com/pub/projects/snapper/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="+btrfs ext4 lvm pam xattr"

RDEPEND="dev-libs/boost[threads]
	dev-libs/libxml2
	dev-libs/icu:=
	sys-apps/acl
	sys-apps/dbus
	sys-apps/util-linux
	sys-libs/zlib
	virtual/libintl
	btrfs? ( >=sys-fs/btrfs-progs-3.17.1 )
	ext4? ( sys-fs/e2fsprogs )
	lvm? ( sys-fs/lvm2 )
	pam? ( sys-libs/pam )
	xattr? ( sys-apps/attr )"

DEPEND="${RDEPEND}
	sys-devel/gettext
	virtual/pkgconfig"

DOCS=( AUTHORS README )

src_prepare() {
	epatch "${FILESDIR}"/cron-confd.patch
}

src_configure() {
	local myeconfargs=(
		--with-conf="/etc/conf.d"
		--docdir="/usr/share/doc/${PF}"
		--disable-zypp
		$(use_enable btrfs)
		$(use_enable ext4)
		$(use_enable lvm)
		$(use_enable pam)
		$(use_enable xattr xattrs)
	)

	econf "${myeconfargs[@]}"
}

src_install() {
	default
	# Existing configuration file required to function
	newconfd data/sysconfig.snapper snapper
	prune_libtool_files
}

pkg_postinst() {
	elog "In order to use Snapper, you need to set up"
	elog "at least one config first. To do this, run:"
	elog "snapper create-config <subvolume>"
	elog "For more information, see man (8) snapper or"
	elog "http://snapper.io/documentation.html"
}