[gentoo-commits] repo/gentoo:master commit in: kde-apps/umbrello/

[Andreas Sturmlechner]

commit:     18e9cef7a33b2344104013a541325c3d52614e1b
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Mon Nov 29 16:03:15 2021 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Mon Nov 29 16:52:29 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=18e9cef7

kde-apps/umbrello: 21.11.90 version bump

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 kde-apps/umbrello/Manifest                 |  1 +
 kde-apps/umbrello/umbrello-21.11.90.ebuild | 75 ++++++++++++++++++++++++++++++
 2 files changed, 76 insertions(+)

diff --git a/kde-apps/umbrello/Manifest b/kde-apps/umbrello/Manifest
index 0bbbe1155fc7..014f3b3625d0 100644
--- a/kde-apps/umbrello/Manifest
+++ b/kde-apps/umbrello/Manifest
@@ -1 +1,2 @@
 DIST umbrello-21.08.3.tar.xz 5650048 BLAKE2B da8d0fd63e7d603a52866e8a91e3aa0d6f4c80f4e95096b4dea4746348ad0cfcde11ec194d4771c6540a6861a206dda371316b12b8f1c69d4853783380d0e92a SHA512 176804977069383aab5e809b2a3e94b2b965d5b57bf14eb8215416a2288d5a141a8bdeabae241b3f08bab498b36b018ac501797f8f61653bf18910302aa61130
+DIST umbrello-21.11.90.tar.xz 5650848 BLAKE2B 2a28e8008bdf5ad5408e7442c6fb93ffa191e119df34efe88089bf7833f10ac01b795e53eebe51f8f50739f50c6dfd2c62ab4e767f3ce2d14dd65d3d50421d29 SHA512 d4ffe83491da8b421488fac69e274ceab673d770630a18e38000aa0ca965f17fd21ebe578274b9c829ce6a615b103aae58c99b3bb3026e6df8d1a3cd0dc13b40

diff --git a/kde-apps/umbrello/umbrello-21.11.90.ebuild b/kde-apps/umbrello/umbrello-21.11.90.ebuild
new file mode 100644
index 000000000000..3965c91a8f82
--- /dev/null
+++ b/kde-apps/umbrello/umbrello-21.11.90.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+ECM_QTHELP="false" # TODO: figure out install error
+ECM_TEST="forceoptional"
+KFMIN=5.88.0
+QTMIN=5.15.2
+VIRTUALX_REQUIRED="test"
+inherit ecm kde.org
+
+DESCRIPTION="KDE UML Modeller"
+HOMEPAGE="https://apps.kde.org/umbrello/ https://umbrello.kde.org"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="php"
+
+RDEPEND="
+	dev-libs/libxml2
+	dev-libs/libxslt
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtprintsupport-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/karchive-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdelibs4support-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kjobwidgets-${KFMIN}:5
+	>=kde-frameworks/ktexteditor-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	php? (
+		dev-util/kdevelop:5=
+		dev-util/kdevelop-pg-qt:5
+		dev-util/kdevelop-php:5
+	)
+"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-20.08.3-no-qtwebkit.patch
+	"${FILESDIR}"/${PN}-20.08.3-gentoo-docbundledir.patch # fix hardcoded path
+)
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_DISABLE_FIND_PACKAGE_Doxygen=ON # broken, re-enable w/ ECM_QTHELP
+		-DCMAKE_DISABLE_FIND_PACKAGE_Qt5WebKitWidgets=ON
+		-DBUILD_APIDOC=OFF
+		-DBUILD_KF5=ON
+		-DBUILD_PHP_IMPORT=$(usex php)
+		-DBUILD_unittests=$(usex test)
+	)
+	use test && mycmakeargs+=(
+		-DCMAKE_DISABLE_FIND_PACKAGE_LLVM=ON
+		-DCMAKE_DISABLE_FIND_PACKAGE_Clang=ON
+		-DCMAKE_DISABLE_FIND_PACKAGE_CLANG=ON
+	)
+
+	ecm_src_configure
+}