[gentoo-commits] repo/gentoo:master commit in: media-sound/whipper/

[Andreas Sturmlechner]

commit:     348b03bf919970a7da51e1249963c8f29ec06169
Author:     Quentin Retornaz <gentoo <AT> retornaz <DOT> com>
AuthorDate: Sun Dec 16 22:45:14 2018 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Thu Jan 10 21:54:09 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=348b03bf

media-sound/whipper: bump version to 0.7.3

Bug: https://bugs.gentoo.org/673294
Signed-off-by: Quentin Retornaz <gentoo <AT> retornaz.com>
Package-Manager: Portage-2.3.51, Repoman-2.3.11
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 media-sound/whipper/Manifest             |  1 +
 media-sound/whipper/whipper-0.7.3.ebuild | 63 ++++++++++++++++++++++++++++++++
 2 files changed, 64 insertions(+)

diff --git a/media-sound/whipper/Manifest b/media-sound/whipper/Manifest
index f17bc7ecf08..78e669ce51c 100644
--- a/media-sound/whipper/Manifest
+++ b/media-sound/whipper/Manifest
@@ -1 +1,2 @@
 DIST whipper-0.7.0.tar.gz 160649 BLAKE2B 8e14b6dda00b3c8be7ba0fabb25d1cbca536edc785373986f857bafbc2e54d358f18b27140ffda74384c4e815e68ee466c8fc5e4e5d17aa80c8237fda389ba2b SHA512 b4bf4ca64521d8600288addecec6cbd8e43d1ff9a6b9a60872eff1bd5a2b6966af036d6467ba09273ac78aa01d8cac3be29a0e2c4e6600829b9988a74ef8cd88
+DIST whipper-0.7.3.tar.gz 168393 BLAKE2B b34151ede7c867dbbca34fcec3d8ef81cb50d66abc760fa54bec880f8f1186faf3e0f5298c2890501b9bd2f586b80d2cdc45a0755b6fe12fc1a2215e9ea9ecbb SHA512 ac96393471a6b4c40f5870f6e3183b65d43229314e2a1eacbf065c51ac61cbc772f2de3bde9f20ee1f7ffec427cd03c31f27df60eb6c621a699927646080c0ab

diff --git a/media-sound/whipper/whipper-0.7.3.ebuild b/media-sound/whipper/whipper-0.7.3.ebuild
new file mode 100644
index 00000000000..f7f2f40ca58
--- /dev/null
+++ b/media-sound/whipper/whipper-0.7.3.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 )
+
+inherit distutils-r1
+
+DESCRIPTION="A Python CD-DA ripper preferring accuracy over speed (forked from morituri)"
+HOMEPAGE="https://github.com/whipper-team/whipper"
+SRC_URI="https://github.com/whipper-team/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	media-libs/libsndfile
+	test? ( dev-python/twisted[${PYTHON_USEDEP}] )
+"
+RDEPEND="
+	app-cdr/cdrdao
+	dev-libs/gobject-introspection[${PYTHON_USEDEP}]
+	>=dev-libs/libcdio-paranoia-0.94_p2
+	dev-python/pycdio[${PYTHON_USEDEP}]
+	dev-python/pygobject:2=[${PYTHON_USEDEP}]
+	dev-python/python-musicbrainz-ngs[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	media-libs/flac
+	media-libs/libsndfile
+	media-libs/mutagen[${PYTHON_USEDEP}]
+	media-sound/sox[flac]
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-0.7.0-cdparanoia-name-fix.patch"
+	"${FILESDIR}/${PN}-0.7.0-src-Makefile-respect-CFLAGS.patch"
+)
+
+src_prepare() {
+	# accurip test totally depends on network access
+	rm "${PN}"/test/test_common_accurip.py || die
+
+	distutils-r1_src_prepare
+}
+
+src_compile() {
+	distutils-r1_src_compile
+	emake -C src CC="$(tc-getCC)"
+}
+
+python_test() {
+	"${EPYTHON}" -m unittest discover -v || die "Tests fail with ${EPYTHON}"
+}
+
+src_install() {
+	distutils-r1_src_install
+	emake PREFIX="${EPREFIX}/usr" DESTDIR="${D}" -C src install
+}