[gentoo-commits] gentoo-x86 commit in media-gfx/fbida: fbida-2.09-r1.ebuild ChangeLog fbida-2.09.ebuild

[Jeroen Roovers (jer)]

jer         13/12/31 17:23:48

  Modified:             ChangeLog fbida-2.09.ebuild
  Added:                fbida-2.09-r1.ebuild
  Log:
  Add giflib-4.2 patch by Tomasz Wasiak (bug #494402).
  
  (Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key A792A613)

Revision  Changes    Path
1.106                media-gfx/fbida/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/fbida/ChangeLog?rev=1.106&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/fbida/ChangeLog?rev=1.106&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/fbida/ChangeLog?r1=1.105&r2=1.106

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-gfx/fbida/ChangeLog,v
retrieving revision 1.105
retrieving revision 1.106
diff -u -r1.105 -r1.106
--- ChangeLog	1 Mar 2013 16:41:25 -0000	1.105
+++ ChangeLog	31 Dec 2013 17:23:48 -0000	1.106
@@ -1,6 +1,13 @@
 # ChangeLog for media-gfx/fbida
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/fbida/ChangeLog,v 1.105 2013/03/01 16:41:25 kensington Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/fbida/ChangeLog,v 1.106 2013/12/31 17:23:48 jer Exp $
+
+*fbida-2.09-r1 (31 Dec 2013)
+
+  31 Dec 2013; Jeroen Roovers <jer@g.o> fbida-2.09.ebuild,
+  +fbida-2.09-r1.ebuild, +files/fbida-2.09-giflib-4.2.patch,
+  files/ida-desktop.patch:
+  Add giflib-4.2 patch by Tomasz Wasiak (bug #494402).
 
   01 Mar 2013; Michael Palimaka <kensington@g.o> -fbida-2.08.ebuild:
   Remove old.



1.13                 media-gfx/fbida/fbida-2.09.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/fbida/fbida-2.09.ebuild?rev=1.13&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/fbida/fbida-2.09.ebuild?rev=1.13&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/fbida/fbida-2.09.ebuild?r1=1.12&r2=1.13

Index: fbida-2.09.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-gfx/fbida/fbida-2.09.ebuild,v
retrieving revision 1.12
retrieving revision 1.13
diff -u -r1.12 -r1.13
--- fbida-2.09.ebuild	1 Mar 2013 16:37:10 -0000	1.12
+++ fbida-2.09.ebuild	31 Dec 2013 17:23:48 -0000	1.13
@@ -1,6 +1,6 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/fbida/fbida-2.09.ebuild,v 1.12 2013/03/01 16:37:10 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/fbida/fbida-2.09.ebuild,v 1.13 2013/12/31 17:23:48 jer Exp $
 
 EAPI=5
 inherit eutils toolchain-funcs
@@ -60,7 +60,7 @@
 	fi
 
 	epatch "${FILESDIR}"/ida-desktop.patch
-	epatch "${FILESDIR}"/fbida-2.08-posix-make.patch
+	epatch "${FILESDIR}"/${PN}-2.08-posix-make.patch
 }
 
 src_configure() {



1.1                  media-gfx/fbida/fbida-2.09-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/fbida/fbida-2.09-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/fbida/fbida-2.09-r1.ebuild?rev=1.1&content-type=text/plain

Index: fbida-2.09-r1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-gfx/fbida/fbida-2.09-r1.ebuild,v 1.1 2013/12/31 17:23:48 jer Exp $

EAPI=5
inherit eutils toolchain-funcs

DESCRIPTION="Image viewers for the framebuffer console (fbi) and X11 (ida)."
HOMEPAGE="http://www.kraxel.org/blog/linux/fbida/"
SRC_URI="http://www.kraxel.org/releases/${PN}/${P}.tar.gz
	mirror://gentoo/ida.png.bz2" #370901
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ppc ~ppc64 ~sh ~sparc ~x86"
IUSE="curl fbcon gif imagemagick lirc pdf png scanner tiff X"

RDEPEND="
	curl? ( net-misc/curl )
	gif? ( >media-libs/giflib-4.2 )
	lirc? ( app-misc/lirc )
	pdf? ( app-text/ghostscript-gpl media-libs/tiff )
	png? ( media-libs/libpng )
	tiff? ( media-libs/tiff )
	imagemagick? (
		|| (
			media-gfx/imagemagick
			media-gfx/graphicsmagick[imagemagick]
		)
	)
	scanner? ( media-gfx/sane-backends )
	X? (
		>=x11-libs/motif-2.3:0
		x11-libs/libX11
		x11-libs/libXpm
		x11-libs/libXt
	)
	!media-gfx/fbi
	>=media-libs/fontconfig-2.2
	>=media-libs/freetype-2.0
	media-libs/libexif
	virtual/jpeg
	virtual/ttf-fonts
"

DEPEND="
	${RDEPEND}
	X? ( x11-proto/xextproto x11-proto/xproto )
"

pkg_setup() {
	tc-export CC
}

src_prepare() {
	sed -e 's:DGifOpenFileName,ungif:DGifOpenFileName,gif:' \
		-e 's:-lungif:-lgif:' -i "${S}/GNUmakefile"

	if [[ $(gcc-major-version) -lt 4 ]]; then
		sed	-e 's:-Wno-pointer-sign::' -i "${S}/GNUmakefile" || die
	fi

	epatch "${FILESDIR}"/ida-desktop.patch
	epatch "${FILESDIR}"/${PN}-2.08-posix-make.patch
	epatch "${FILESDIR}"/${P}-giflib-4.2.patch
}

src_configure() {
	# Let autoconf do its job and then fix things to build fbida
	# according to our specifications
	emake Make.config

	set_feat() {
		local useflag=${1}
		local config=${2}

		local option="yes"
		if ! use ${useflag}; then
			option="no"
		fi

		sed -i \
			-e "s|${config}.*|${config} := ${option}|" \
			"${S}/Make.config" || die
	}

	set_feat fbcon 	HAVE_LINUX_FB_H
	set_feat X 		HAVE_MOTIF
	set_feat tiff 	HAVE_LIBTIFF

	# The 'pdf' flag forces the use of libtiff.
	set_feat pdf	HAVE_LIBTIFF
	set_feat png 	HAVE_LIBPNG
	set_feat gif 	HAVE_LIBUNGIF
	set_feat lirc 	HAVE_LIBLIRC
	set_feat curl 	HAVE_LIBCURL
	set_feat scanner HAVE_LIBSANE
	set_feat imagemagick HAVE_LIBMAGICK
}

src_compile() {
	emake verbose=yes
}

src_install() {
	emake \
		DESTDIR="${D}" \
		STRIP="" \
		prefix=/usr \
		install

	dodoc README

	if ! use pdf; then
		rm -f "${D}"/usr/bin/fbgs "${D}"/usr/share/man/man1/fbgs.1
	fi

	if use X ; then
		doicon "${WORKDIR}"/ida.png
		domenu desktop/ida.desktop
	fi
}