[gentoo-commits] gentoo-x86 commit in dev-db/pgpool2: pgpool2-3.0.1.ebuild ChangeLog metadata.xml

[Tomas Chvatal (scarabeus)]

scarabeus    11/01/26 16:49:10

  Added:                pgpool2-3.0.1.ebuild ChangeLog metadata.xml
  Log:
  Initial commit. Fixes bug #196300. Ebuild made thanks to ccss.cz.
  
  (Portage version: 2.2.0_alpha19/cvs/Linux x86_64)

Revision  Changes    Path
1.1                  dev-db/pgpool2/pgpool2-3.0.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/pgpool2/pgpool2-3.0.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/pgpool2/pgpool2-3.0.1.ebuild?rev=1.1&content-type=text/plain

Index: pgpool2-3.0.1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-db/pgpool2/pgpool2-3.0.1.ebuild,v 1.1 2011/01/26 16:49:09 scarabeus Exp $

EAPI=3

inherit autotools-utils

MY_P="${PN/2/-II}-${PV}"

DESCRIPTION="Connection pool server for PostgreSQL"
HOMEPAGE="http://pgpool.projects.postgresql.org/"
SRC_URI="http://pgfoundry.org/frs/download.php/2841/${MY_P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="pam ssl static-libs"

RDEPEND="
	dev-db/postgresql-base
	pam? ( sys-auth/pambase )
	ssl? ( dev-libs/openssl )
"
DEPEND="${DEPEND}
	sys-devel/bison"

AUTOTOOLS_IN_SOURCE_BUILD="1"

PATCHES=(
	"${FILESDIR}/${PN}-tmpdir.patch"
	"${FILESDIR}/${PV}-fix_md5_malloc.patch"
)

DOCS=(
	"NEWS"
	"doc/where_to_send_queries.pdf"
)
HTML_DOCS=(
	"doc/pgpool-en.html" "doc/pgpool.css"
	"doc/tutorial-en.html"
)

S=${WORKDIR}/${MY_P}

src_configure() {
	local myeconfargs=(
		"--sysconfdir=${EROOT}/etc/${PN}"
		"--disable-dependency-tracking"
		"--disable-rpath"
		$(use_with ssl openssl)
		$(use_with pam)
	)
	autotools-utils_src_configure
}

src_install() {
	autotools-utils_src_install
	remove_libtool_files all
	# move misc data to proper folder
	mv "${ED}/usr/share/${PN/2/-II}" "${ED}/usr/share/${PN}" || die

	newinitd "${FILESDIR}/${PN}.initd" ${PN} || die
}



1.1                  dev-db/pgpool2/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/pgpool2/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/pgpool2/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for dev-db/pgpool2
# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/dev-db/pgpool2/ChangeLog,v 1.1 2011/01/26 16:49:09 scarabeus Exp $

*pgpool2-3.0.1 (26 Jan 2011)

  26 Jan 2011; Tomáš Chvátal <scarabeus@g.o>
  +files/3.0.1-fix_md5_malloc.patch, +files/pgpool2-tmpdir.patch,
  +pgpool2-3.0.1.ebuild, +files/pgpool2.initd, +metadata.xml:
  Initial commit. Fixes bug #196300. Ebuild made thanks to ccss.cz.




1.1                  dev-db/pgpool2/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/pgpool2/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/pgpool2/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
	<herd>postgresql</herd>
</pkgmetadata>