[gentoo-commits] gentoo-x86 commit in media-sound/lame: ChangeLog lame-3.99.5.ebuild

[Alexis Ballier (aballier)]

aballier    12/03/01 12:14:46

  Modified:             ChangeLog
  Added:                lame-3.99.5.ebuild
  Log:
  version bump
  
  (Portage version: 2.2.0_alpha89/cvs/Linux x86_64)

Revision  Changes    Path
1.146                media-sound/lame/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/lame/ChangeLog?rev=1.146&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/lame/ChangeLog?rev=1.146&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/lame/ChangeLog?r1=1.145&r2=1.146

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/lame/ChangeLog,v
retrieving revision 1.145
retrieving revision 1.146
diff -u -r1.145 -r1.146
--- ChangeLog	4 Feb 2012 16:52:02 -0000	1.145
+++ ChangeLog	1 Mar 2012 12:14:46 -0000	1.146
@@ -1,6 +1,11 @@
 # ChangeLog for media-sound/lame
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/lame/ChangeLog,v 1.145 2012/02/04 16:52:02 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/lame/ChangeLog,v 1.146 2012/03/01 12:14:46 aballier Exp $
+
+*lame-3.99.5 (01 Mar 2012)
+
+  01 Mar 2012; Alexis Ballier <aballier@g.o> +lame-3.99.5.ebuild:
+  version bump
 
 *lame-3.99.4 (04 Feb 2012)
 



1.1                  media-sound/lame/lame-3.99.5.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/lame/lame-3.99.5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/lame/lame-3.99.5.ebuild?rev=1.1&content-type=text/plain

Index: lame-3.99.5.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/lame/lame-3.99.5.ebuild,v 1.1 2012/03/01 12:14:46 aballier Exp $

EAPI=4
inherit autotools eutils

DESCRIPTION="LAME Ain't an MP3 Encoder"
HOMEPAGE="http://lame.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
IUSE="debug mmx mp3rtp sndfile static-libs"

RDEPEND=">=sys-libs/ncurses-5.7-r7
	sndfile? ( >=media-libs/libsndfile-1.0.2 )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	mmx? ( dev-lang/nasm )"

src_prepare() {
	epatch \
		"${FILESDIR}"/${PN}-3.96-ccc.patch \
		"${FILESDIR}"/${PN}-3.98-gtk-path.patch

	mkdir libmp3lame/i386/.libs || die #workaround parallel build with nasm

	sed -i -e '/define sp/s/+/ + /g' libmp3lame/i386/nasm.h || die

	use mmx || sed -i -e '/AC_PATH_PROG/s:nasm:dIsAbLe&:' configure.in #361879

	AT_M4DIR=${S} eautoreconf
	epunt_cxx #74498
}

src_configure() {
	local myconf
	use mmx && myconf+="--enable-nasm" #361879
	use sndfile && myconf+=" --with-fileio=sndfile"

	econf \
		$(use_enable static-libs static) \
		$(use_enable debug debug norm) \
		--disable-mp3x \
		$(use_enable mp3rtp) \
		--enable-dynamic-frontends \
		${myconf}
}

src_install() {
	emake DESTDIR="${D}" pkghtmldir="${EPREFIX}/usr/share/doc/${PF}/html" install
	dobin misc/mlame

	dodoc API ChangeLog HACKING README STYLEGUIDE TODO USAGE
	dohtml misc/lameGUI.html Dll/LameDLLInterface.htm

	find "${ED}" -name '*.la' -exec rm -f {} +
}