[gentoo-commits] repo/gentoo:master commit in: app-text/dos2unix/

[Patrice Clement]

commit:     9003c5f46a4b302330a295e1276ba1ab6723c8b9
Author:     Patrice Clement <monsieurp <AT> gentoo <DOT> org>
AuthorDate: Fri Sep 25 04:14:47 2015 +0000
Commit:     Patrice Clement <monsieurp <AT> gentoo <DOT> org>
CommitDate: Fri Sep 25 04:18:22 2015 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9003c5f4

app-text/dos2unix: Remove app-text/unix2dos blocker from DEPEND. Fixes bug 525826.

Package-Manager: portage-2.2.18
Signed-off-by: Patrice Clement <monsieurp <AT> gentoo.org>

 app-text/dos2unix/dos2unix-7.3-r1.ebuild | 60 ++++++++++++++++++++++++++++++++
 1 file changed, 60 insertions(+)

diff --git a/app-text/dos2unix/dos2unix-7.3-r1.ebuild b/app-text/dos2unix/dos2unix-7.3-r1.ebuild
new file mode 100644
index 0000000..d8a8be9
--- /dev/null
+++ b/app-text/dos2unix/dos2unix-7.3-r1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit eutils toolchain-funcs
+
+DESCRIPTION="Convert DOS or MAC text files to UNIX format or vice versa"
+HOMEPAGE="http://www.xs4all.nl/~waterlan/dos2unix.html http://sourceforge.net/projects/dos2unix/"
+SRC_URI="
+	http://www.xs4all.nl/~waterlan/${PN}/${P}.tar.gz
+	mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~sparc-solaris ~sparc64-solaris"
+IUSE="debug nls test"
+
+RDEPEND="
+	!app-text/hd2u
+	virtual/libintl"
+
+DEPEND="
+	${RDEPEND}
+	nls? ( sys-devel/gettext )
+	test? ( virtual/perl-Test-Simple )
+	dev-lang/perl"
+
+src_prepare() {
+	sed \
+		-e '/^LDFLAGS/s|=|+=|' \
+		-e '/CFLAGS_OS \+=/d' \
+		-e '/LDFLAGS_EXTRA \+=/d' \
+		-e "/^CFLAGS/s|-O2|${CFLAGS}|" \
+		-i Makefile || die
+
+	if use debug ; then
+		sed -e "/^DEBUG/s:0:1:" \
+			-e "/EXTRA_CFLAGS +=/s:-g::" \
+			-i Makefile || die
+	fi
+
+	tc-export CC
+}
+
+lintl() {
+	# same logic as from virtual/libintl
+	use !elibc_glibc && use !elibc_uclibc && echo "-lintl"
+}
+
+src_compile() {
+	emake prefix="${EPREFIX}/usr" \
+		$(usex nls "LDFLAGS_EXTRA=$(lintl)" "ENABLE_NLS=")
+}
+
+src_install() {
+	emake DESTDIR="${D}" prefix="${EPREFIX}/usr" \
+		$(usex nls "" "ENABLE_NLS=") install
+}