[gentoo-commits] repo/gentoo:master commit in: dev-util/its4/

[Sam James]

commit:     91d6e8e1eb1da9c52e9023c3889d67a4a687a7b7
Author:     Thomas Bracht Laumann Jespersen <t <AT> laumann <DOT> xyz>
AuthorDate: Thu Feb  3 20:48:44 2022 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sun Feb 20 00:29:50 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=91d6e8e1

dev-util/its4: Avoid calling g++ directly

This revbump accomplishes two things:

 * Bump EAPI=8 from 5. The biggest change is adding eapply_user in
   src_prepare()

 * Use --with-cpp argument for call to ./configure, so the script
   doesn't try to find a compiler

Signed-off-by: Thomas Bracht Laumann Jespersen <t <AT> laumann.xyz>
Closes: https://bugs.gentoo.org/724268
Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Sam James <sam <AT> gentoo.org>

 dev-util/its4/its4-1.1.1-r2.ebuild | 43 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)

diff --git a/dev-util/its4/its4-1.1.1-r2.ebuild b/dev-util/its4/its4-1.1.1-r2.ebuild
new file mode 100644
index 000000000000..5bb0c4ed44fc
--- /dev/null
+++ b/dev-util/its4/its4-1.1.1-r2.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs
+
+DESCRIPTION="ITS4: Software Security Tool"
+HOMEPAGE="http://www.cigital.com/its4/"
+SRC_URI="https://dev.gentoo.org/~robbat2/distfiles/${P}.tgz"
+
+LICENSE="ITS4"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+
+S="${WORKDIR}/${PN}"
+
+src_prepare() {
+	sed -i \
+		-e 's,iostream.h,iostream,g'\
+		"${S}"/configure || die
+	sed -i \
+		-e 's/$(CC) -o/$(CC) $(OPTIMIZATION) $(EXTRA_FLAGS) -o/' \
+		"${S}"/Makefile.in || die
+	eapply_user
+}
+
+src_configure() {
+	# WARNING
+	# non-standard configure
+	# do NOT use econf
+	./configure --with-cpp=$(tc-getCXX) --prefix=/usr --mandir=/usr/share/man --datadir=/usr/share/its4 || die "configure failed"
+}
+
+src_compile() {
+	emake CC="$(tc-getCXX)" OPTIMIZATION="${CXXFLAGS}" EXTRA_FLAGS="${LDFLAGS}"
+}
+
+src_install() {
+	# WARNING
+	# non-standard, do NOT use einstall or 'make install DESTDIR=...'
+	make install INSTALL_BINDIR="${D}/usr/bin" INSTALL_MANDIR="${D}/usr/share/man" INSTALL_DATADIR="${D}/usr/share/its4" || die "install failed"
+}