[gentoo-commits] gentoo-x86 commit in media-video/qdvdauthor: metadata.xml ChangeLog qdvdauthor-1.2.0.ebuild qdvdauthor-1.11.1.ebuild

[Daniel Pielmeier (billie)]

billie      09/09/04 16:34:08

  Modified:             metadata.xml ChangeLog qdvdauthor-1.2.0.ebuild
  Added:                qdvdauthor-1.11.1.ebuild
  Log:
  Version bump. Fixes bugs #255889 and finally #241804. Some small repoman fixes.
  (Portage version: 2.1.6.13/cvs/Linux i686)

Revision  Changes    Path
1.3                  media-video/qdvdauthor/metadata.xml

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/qdvdauthor/metadata.xml?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/qdvdauthor/metadata.xml?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/qdvdauthor/metadata.xml?r1=1.2&r2=1.3

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-video/qdvdauthor/metadata.xml,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- metadata.xml	13 Dec 2005 01:52:14 -0000	1.2
+++ metadata.xml	4 Sep 2009 16:34:07 -0000	1.3
@@ -9,4 +9,12 @@
 	<longdescription lang="en">
 		'Q' DVD-Author is a GUI frontend for dvdauthor written in Qt.
 	</longdescription>
+	<use>
+		<flag name="plugins">
+			Install additional plugins.
+		</flag>
+		<flag name="templates">
+			Install various templates.
+		</flag>
+	</use>
 </pkgmetadata>



1.26                 media-video/qdvdauthor/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/qdvdauthor/ChangeLog?rev=1.26&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/qdvdauthor/ChangeLog?rev=1.26&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/qdvdauthor/ChangeLog?r1=1.25&r2=1.26

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-video/qdvdauthor/ChangeLog,v
retrieving revision 1.25
retrieving revision 1.26
diff -u -r1.25 -r1.26
--- ChangeLog	17 Dec 2008 21:23:36 -0000	1.25
+++ ChangeLog	4 Sep 2009 16:34:07 -0000	1.26
@@ -1,6 +1,13 @@
 # ChangeLog for media-video/qdvdauthor
-# Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/qdvdauthor/ChangeLog,v 1.25 2008/12/17 21:23:36 loki_val Exp $
+# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-video/qdvdauthor/ChangeLog,v 1.26 2009/09/04 16:34:07 billie Exp $
+
+*qdvdauthor-1.11.1 (04 Sep 2009)
+
+  04 Sep 2009; Pielmeier Daniel <billie@g.o> qdvdauthor-1.2.0.ebuild,
+  +qdvdauthor-1.11.1.ebuild, metadata.xml:
+  Version bump. Fixes bugs #255889 and finally #241804. Some small repoman
+  fixes.
 
   17 Dec 2008; Peter Alfredsen <loki_val@g.o>
   -qdvdauthor-1.0.0.ebuild:



1.3                  media-video/qdvdauthor/qdvdauthor-1.2.0.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/qdvdauthor/qdvdauthor-1.2.0.ebuild?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/qdvdauthor/qdvdauthor-1.2.0.ebuild?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/qdvdauthor/qdvdauthor-1.2.0.ebuild?r1=1.2&r2=1.3

Index: qdvdauthor-1.2.0.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-video/qdvdauthor/qdvdauthor-1.2.0.ebuild,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- qdvdauthor-1.2.0.ebuild	27 Jul 2008 21:54:04 -0000	1.2
+++ qdvdauthor-1.2.0.ebuild	4 Sep 2009 16:34:07 -0000	1.3
@@ -1,6 +1,6 @@
-# Copyright 1999-2008 Gentoo Foundation
+# Copyright 1999-2009 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/qdvdauthor/qdvdauthor-1.2.0.ebuild,v 1.2 2008/07/27 21:54:04 carlo Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/qdvdauthor/qdvdauthor-1.2.0.ebuild,v 1.3 2009/09/04 16:34:07 billie Exp $
 
 EAPI=1
 
@@ -94,7 +94,7 @@
 		insinto /usr/share/qdvdauthor/plugins/${i}
 		doins qdvdauthor/plugins/${i}/*.{jpg,png}
 		cp -dp qdvdauthor/plugins/plugins/lib${i}.so* \
-			${D}usr/share/qdvdauthor/plugins/
+			"${D}"usr/share/qdvdauthor/plugins/
 	done
 
 	domenu qdvdauthor.desktop



1.1                  media-video/qdvdauthor/qdvdauthor-1.11.1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/qdvdauthor/qdvdauthor-1.11.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/qdvdauthor/qdvdauthor-1.11.1.ebuild?rev=1.1&content-type=text/plain

Index: qdvdauthor-1.11.1.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-video/qdvdauthor/qdvdauthor-1.11.1.ebuild,v 1.1 2009/09/04 16:34:07 billie Exp $

EAPI=2

inherit eutils flag-o-matic qt4 qt3

DESCRIPTION="'Q' DVD-Author is a GUI frontend for dvdauthor written in Qt"
HOMEPAGE="http://qdvdauthor.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz
		templates? ( mirror://sourceforge/${PN}/${PN}-templates-1.10.0.tar.bz2
					http://${PN}.sourceforge.net/data/masks.tar.bz2 )"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"	# ppc currently disabled because of media-video/dv2sub
IUSE="mplayer +xine plugins cdr templates debug"

DEPEND="media-video/dvdauthor
	media-gfx/jhead
	media-video/ffmpeg
	media-video/mjpegtools
	xine? ( media-libs/xine-lib )
	mplayer? ( media-video/mplayer )
	!xine? ( !mplayer? ( media-libs/xine-lib ) )
	x11-libs/qt:3
	x11-libs/qt-gui:4
	x11-libs/libX11
	templates? ( app-text/convmv )"

RDEPEND="${DEPEND}
	app-cdr/dvdisaster
	media-libs/netpbm
	media-video/dv2sub
	media-video/videotrans
	media-gfx/imagemagick
	media-sound/toolame
	media-sound/lame
	media-sound/sox
	media-sound/vorbis-tools
	cdr? ( || ( virtual/cdrtools app-cdr/dvd+rw-tools ) )"

TEMPLATES="${WORKDIR}"/${PN}-templates-1.10.0

pkg_setup() {
	if ! use xine && ! use mplayer ; then
		eerror "You have to enable at least one of the use flags xine or \
			mplayer"
		die "xine and mplayer flag unset."
	fi
}

src_prepare() {
	sed -i -e 's:backround:background:g' qdvdauthor/qdvdauthor.pro \
		|| die "sed failed"

	mv "${WORKDIR}"/masks ${TEMPLATES}

	# remove spaces in filenames
	local OIFS IFS i
	OIFS=${IFS}; IFS=$'\n'
	for i in $(find ${TEMPLATES} -depth -name '* *') ; do
		mv ${i} $(dirname ${i})/$(basename ${i// /-})
	done
	IFS=${OIFS}

	# fix filename encoding
	convmv --notest -r -f iso-8859-15 -t utf8 ${TEMPLATES}/buttons 1>>/dev/null 2>&1
}

src_configure() {
	if use xine ; then
		export WITH_XINE_SUPPORT=1
	fi

	if use mplayer ; then
		export WITH_MPLAYER_SUPPORT=1
	fi

	export WITH_VLC_SUPPORT=0

	eqmake3 all.pro

	cd "${S}"/qdvdauthor
	eqmake3 qdvdauthor.pro

	cd "${S}"/qdvdauthor/qplayer
	eqmake3 qplayer.pro

	if use plugins ; then
		for i in simpledvd complexdvd menuslide testplugs; do
			cd "${S}"/qdvdauthor/plugins/${i}
			eqmake3 ${i}.pro
		done
	fi

	cd "${S}"/addons/jhead/libjhead
	eqmake3 interface.pro

	cd "${S}"/qrender
	eqmake4 qrender.pro
}

src_compile() {
	cd "${S}"/qdvdauthor
	emake || die "emake failed"

	cd "${S}"/qdvdauthor/qplayer
	emake || die "emake failed"

	if use plugins ; then
		for i in simpledvd complexdvd menuslide testplugs; do
			cd "${S}"/qdvdauthor/plugins/${i}
			emake || die "emake failed"
			eqmake3 ${i}.pro
		done
	fi

	cd "${S}"/addons/jhead/libjhead
	emake || die "emake failed"
	eqmake3 interface.pro -o Makefile.interface

	cd "${S}"/qrender
	emake || die "emake failed"
}

src_install() {
	cd "${S}"/qdvdauthor
	emake INSTALL_ROOT="${D}" install || die "emake install failed"

	cd "${S}"/qdvdauthor/qplayer
	emake INSTALL_ROOT="${D}" install || die "emake install failed"

	if use plugins ; then
		for i in simpledvd complexdvd; do
			cd "${S}"/qdvdauthor/plugins/${i}
			emake INSTALL_ROOT="${D}" install || die "emake install failed"
		done
	fi

	cd "${S}"/addons/jhead/libjhead
	emake INSTALL_ROOT="${D}" -f Makefile.interface install || \
		die "emake install failed"

	cd "${S}"/qrender
	emake INSTALL_ROOT="${D}" install || die "emake install failed"

	cd "${TEMPLATES}"
	if use templates ; then
		insinto /usr/share/qdvdauthor
		doins -r animated buttons masks slideshow static
	fi

	cd "${S}"
	dodoc CHANGELOG README
	domenu qdvdauthor.desktop
	doicon qdvdauthor.png
}