[gentoo-commits] gentoo-x86 commit in app-benchmarks/bootchart2: bootchart2-0.14.2.ebuild metadata.xml ChangeLog Manifest

[Justin Lecher (jlec)]

jlec        12/04/02 07:19:16

  Added:                bootchart2-0.14.2.ebuild metadata.xml ChangeLog
                        Manifest
  Log:
  New addition, ebuild after submission by Gustavo Sverzut Barbieri, Lucian Muresan & Henry Gebhardt; #345695
  
  (Portage version: 2.2.0_alpha96/cvs/Linux x86_64)

Revision  Changes    Path
1.1                  app-benchmarks/bootchart2/bootchart2-0.14.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-benchmarks/bootchart2/bootchart2-0.14.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-benchmarks/bootchart2/bootchart2-0.14.2.ebuild?rev=1.1&content-type=text/plain

Index: bootchart2-0.14.2.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-benchmarks/bootchart2/bootchart2-0.14.2.ebuild,v 1.1 2012/04/02 07:19:16 jlec Exp $

EAPI=4

PYTHON_DEPEND="2"
SUPPORT_PYTHON_ABIS="1"
RESTRICT_PYTHON_ABI="2.7-pypy-*"

inherit linux-info python systemd toolchain-funcs

DESCRIPTION="Performance analysis and visualization of the system boot process"
HOMEPAGE="https://github.com/mmeeks/bootchart/"
SRC_URI="mirror://github/mmeeks/bootchart/${P}.tar.bz2"

SLOT="0"
LICENSE="GPL-2"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
IUSE="svg"

RDEPEND="
	!app-benchmarks/bootchart
	dev-python/pycairo[svg=]"
DEPEND="${RDEPEND}
"

CONFIG_CHECK="~PROC_EVENTS ~TASKSTATS ~TASK_DELAY_ACCT ~TMPFS"

src_prepare() {
	tc-export CC
	sed \
		-e "/^install/s:py-install-compile::g" \
		-e "/^VER/s:0.14.1:0.14.2:g" \
		-e "/^SYSTEMD_UNIT_DIR/s:=.*:= $(systemd_get_unitdir):g" \
		-i Makefile || die
}

src_install() {
	export NO_PYTHON_COMPILE=0
	export DOCDIR=/usr/share/doc/${PF}
	default

	# Note: LIBDIR is hardcoded as /lib in collector/common.h, so we shouldn't
	# just change it. Since no libraries are installed, /lib is fine.
	keepdir /lib/bootchart/tmpfs

	installation() {
		emake \
			DESTDIR="${D}" \
			PY_SITEDIR=$(python_get_sitedir) \
			py-install-compile
	}
	python_execute_function installation
}

src_test() {
	testing() {
		emake test
	}
	python_execute_function testing
}

pkg_postinst() {
	elog "Please review /usr/share/doc/${PF}/README"
	elog "for further usage informations."
}



1.1                  app-benchmarks/bootchart2/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-benchmarks/bootchart2/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-benchmarks/bootchart2/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
	<maintainer>
		<email>jlec@g.o</email>
	</maintainer>
</pkgmetadata>



1.1                  app-benchmarks/bootchart2/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-benchmarks/bootchart2/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-benchmarks/bootchart2/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for app-benchmarks/bootchart2
# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/app-benchmarks/bootchart2/ChangeLog,v 1.1 2012/04/02 07:19:16 jlec Exp $

*bootchart2-0.14.2 (02 Apr 2012)

  02 Apr 2012; Justin Lecher <jlec@g.o> +bootchart2-0.14.2.ebuild,
  +metadata.xml:
  New addition, ebuild after submission by Gustavo Sverzut Barbieri, Lucian
  Muresan & Henry Gebhardt; #345695




1.1                  app-benchmarks/bootchart2/Manifest

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-benchmarks/bootchart2/Manifest?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-benchmarks/bootchart2/Manifest?rev=1.1&content-type=text/plain

Index: Manifest
===================================================================
DIST bootchart2-0.14.2.tar.bz2 775770 RMD160 cdfc030c12060737768cd6f6b55be508a8c517bc SHA1 75b3db97c239e8eee4c3143e35f77505480ec415 SHA256 0a9c9cd4065a1ad4d9e27e36888cf6258bb8c830a719e1a4afbf3b1092e728a4
EBUILD bootchart2-0.14.2.ebuild 1476 RMD160 94b8db637093c9ec2ec6d72ab7550a65531ceea6 SHA1 4fd49e867c324e89cb6b269778e0c925c6d1d759 SHA256 7a21d7a497c860299622c9d6c486eb6ebae95eaf99c625081685a67f8b525d69
MISC ChangeLog 364 RMD160 e4d9af52d4e905dbf1281d241a17f51d4c876c58 SHA1 fe53808055a84eef16f06854bb4bc3b45730e9cc SHA256 d26b9662ca408761b0729839687b1fb27f351a33d3006b730cf7311411656d5b
MISC metadata.xml 201 RMD160 a6c5202673c0843bd9d1453b78b3f6bddc62a1f7 SHA1 6c7c52b9cddff4c6507fe6e49be0bbd53611d236 SHA256 180014e727f4e39b95bfeadf7661f97f2a0c8fe30658a82cd676fac065c7b3c9