[gentoo-commits] gentoo-x86 commit in media-sound/cantata: cantata-1.0.3.ebuild ChangeLog

[Ben de Groot (yngwin)]

yngwin      13/06/02 06:12:25

  Modified:             ChangeLog
  Added:                cantata-1.0.3.ebuild
  Log:
  Version bump (bug #468570); ebuild from kde overlay with slight improvements
  
  (Portage version: 2.2.0_alpha177/cvs/Linux x86_64, signed Manifest commit with key 0x2B2474AD43CE296E!)

Revision  Changes    Path
1.17                 media-sound/cantata/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/cantata/ChangeLog?rev=1.17&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/cantata/ChangeLog?rev=1.17&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/cantata/ChangeLog?r1=1.16&r2=1.17

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/cantata/ChangeLog,v
retrieving revision 1.16
retrieving revision 1.17
diff -u -r1.16 -r1.17
--- ChangeLog	12 May 2013 07:45:44 -0000	1.16
+++ ChangeLog	2 Jun 2013 06:12:25 -0000	1.17
@@ -1,6 +1,11 @@
 # ChangeLog for media-sound/cantata
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/cantata/ChangeLog,v 1.16 2013/05/12 07:45:44 patrick Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/cantata/ChangeLog,v 1.17 2013/06/02 06:12:25 yngwin Exp $
+
+*cantata-1.0.3 (02 Jun 2013)
+
+  02 Jun 2013; Ben de Groot <yngwin@g.o> +cantata-1.0.3.ebuild:
+  Version bump (bug #468570); ebuild from kde overlay with slight improvements
 
   12 May 2013; Patrick Lauer <patrick@g.o> metadata.xml:
   Remove obsolete useflag from metadata.xml



1.1                  media-sound/cantata/cantata-1.0.3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/cantata/cantata-1.0.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/cantata/cantata-1.0.3.ebuild?rev=1.1&content-type=text/plain

Index: cantata-1.0.3.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/cantata/cantata-1.0.3.ebuild,v 1.1 2013/06/02 06:12:25 yngwin Exp $

EAPI=5
KDE_REQUIRED="optional"
inherit kde4-base

DESCRIPTION="A featureful and configurable Qt4 client for the music player daemon (MPD)"
HOMEPAGE="http://kde-apps.org/content/show.php?content=147733"
SRC_URI="http://${PN}.googlecode.com/files/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="4"
KEYWORDS="~amd64 ~x86"
IUSE="kde mtp phonon qt5 replaygain webkit"
REQUIRED_USE="mtp? ( kde ) qt5? ( !kde !phonon )"

DEPEND="
	kde? (
		media-libs/taglib[asf,mp4]
		media-libs/taglib-extras
		mtp? ( media-libs/libmtp )
	)
	phonon? ( || ( media-libs/phonon dev-qt/qtphonon:4 ) )
	qt5? (
		dev-qt/qtconcurrent:5
		dev-qt/qtnetwork:5
		dev-qt/qtwidgets:5
		dev-qt/qtxml:5
	)
	!qt5? (
		dev-qt/qtcore:4
		dev-qt/qtdbus:4
		dev-qt/qtgui:4
	)
	replaygain? (
		media-libs/speex
		media-libs/taglib[asf,mp4]
		media-libs/taglib-extras
		media-sound/mpg123
		virtual/ffmpeg
	)
	webkit? ( dev-qt/qtwebkit:4 )
"
RDEPEND="${DEPEND}
	$(add_kdebase_dep oxygen-icons)
"

src_prepare() {
	# make desktop file pass validation
	sed -e 's/MPD/MPD;/' -i ${PN}.desktop || die 'sed failed'
}

src_configure() {
	local mycmakeargs=(
		$(cmake-utils_use_enable kde)
		$(cmake-utils_use_enable phonon)
		$(cmake-utils_use_enable replaygain FFMPEG)
		$(cmake-utils_use_enable replaygain MPG123)
		$(cmake-utils_use_enable replaygain SPEEXDSP)
		$(cmake-utils_use_enable mtp)
	)

	# kde fails to build without taglib
	# taglib is required to enable replaygain
	if use kde || use replaygain; then
		mycmakeargs+=(
			-DENABLE_TAGLIB=ON
			-DENABLE_TAGLIB_EXTRAS=ON
		)
	fi

	kde4-base_src_configure
}