[gentoo-commits] gentoo-x86 commit in net-im/centerim: ChangeLog centerim-4.22.1_p20071103.ebuild centerim-4.22.2.ebuild centerim-4.22.1_p20070625.ebuild

[Sven Wegener (swegener)]

swegener    07/12/08 20:51:14

  Modified:             ChangeLog centerim-4.22.1_p20071103.ebuild
  Added:                centerim-4.22.2.ebuild
  Removed:              centerim-4.22.1_p20070625.ebuild
  Log:
  Version bump.
  (Portage version: 2.1.3.19)

Revision  Changes    Path
1.8                  net-im/centerim/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-im/centerim/ChangeLog?rev=1.8&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-im/centerim/ChangeLog?rev=1.8&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-im/centerim/ChangeLog?r1=1.7&r2=1.8

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-im/centerim/ChangeLog,v
retrieving revision 1.7
retrieving revision 1.8
diff -u -r1.7 -r1.8
--- ChangeLog	28 Nov 2007 20:08:06 -0000	1.7
+++ ChangeLog	8 Dec 2007 20:51:13 -0000	1.8
@@ -1,6 +1,13 @@
 # ChangeLog for net-im/centerim
 # Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-im/centerim/ChangeLog,v 1.7 2007/11/28 20:08:06 swegener Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-im/centerim/ChangeLog,v 1.8 2007/12/08 20:51:13 swegener Exp $
+
+*centerim-4.22.2 (08 Dec 2007)
+
+  08 Dec 2007; Sven Wegener <swegener@g.o>
+  -centerim-4.22.1_p20070625.ebuild, centerim-4.22.1_p20071103.ebuild,
+  +centerim-4.22.2.ebuild:
+  Version bump.
 
 *centerim-4.22.1_p20071103 (28 Nov 2007)
 



1.2                  net-im/centerim/centerim-4.22.1_p20071103.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-im/centerim/centerim-4.22.1_p20071103.ebuild?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-im/centerim/centerim-4.22.1_p20071103.ebuild?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-im/centerim/centerim-4.22.1_p20071103.ebuild?r1=1.1&r2=1.2

Index: centerim-4.22.1_p20071103.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-im/centerim/centerim-4.22.1_p20071103.ebuild,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- centerim-4.22.1_p20071103.ebuild	28 Nov 2007 20:08:06 -0000	1.1
+++ centerim-4.22.1_p20071103.ebuild	8 Dec 2007 20:51:13 -0000	1.2
@@ -1,6 +1,6 @@
 # Copyright 1999-2007 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-im/centerim/centerim-4.22.1_p20071103.ebuild,v 1.1 2007/11/28 20:08:06 swegener Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-im/centerim/centerim-4.22.1_p20071103.ebuild,v 1.2 2007/12/08 20:51:13 swegener Exp $
 
 inherit eutils
 
@@ -78,7 +78,6 @@
 	unpack ${A}
 	cd "${S}"
 
-	epatch "${FILESDIR}"/${PN}-imotr-config.patch
 	epatch "${FILESDIR}"/${PN}-ack-sbl.patch
 }
 



1.1                  net-im/centerim/centerim-4.22.2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-im/centerim/centerim-4.22.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-im/centerim/centerim-4.22.2.ebuild?rev=1.1&content-type=text/plain

Index: centerim-4.22.2.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-im/centerim/centerim-4.22.2.ebuild,v 1.1 2007/12/08 20:51:13 swegener Exp $

inherit eutils

PROTOCOL_IUSE="aim gadu icq irc jabber lj msn rss yahoo"
IUSE="${PROTOCOL_IUSE} bidi nls ssl crypt jpeg otr"

DESCRIPTION="CenterIM is a fork of CenterICQ - a ncurses ICQ/Yahoo!/AIM/IRC/MSN/Jabber/GaduGadu/RSS/LiveJournal Client"
if [[ ${PV} = *_p* ]] # is this a snaphot?
then
	SRC_URI="http://www.centerim.org/download/snapshots/${PN}-${PV/*_p/}.tar.gz"
else
	SRC_URI="http://www.centerim.org/download/releases/${P}.tar.gz"
fi
HOMEPAGE="http://www.centerim.org/"
SLOT="0"
LICENSE="GPL-2"
KEYWORDS="~x86 ~amd64"

DEPEND=">=sys-libs/ncurses-5.2
	bidi? ( dev-libs/fribidi )
	ssl? ( >=dev-libs/openssl-0.9.6g )
	jpeg? ( media-libs/jpeg )
	otr? ( net-libs/libotr )
	jabber? ( crypt? ( >=app-crypt/gpgme-1.0.2 ) )
	msn? (
		net-misc/curl
		dev-libs/openssl
	)"

RDEPEND="${DEPEND}
	nls? ( sys-devel/gettext )"

S="${WORKDIR}"/${P/_p*}

check_protocol_iuse() {
	local flag

	for flag in ${PROTOCOL_IUSE}
	do
		use ${flag} && return 0
	done

	return 1
}

pkg_setup() {
	if ! check_protocol_iuse
	then
		eerror
		eerror "Please activate at least one of the following protocol USE flags:"
		eerror "${PROTOCOL_IUSE}"
		eerror
		die "Please activate at least one protocol USE flag!"
	fi

	if use msn && ! built_with_use net-misc/curl ssl
	then
		eerror
		eerror "As of right now, the msn use flags requires curl to be built"
		eerror "with SSL support. Make sure ssl is in your USE flags and"
		eerror "re-emerge net-misc/curl."
		eerror
		die "net-misc/curl dependencie issue"
	fi

	if use gadu && ! use jpeg
	then
		ewarn
		ewarn "You need jpeg support to be able to register Gadu-Gadu accounts!"
		ewarn
	fi
}

src_compile() {
	econf \
		$(use_with ssl) \
		$(use_enable aim) \
		$(use_with bidi fribidi) \
		$(use_with jpeg libjpeg) \
		$(use_with otr libotr) \
		$(use_enable gadu gg) \
		$(use_enable icq) \
		$(use_enable irc) \
		$(use_enable jabber) \
		$(use_enable lj) \
		$(use_enable msn) \
		$(use_enable nls locales-fix) \
		$(use_enable nls) \
		$(use_enable rss) \
		$(use_enable yahoo) \
		|| die "econf failed"
	emake || die "emake failed"
}

src_install () {
	emake DESTDIR="${D}" install || die "emake install failed"

	dodoc AUTHORS ChangeLog FAQ README THANKS TODO
}



-- 
gentoo-commits@g.o mailing list