[gentoo-commits] gentoo-x86 commit in sys-kernel/ck-sources: ck-sources-4.0.4-r1.ebuild ChangeLog ck-sources-4.0.4.ebuild

[Ben de Groot (yngwin)]

yngwin      15/05/31 23:27:53

  Modified:             ChangeLog
  Added:                ck-sources-4.0.4-r1.ebuild
  Removed:              ck-sources-4.0.4.ebuild
  Log:
  Add upstream BFS 462 patches (bug #549788)
  
  (Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key 0x4FDF9CFD2FAC514E!)

Revision  Changes    Path
1.251                sys-kernel/ck-sources/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-kernel/ck-sources/ChangeLog?rev=1.251&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-kernel/ck-sources/ChangeLog?rev=1.251&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-kernel/ck-sources/ChangeLog?r1=1.250&r2=1.251

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-kernel/ck-sources/ChangeLog,v
retrieving revision 1.250
retrieving revision 1.251
diff -u -r1.250 -r1.251
--- ChangeLog	24 May 2015 05:04:29 -0000	1.250
+++ ChangeLog	31 May 2015 23:27:53 -0000	1.251
@@ -1,6 +1,13 @@
 # ChangeLog for sys-kernel/ck-sources
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-kernel/ck-sources/ChangeLog,v 1.250 2015/05/24 05:04:29 yngwin Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-kernel/ck-sources/ChangeLog,v 1.251 2015/05/31 23:27:53 yngwin Exp $
+
+*ck-sources-4.0.4-r1 (31 May 2015)
+
+  31 May 2015; Ben de Groot <yngwin@g.o> +ck-sources-4.0.4-r1.ebuild,
+  +files/bfs462-rtmn-fix.patch, +files/bfs462-update_inittask.patch,
+  -ck-sources-4.0.4.ebuild:
+  Add upstream BFS 462 patches (bug #549788)
 
 *ck-sources-3.18.14 (24 May 2015)
 *ck-sources-3.14.43 (24 May 2015)



1.1                  sys-kernel/ck-sources/ck-sources-4.0.4-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-kernel/ck-sources/ck-sources-4.0.4-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-kernel/ck-sources/ck-sources-4.0.4-r1.ebuild?rev=1.1&content-type=text/plain

Index: ck-sources-4.0.4-r1.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-kernel/ck-sources/ck-sources-4.0.4-r1.ebuild,v 1.1 2015/05/31 23:27:53 yngwin Exp $

EAPI="5"
ETYPE="sources"
KEYWORDS="~amd64 ~x86"
IUSE="bfsonly"

HOMEPAGE="http://dev.gentoo.org/~mpagano/genpatches/
	http://users.on.net/~ckolivas/kernel/"

K_WANT_GENPATCHES="base extras experimental"
K_EXP_GENPATCHES_PULL="1"
K_EXP_GENPATCHES_NOUSE="1"
K_GENPATCHES_VER="6"
K_SECURITY_UNSUPPORTED="1"
K_DEBLOB_AVAILABLE="1"

inherit kernel-2
detect_version
detect_arch

K_BRANCH_ID="${KV_MAJOR}.${KV_MINOR}"

DESCRIPTION="Full Linux ${K_BRANCH_ID} kernel sources with Con Kolivas' high performance patchset and Gentoo's genpatches"

#-- If Gentoo-Sources don't follow then extra incremental patches are needed -

XTRA_INCP_MIN=""
XTRA_INCP_MAX=""

#--

CK_VERSION="1"
BFS_VERSION="462"

CK_FILE="patch-${K_BRANCH_ID}-ck${CK_VERSION}.bz2"
BFS_FILE="${K_BRANCH_ID}-sched-bfs-${BFS_VERSION}.patch"

CK_BASE_URL="http://ck.kolivas.org/patches/4.0"
CK_LVER_URL="${CK_BASE_URL}/${K_BRANCH_ID}/${K_BRANCH_ID}-ck${CK_VERSION}"
CK_URI="${CK_LVER_URL}/${CK_FILE}"
BFS_URI="${CK_LVER_URL}/patches/${BFS_FILE}"

#-- Build extra incremental patches list --------------------------------------

LX_INCP_URI=""
LX_INCP_LIST=""
if [ -n "${XTRA_INCP_MIN}" ]; then
	LX_INCP_URL="${KERNEL_BASE_URI}/incr"
	for i in `seq ${XTRA_INCP_MIN} ${XTRA_INCP_MAX}`; do
		LX_INCP[i]="patch-${K_BRANCH_ID}.${i}-$(($i+1)).bz2"
		LX_INCP_URI="${LX_INCP_URI} ${LX_INCP_URL}/${LX_INCP[i]}"
		LX_INCP_LIST="${LX_INCP_LIST} ${DISTDIR}/${LX_INCP[i]}"
	done
fi

#-- CK needs sometimes to patch itself... ---------------------------

CK_INCP_URI=""
CK_INCP_LIST=""

#-- Local patches needed for the ck-patches to apply smoothly -------

PRE_CK_FIX=""
POST_CK_FIX="( ${FILESDIR}/bfs462-rtmn-fix.patch
	${FILESDIR}/bfs462-update_inittask.patch )"

#--

SRC_URI="${KERNEL_URI} ${LX_INCP_URI} ${GENPATCHES_URI} ${ARCH_URI} ${CK_INCP_URI}
	!bfsonly? ( ${CK_URI} )
	bfsonly? ( ${BFS_URI} )"

UNIPATCH_LIST="${LX_INCP_LIST} ${PRE_CK_FIX} ${DISTDIR}"

if ! use bfsonly ; then
	UNIPATCH_LIST="${UNIPATCH_LIST}/${CK_FILE}"
else
	UNIPATCH_LIST="${UNIPATCH_LIST}/${BFS_FILE}"
fi

UNIPATCH_LIST="${UNIPATCH_LIST} ${CK_INCP_LIST} ${POST_CK_FIX}"

UNIPATCH_STRICTORDER="yes"

#-- Since experimental genpatches && we want BFQ irrespective of experimental -

K_EXP_GENPATCHES_LIST="50*_*.patch*"

src_prepare() {

#-- Comment out CK's EXTRAVERSION in Makefile ---------------------------------

	sed -i -e 's/\(^EXTRAVERSION :=.*$\)/# \1/' "${S}/Makefile"
}

pkg_postinst() {

	kernel-2_pkg_postinst

	elog
	elog "For more info on this patchset, see: http://forums.gentoo.org/viewtopic-t-941030-start-0.html"
	elog
}