[gentoo-commits] repo/gentoo:master commit in: media-libs/glfw/

[Ionen Wolkens]

commit:     ea3f59777a76bb44feeef346e9d55496a5826646
Author:     Haelwenn (lanodan) Monnier <contact <AT> hacktivis <DOT> me>
AuthorDate: Sun Jun 27 06:59:57 2021 +0000
Commit:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
CommitDate: Wed Jun 30 02:40:38 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ea3f5977

media-libs/glfw: Add support for multilib

This is required for proprietary games compiled only for x86_32.

Closes: https://bugs.gentoo.org/580890
Signed-off-by: Haelwenn (lanodan) Monnier <contact <AT> hacktivis.me>
Closes: https://github.com/gentoo/gentoo/pull/21441
Signed-off-by: Ionen Wolkens <ionen <AT> gentoo.org>

 media-libs/glfw/glfw-3.3.4-r1.ebuild | 55 ++++++++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)

diff --git a/media-libs/glfw/glfw-3.3.4-r1.ebuild b/media-libs/glfw/glfw-3.3.4-r1.ebuild
new file mode 100644
index 00000000000..43f33ee0dd7
--- /dev/null
+++ b/media-libs/glfw/glfw-3.3.4-r1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+CMAKE_ECLASS=cmake
+inherit cmake-multilib
+
+DESCRIPTION="The Portable OpenGL FrameWork"
+HOMEPAGE="https://www.glfw.org/"
+SRC_URI="https://github.com/glfw/glfw/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="ZLIB"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc64 ~x86"
+IUSE="wayland"
+
+RDEPEND="
+	x11-libs/libxkbcommon[${MULTILIB_USEDEP}]
+	!wayland? (
+		virtual/opengl[${MULTILIB_USEDEP}]
+		x11-libs/libX11[${MULTILIB_USEDEP}]
+		x11-libs/libXcursor[${MULTILIB_USEDEP}]
+		x11-libs/libXinerama[${MULTILIB_USEDEP}]
+		x11-libs/libXrandr[${MULTILIB_USEDEP}]
+		x11-libs/libXxf86vm[${MULTILIB_USEDEP}]
+	)
+	wayland? (
+		dev-libs/wayland[${MULTILIB_USEDEP}]
+		media-libs/mesa[egl,wayland,${MULTILIB_USEDEP}]
+	)
+"
+DEPEND="
+	${RDEPEND}
+	!wayland? (
+		x11-base/xorg-proto
+		x11-libs/libXi[${MULTILIB_USEDEP}]
+	)
+	wayland? ( dev-libs/wayland-protocols )
+"
+BDEPEND="
+	wayland? (
+		dev-util/wayland-scanner
+		kde-frameworks/extra-cmake-modules
+	)
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DGLFW_BUILD_EXAMPLES=no
+		-DGLFW_USE_WAYLAND="$(usex wayland)"
+		-DBUILD_SHARED_LIBS=1
+	)
+	cmake-multilib_src_configure
+}