[gentoo-commits] gentoo-x86 commit in gnome-extra/cinnamon-desktop: cinnamon-desktop-2.6.5.ebuild ChangeLog

[Pacho Ramos (pacho)]

pacho       15/07/04 19:17:49

  Modified:             ChangeLog
  Added:                cinnamon-desktop-2.6.5.ebuild
  Log:
  Version bump
  
  (Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

Revision  Changes    Path
1.11                 gnome-extra/cinnamon-desktop/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/cinnamon-desktop/ChangeLog?rev=1.11&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/cinnamon-desktop/ChangeLog?rev=1.11&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/cinnamon-desktop/ChangeLog?r1=1.10&r2=1.11

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-extra/cinnamon-desktop/ChangeLog,v
retrieving revision 1.10
retrieving revision 1.11
diff -u -r1.10 -r1.11
--- ChangeLog	14 Jun 2015 01:54:17 -0000	1.10
+++ ChangeLog	4 Jul 2015 19:17:49 -0000	1.11
@@ -1,6 +1,11 @@
 # ChangeLog for gnome-extra/cinnamon-desktop
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-extra/cinnamon-desktop/ChangeLog,v 1.10 2015/06/14 01:54:17 tetromino Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/cinnamon-desktop/ChangeLog,v 1.11 2015/07/04 19:17:49 pacho Exp $
+
+*cinnamon-desktop-2.6.5 (04 Jul 2015)
+
+  04 Jul 2015; Pacho Ramos <pacho@g.o> +cinnamon-desktop-2.6.5.ebuild:
+  Version bump
 
 *cinnamon-desktop-2.6.4 (13 Jun 2015)
 



1.1                  gnome-extra/cinnamon-desktop/cinnamon-desktop-2.6.5.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/cinnamon-desktop/cinnamon-desktop-2.6.5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/cinnamon-desktop/cinnamon-desktop-2.6.5.ebuild?rev=1.1&content-type=text/plain

Index: cinnamon-desktop-2.6.5.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/gnome-extra/cinnamon-desktop/cinnamon-desktop-2.6.5.ebuild,v 1.1 2015/07/04 19:17:49 pacho Exp $

EAPI="5"
GCONF_DEBUG="no"
PYTHON_COMPAT=( python2_7 )

inherit autotools eutils gnome2 python-single-r1

DESCRIPTION="A collection of libraries and utilites used by Cinnamon"
HOMEPAGE="http://cinnamon.linuxmint.com/"
SRC_URI="https://github.com/linuxmint/cinnamon-desktop/archive/${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="GPL-2+ FDL-1.1+ LGPL-2+"
SLOT="0/4" # subslot = libcinnamon-desktop soname version
KEYWORDS="~amd64 ~x86"
IUSE="+introspection systemd"

COMMON_DEPEND="
	>=dev-libs/glib-2.37.3:2
	>=x11-libs/gdk-pixbuf-2.22:2[introspection?]
	>=x11-libs/gtk+-3.3.16:3[introspection?]
	>=x11-libs/libXext-1.1
	>=x11-libs/libXrandr-1.3
	x11-libs/cairo:=[X]
	x11-libs/libX11
	x11-libs/libxkbfile
	x11-misc/xkeyboard-config
	>=gnome-base/gsettings-desktop-schemas-3.5.91
	introspection? ( >=dev-libs/gobject-introspection-0.9.7:= )

	${PYTHON_DEPS}
"
RDEPEND="${COMMON_DEPEND}
	dev-python/pygobject:3[${PYTHON_USEDEP}]
"
DEPEND="${COMMON_DEPEND}
	>=dev-util/gtk-doc-am-1.4
	>=dev-util/intltool-0.40.6
	gnome-base/gnome-common
	x11-proto/randrproto
	x11-proto/xproto
	virtual/pkgconfig
"

pkg_setup() {
	python_setup
}

src_prepare() {
	epatch_user
	eautoreconf

	# Fix intltool unittest
	echo "schemas/org.cinnamon.desktop.keybindings.gschema.xml.in.in" >> po/POTFILES.in
	echo "schemas/org.cinnamon.desktop.keybindings.media-keys.gschema.xml.in.in" >> po/POTFILES.in
	echo "schemas/org.cinnamon.desktop.notifications.gschema.xml.in.in" >> po/POTFILES.in
	echo "schemas/org.cinnamon.desktop.privacy.gschema.xml.in.in" >> po/POTFILES.in

	python_fix_shebang files
	gnome2_src_prepare
}

src_configure() {
	DOCS="AUTHORS ChangeLog HACKING MAINTAINERS README"

	gnome2_src_configure \
		--disable-static \
		$(use_enable introspection)
}

src_install() {
	gnome2_src_install

	# set sane default gschema values for systemd users
	if use systemd; then
		insinto /usr/share/glib-2.0/schemas/
		newins "${FILESDIR}"/${PN}-2.6.4.systemd.gschema.override ${PN}.systemd.gschema.override
	fi
}