[gentoo-commits] gentoo-x86 commit in dev-util/monotone: ChangeLog monotone-0.44.ebuild

[Patrick Lauer (patrick)]

patrick     09/06/28 11:41:36

  Modified:             ChangeLog
  Added:                monotone-0.44.ebuild
  Log:
  Bump to 0.44, fixes #270827
  (Portage version: 2.2_rc33/cvs/Linux x86_64)

Revision  Changes    Path
1.61                 dev-util/monotone/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/monotone/ChangeLog?rev=1.61&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/monotone/ChangeLog?rev=1.61&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/monotone/ChangeLog?r1=1.60&r2=1.61

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-util/monotone/ChangeLog,v
retrieving revision 1.60
retrieving revision 1.61
diff -u -r1.60 -r1.61
--- ChangeLog	29 Apr 2009 11:31:56 -0000	1.60
+++ ChangeLog	28 Jun 2009 11:41:36 -0000	1.61
@@ -1,6 +1,11 @@
 # ChangeLog for dev-util/monotone
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/monotone/ChangeLog,v 1.60 2009/04/29 11:31:56 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/monotone/ChangeLog,v 1.61 2009/06/28 11:41:36 patrick Exp $
+
+*monotone-0.44 (28 Jun 2009)
+
+  28 Jun 2009; Patrick Lauer <patrick@g.o> +monotone-0.44.ebuild:
+  Bump to 0.44, fixes #270827
 
   29 Apr 2009; Raúl Porcel <armin76@g.o> monotone-0.43.ebuild:
   Readd ~ia64 wrt #267773



1.1                  dev-util/monotone/monotone-0.44.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/monotone/monotone-0.44.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/monotone/monotone-0.44.ebuild?rev=1.1&content-type=text/plain

Index: monotone-0.44.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/monotone/monotone-0.44.ebuild,v 1.1 2009/06/28 11:41:36 patrick Exp $

inherit elisp-common flag-o-matic bash-completion eutils

DESCRIPTION="Monotone Distributed Version Control System"
HOMEPAGE="http://monotone.ca"
SRC_URI="http://monotone.ca/downloads/${PV}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="1"
KEYWORDS="~amd64 ~ia64 ~ppc ~x86"

IUSE="doc emacs ipv6 nls"

RDEPEND="
	sys-libs/zlib
	emacs? ( virtual/emacs )
	>=dev-libs/libpcre-7.6
	>=dev-libs/botan-1.8.0
	>=dev-db/sqlite-3.3.8
	>=dev-lang/lua-5.1
	net-dns/libidn"

DEPEND="${RDEPEND}
	>=dev-libs/boost-1.33.1
	nls? ( >=sys-devel/gettext-0.11.5 )
	doc? ( sys-apps/texinfo )"

pkg_setup() {
	enewgroup monotone
	enewuser monotone -1 -1 /var/lib/monotone monotone
	if [[ "$(gcc-version)" == "3.3" ]]; then
		die 'requires >=gcc-3.4'
	fi
	# https://bugs.gentoo.org/show_bug.cgi?id=202371#c2
	if ! has userpriv ${FEATURES} && has test ${FEATURES}; then
		ewarn "No test will be performed due to lack of FEATURES=userpriv"
	fi
}

src_compile() {
	# more aggressive optimizations cause trouble with the crypto library
	strip-flags
	append-flags $(test-flags -fno-stack-protector-all -fno-stack-protector)
	append-flags -fno-strict-aliasing -fno-omit-frame-pointer

	econf $(use_enable nls) \
		$(use_enable ipv6) \
		--with-system-pcre || die "configure failed"
	emake || die "Compilation failed"

	if use doc; then
		emake html || die 'html compilation failed'
	fi

	if use emacs; then
		cd contrib
		elisp-compile *.el || die "elisp-compile failed"
	fi
}

src_test() {
	if has userpriv ${FEATURES}; then
		emake check || die "self test failed"
	else
		ewarn 'not tested - requires FEATURES=userpriv'
	fi
}

src_install() {
	emake DESTDIR="${D}" install || die "Installation failed"

	mv "${D}"/usr/share/doc/"${PN}" "${D}"/usr/share/doc/"${PF}"

	dobashcompletion contrib/monotone.bash_completion

	if use doc; then
		dohtml -r html/*
		dohtml -r figures
	fi

	if use emacs; then
		elisp-install ${PN} contrib/*.{el,elc} || die "elisp-install failed"
		elisp-site-file-install "${FILESDIR}"/50${PN}-gentoo.el \
			|| die "elisp-site-file-install failed"
	fi

	dodoc AUTHORS ChangeLog NEWS README* UPGRADE
	docinto contrib
	dodoc contrib/*
	newconfd "${FILESDIR}"/monotone.confd monotone
	newinitd "${FILESDIR}"/${PN}-0.36.initd monotone

	insinto /etc/monotone ;
	newins "${FILESDIR}"/hooks.lua hooks.lua
	newins "${FILESDIR}"/read-permissions read-permissions
	newins "${FILESDIR}"/write-permissions write-permissions

	keepdir /var/lib/monotone/keys/ /var/log/monotone /var/run/monotone
	fowners monotone:monotone /var/lib/monotone /var/lib/monotone/keys/ \
		/var/log/monotone /var/run/monotone
}

pkg_postinst() {
	use emacs && elisp-site-regen
	bash-completion_pkg_postinst

	elog
	elog "For details and instructions to upgrade from previous versions,"
	elog "please read /usr/share/doc/${PF}/UPGRADE.bz2"
	elog
	elog "  1. edit /etc/conf.d/monotone"
	elog "  2. import the first keys to enable access with"
	elog "     env HOME=\${homedir} mtn pubkey me@×××××××.net | /etc/init.d/monotone import"
	elog "     Thereafter, those with write permission can add other keys via"
	elog "     netsync with 'monotone push --key-to-push=IDENT' and then IDENT"
	elog "     can be used in the read-permission and write-permission files."
	elog "  3. adjust permisions in /etc/monotone/read-permissions"
	elog "                      and /etc/monotone/write-permissions"
	elog "  4. start the daemon: /etc/init.d/monotone start"
	elog "  5. make persistent: rc-update add monotone default"
	elog
}

pkg_postrm() {
	use emacs && elisp-site-regen
}