[gentoo-commits] gentoo-x86 commit in net-misc/mosh: mosh-1.2.4.ebuild ChangeLog

[Michael Weber (xmw)]

xmw         13/03/27 15:23:26

  Modified:             ChangeLog
  Added:                mosh-1.2.4.ebuild
  Log:
  Version bump
  
  (Portage version: 2.2.0_alpha169/cvs/Linux x86_64, signed Manifest commit with key 62EEF090)

Revision  Changes    Path
1.39                 net-misc/mosh/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/mosh/ChangeLog?rev=1.39&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/mosh/ChangeLog?rev=1.39&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/mosh/ChangeLog?r1=1.38&r2=1.39

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/mosh/ChangeLog,v
retrieving revision 1.38
retrieving revision 1.39
diff -u -r1.38 -r1.39
--- ChangeLog	13 Mar 2013 19:19:51 -0000	1.38
+++ ChangeLog	27 Mar 2013 15:23:26 -0000	1.39
@@ -1,6 +1,11 @@
 # ChangeLog for net-misc/mosh
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/mosh/ChangeLog,v 1.38 2013/03/13 19:19:51 xmw Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/mosh/ChangeLog,v 1.39 2013/03/27 15:23:26 xmw Exp $
+
+*mosh-1.2.4 (27 Mar 2013)
+
+  27 Mar 2013; Michael Weber <xmw@g.o> +mosh-1.2.4.ebuild:
+  Version bump
 
   13 Mar 2013; Michael Weber <xmw@g.o> mosh-9999.ebuild:
   Update live build



1.1                  net-misc/mosh/mosh-1.2.4.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/mosh/mosh-1.2.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/mosh/mosh-1.2.4.ebuild?rev=1.1&content-type=text/plain

Index: mosh-1.2.4.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/mosh/mosh-1.2.4.ebuild,v 1.1 2013/03/27 15:23:26 xmw Exp $

EAPI=4

inherit autotools vcs-snapshot

DESCRIPTION="Mobile shell that supports roaming and intelligent local echo"
HOMEPAGE="http://mosh.mit.edu"
SRC_URI="http://mosh.mit.edu/${P}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~mips ~ppc ~x86 ~arm-linux ~x86-linux"
IUSE="bash-completion +client examples +mosh-hardening +server ufw +utempter"
REQUIRED_USE="|| ( client server )
	examples? ( client )"

RDEPEND="dev-libs/protobuf
	sys-libs/ncurses:5
	virtual/ssh
	client? ( dev-lang/perl
		dev-perl/IO-Tty )
	utempter? ( sys-libs/libutempter )"
DEPEND="${RDEPEND}
	virtual/pkgconfig"

src_prepare() {
	eautoreconf
}

src_configure() {
	econf \
		$(use_enable bash-completion completion) \
		$(use_enable client) \
		$(use_enable server) \
		$(use_enable examples) \
		$(use_enable ufw) \
		$(use_enable mosh-hardening hardening) \
		$(use_with utempter)
}

src_compile() {
	emake V=1
}

src_install() {
	default

	for myprog in $(find src/examples -type f -perm /0111) ; do
		newbin ${myprog} ${PN}-$(basename ${myprog})
		elog "${myprog} installed as ${PN}-$(basename ${myprog})"
	done

	if use bash-completion ; then
		insinto /usr/share/bash-completion
		doins "${ED}"/etc/bash_completion.d/mosh
		rm -rf "${ED}"/etc/bash_completion.d
	fi
}