[gentoo-commits] gentoo-x86 commit in app-mobilephone/obexftp: ChangeLog obexftp-0.22.ebuild

[Alin Nastac (mrness)]

mrness      08/06/20 23:44:00

  Modified:             ChangeLog
  Added:                obexftp-0.22.ebuild
  Log:
  Version bump. Fix src_install failure on SMP boxes (#225453).
  (Portage version: 2.1.4.4)

Revision  Changes    Path
1.35                 app-mobilephone/obexftp/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-mobilephone/obexftp/ChangeLog?rev=1.35&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-mobilephone/obexftp/ChangeLog?rev=1.35&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-mobilephone/obexftp/ChangeLog?r1=1.34&r2=1.35

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-mobilephone/obexftp/ChangeLog,v
retrieving revision 1.34
retrieving revision 1.35
diff -u -r1.34 -r1.35
--- ChangeLog	1 Jun 2008 10:33:52 -0000	1.34
+++ ChangeLog	20 Jun 2008 23:43:59 -0000	1.35
@@ -1,6 +1,11 @@
 # ChangeLog for app-mobilephone/obexftp
 # Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-mobilephone/obexftp/ChangeLog,v 1.34 2008/06/01 10:33:52 mrness Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-mobilephone/obexftp/ChangeLog,v 1.35 2008/06/20 23:43:59 mrness Exp $
+
+*obexftp-0.22 (20 Jun 2008)
+
+  20 Jun 2008; Alin Năstac <mrness@g.o> +obexftp-0.22.ebuild:
+  Version bump. Fix src_install failure on SMP boxes (#225453).
 
   01 Jun 2008; Alin Năstac <mrness@g.o> obexftp-0.21.ebuild,
   obexftp-0.22_rc9.ebuild:



1.1                  app-mobilephone/obexftp/obexftp-0.22.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-mobilephone/obexftp/obexftp-0.22.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-mobilephone/obexftp/obexftp-0.22.ebuild?rev=1.1&content-type=text/plain

Index: obexftp-0.22.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-mobilephone/obexftp/obexftp-0.22.ebuild,v 1.1 2008/06/20 23:43:59 mrness Exp $

inherit eutils perl-module flag-o-matic python

DESCRIPTION="File transfer over OBEX for mobile phones"
HOMEPAGE="http://dev.zuckschwerdt.org/openobex/wiki/ObexFtp"
SRC_URI="mirror://sourceforge/openobex/${P}.tar.bz2"

SLOT="0"
LICENSE="GPL-2"
KEYWORDS="~amd64 ~hppa ~ppc ~sparc ~x86"
IUSE="bluetooth debug perl python ruby swig tcl"

RDEPEND="dev-libs/openobex
	bluetooth? ( net-wireless/bluez-libs )
	perl? ( dev-lang/perl )
	python? ( >=dev-lang/python-2.4.4 )
	ruby? ( dev-lang/ruby )
	tcl? ( dev-lang/tcl )"
DEPEND="${RDEPEND}
	swig? ( dev-lang/swig )
	dev-util/pkgconfig"

src_compile() {
	# do not byte-compile python module
	if use python; then
		sed -i \
			-e 's/\(setup.py install\)/\1 --no-compile/' \
			swig/python/Makefile.in || die "sed failed"
	fi

	if use debug ; then
		strip-flags
		append-flags "-g -DOBEXFTP_DEBUG=5"
	fi
	if use ruby && ! use bluetooth ; then
		sed -i -e "s/^\(.*bluetooth.*\)$/#\1/" swig/ruby/extconf.rb
	fi

	econf \
		$(use_enable bluetooth) \
		$(use_enable swig) \
		$(use_enable perl) \
		$(use_enable python) \
		$(use_enable tcl) \
		$(use_enable ruby) || die "econf failed"
	emake || die "emake failed"
}

src_install() {
	emake -j1 DESTDIR="${D}" install || die "emake install failed"

	dodoc AUTHORS ChangeLog NEWS README* THANKS TODO
	dohtml doc/*.html

	# Install examples
	insinto /usr/share/doc/${PF}/examples
	doins examples/*.c
	use perl && doins examples/*.pl
	use python && doins examples/*.py
	use ruby && doins examples/*.rb
	use tcl && doins examples/*.tcl

	use perl && fixlocalpod
}

pkg_postrm() {
	use perl && perl-module_pkg_postrm
	use python && python_mod_cleanup
}

pkg_postinst() {
	use perl && perl-module_pkg_postinst
	use python && {
		python_version
		python_mod_optimize /usr/$(get_libdir)/python${PYVER}/site-packages/${PN}
	}
}



-- 
gentoo-commits@l.g.o mailing list