Gentoo Archives: gentoo-commits

From: Sebastien Fabbro <bicatali@g.o>
To: gentoo-commits@l.g.o
Subject: [gentoo-commits] repo/gentoo:master commit in: dev-python/ginga/
Date: Thu, 29 Dec 2016 07:02:15
Message-Id: 1482994887.94986c3b7151d2c96bf979c6f9368201edcacbde.bicatali@gentoo
1 commit: 94986c3b7151d2c96bf979c6f9368201edcacbde
2 Author: S├ębastien Fabbro <bicatali <AT> gentoo <DOT> org>
3 AuthorDate: Thu Dec 29 01:09:36 2016 +0000
4 Commit: Sebastien Fabbro <bicatali <AT> gentoo <DOT> org>
5 CommitDate: Thu Dec 29 07:01:27 2016 +0000
6 URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=94986c3b
7
8 dev-python/ginga: version bump
9
10 Package-Manager: Portage-2.3.3, Repoman-2.3.1
11
12 dev-python/ginga/Manifest | 1 +
13 dev-python/ginga/ginga-2.6.1.ebuild | 79 +++++++++++++++++++++++++++++++++++++
14 2 files changed, 80 insertions(+)
15
16 diff --git a/dev-python/ginga/Manifest b/dev-python/ginga/Manifest
17 index d355770..93b58a8 100644
18 --- a/dev-python/ginga/Manifest
19 +++ b/dev-python/ginga/Manifest
20 @@ -1 +1,2 @@
21 DIST ginga-2.6.0.tar.gz 12682426 SHA256 ae4661cc2438cafcd66281172776e6968255482d122a154030bc815c19e0afd4 SHA512 b07fc8a20f17173682bfce5190200f3080dff12fae73e06e1447ebdfe1dc98362e03bd2ed5c524fce0ffcd15e3b74170c97a74222f7601f25e9e5bf0bd93148a WHIRLPOOL 430f9e0585f1b4546400ca9ba89eda1a81d88fd62ebade5d907d069f3f19e6155d7b7c8bdaa9186ba306873a1d41f7cfb64ed5f2262a96eb1c5e06f4a1027d82
22 +DIST ginga-2.6.1.tar.gz 12693626 SHA256 5087f1213a0aa2fffdc3d81a258d1a4662f92894f532843ba2c83ba237363116 SHA512 f12bc41de0f6efb39096f1175a7d94659135230fc2d024ac0532f09e39d1d674cbce28ce073c37e8cbff19db9b8d0fe6c40ee829a4ba38ad276b39ab6765c5a9 WHIRLPOOL ada7e2174ba401581d70b88301f145e6ba348aec71271eac982056ce3c20fb8c1dcfa31200506a5bb6183777708df5ee57a2ccb50f2732ea90a20c864aea6683
23
24 diff --git a/dev-python/ginga/ginga-2.6.1.ebuild b/dev-python/ginga/ginga-2.6.1.ebuild
25 new file mode 100644
26 index 00000000..249b5fa
27 --- /dev/null
28 +++ b/dev-python/ginga/ginga-2.6.1.ebuild
29 @@ -0,0 +1,79 @@
30 +# Copyright 1999-2016 Gentoo Foundation
31 +# Distributed under the terms of the GNU General Public License v2
32 +# $Id$
33 +
34 +EAPI=6
35 +
36 +PYTHON_COMPAT=( python{2_7,3_5} )
37 +PYTHON_REQ_USE='tk?'
38 +
39 +inherit distutils-r1 eutils fdo-mime
40 +
41 +DESCRIPTION="Astronomical image toolkit for Python"
42 +HOMEPAGE="https://ejeschke.github.io/ginga"
43 +SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
44 +KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
45 +
46 +LICENSE="BSD"
47 +SLOT="0"
48 +IUSE="doc examples gtk qt4 qt5 test tk"
49 +
50 +RDEPEND="
51 + dev-python/astropy[${PYTHON_USEDEP}]
52 + media-fonts/roboto
53 + gtk? ( dev-python/pygobject[${PYTHON_USEDEP},cairo] )
54 + qt4? ( || (
55 + dev-python/pyside[${PYTHON_USEDEP},help,X]
56 + dev-python/PyQt4[${PYTHON_USEDEP},help,X]
57 + ) )
58 + qt5? ( dev-python/PyQt5[${PYTHON_USEDEP},help,gui,widgets] )"
59 +
60 +DEPEND="${RDEPEND}
61 + dev-python/astropy-helpers[${PYTHON_USEDEP}]
62 + dev-python/setuptools[${PYTHON_USEDEP}]
63 + doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )"
64 +
65 +PATCHES=( "${FILESDIR}"/${PN}-no-roboto.patch )
66 +
67 +python_prepare_all() {
68 + # use system astropy-helpers instead of bundled one
69 + sed -i -e '/auto_use/s/True/False/' setup.cfg || die
70 + distutils-r1_python_prepare_all
71 +}
72 +
73 +python_compile_all() {
74 + if use doc; then
75 + python_setup
76 + PYTHONPATH="${BUILD_DIR}"/lib esetup.py build_sphinx --no-intersphinx
77 + fi
78 +}
79 +
80 +python_test() {
81 + esetup.py test
82 +}
83 +
84 +python_install_all() {
85 + use doc && local HTML_DOCS=( doc/_build/html/. )
86 + distutils-r1_python_install_all
87 + rm -r "${ED%/}"/usr/lib*/*/*/ginga/examples || die
88 + if use examples; then
89 + insinto /usr/share/doc/${PF}
90 + doins -r ginga/examples
91 + fi
92 + domenu ginga.desktop
93 +}
94 +
95 +pkg_postinst() {
96 + optfeature "Pick, Cuts, Histogram, LineProfile" \
97 + dev-python/matplotlib sci-libs/scipy
98 + optfeature "Online help browser" dev-qt/qtwebkit
99 + optfeature "To save a movie" media-video/mplayer
100 + optfeature "Speeds up rotation and some transformations" \
101 + dev-python/numexpr dev-python/opencv dev-python/pyopencl
102 + optfeature "Aids in identifying files when opening them" \
103 + dev-python/filemagic
104 + optfeature "Useful for various RGB file manipulations" dev-python/pillow
105 +
106 + # Update mimedb for the new .desktop file
107 + fdo-mime_desktop_database_update
108 +}