[gentoo-commits] gentoo-x86 commit in sys-apps/proot: ChangeLog proot-4.0.1.ebuild proot-4.0.0.ebuild

[Sergey Popov (pinkbyte)]

pinkbyte    14/09/02 07:07:02

  Modified:             ChangeLog
  Added:                proot-4.0.1.ebuild
  Removed:              proot-4.0.0.ebuild
  Log:
  Version bump, wrt bug #520050 with fix for bug #517496. Thanks to Joakim Tjernlund <Joakim.Tjernlund AT transmode.se> for discovering this issues. Drop old version
  
  (Portage version: 2.2.12/cvs/Linux x86_64, signed Manifest commit with key 0x1F357D42)

Revision  Changes    Path
1.10                 sys-apps/proot/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/proot/ChangeLog?rev=1.10&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/proot/ChangeLog?rev=1.10&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/proot/ChangeLog?r1=1.9&r2=1.10

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/proot/ChangeLog,v
retrieving revision 1.9
retrieving revision 1.10
diff -u -r1.9 -r1.10
--- ChangeLog	23 Jul 2014 12:46:07 -0000	1.9
+++ ChangeLog	2 Sep 2014 07:07:02 -0000	1.10
@@ -1,6 +1,14 @@
 # ChangeLog for sys-apps/proot
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/proot/ChangeLog,v 1.9 2014/07/23 12:46:07 pinkbyte Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/proot/ChangeLog,v 1.10 2014/09/02 07:07:02 pinkbyte Exp $
+
+*proot-4.0.1 (02 Sep 2014)
+
+  02 Sep 2014; Sergey Popov <pinkbyte@g.o> -proot-4.0.0.ebuild,
+  +proot-4.0.1.ebuild, +files/proot-4.0.1-argv.patch:
+  Version bump, wrt bug #520050 with fix for bug #517496. Thanks to Joakim
+  Tjernlund <Joakim.Tjernlund AT transmode.se> for discovering this issues.
+  Drop old version
 
 *proot-4.0.0 (23 Jul 2014)
 



1.1                  sys-apps/proot/proot-4.0.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/proot/proot-4.0.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/proot/proot-4.0.1.ebuild?rev=1.1&content-type=text/plain

Index: proot-4.0.1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/proot/proot-4.0.1.ebuild,v 1.1 2014/09/02 07:07:02 pinkbyte Exp $

EAPI=5
MY_PN="PRoot"

inherit eutils toolchain-funcs

DESCRIPTION="User-space implementation of chroot, mount --bind, and binfmt_misc"
HOMEPAGE="http://proot.me"
SRC_URI="https://github.com/cedric-vincent/${MY_PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="care test"

RDEPEND="care? ( app-arch/libarchive:0= )
	 sys-libs/talloc"
DEPEND="${RDEPEND}
	care? ( dev-libs/uthash )
	test? ( dev-util/valgrind )"

# Breaks sandbox
RESTRICT="test"

S="${WORKDIR}/${MY_PN}-${PV}"

src_prepare() {
	epatch  "${FILESDIR}/${PN}-3.2.1-makefile.patch" \
		"${FILESDIR}/${PN}-2.3.1-lib-paths-fix.patch" \
		"${FILESDIR}/${PN}-3.2.2-build-care.patch" \
		"${FILESDIR}/${PN}-4.0.1-argv.patch"
	epatch_user
}

src_compile() {
	# build the proot and care targets
	emake -C src V=1 \
		CC="$(tc-getCC)" \
		CHECK_VERSION="true" \
		CAREBUILDENV="ok" \
		proot $(use care && echo "care")
}

src_install() {
	use care && dobin src/care
	dobin src/proot
	newman doc/proot/man.1 proot.1
	dodoc doc/proot/*.txt
	dodoc -r doc/articles
}

src_test() {
	emake -C tests -j1 CC="$(tc-getCC)"
}

pkg_postinst() {
	if use care; then
		elog "You have enabled 'care' USE flag, that builds and installs"
		elog "dynamically linked care binary."
		elog "Upstream does NOT support such way of building CARE,"
		elog "it provides only prebuilt binaries."
		elog "CARE also has known problems on hardened systems"
		elog "Please do NOT file bugs about them to http://bugs.gentoo.org"
	fi
}