[gentoo-commits] gentoo-x86 commit in media-sound/mpg123: ChangeLog mpg123-1.13.2.ebuild

[Tim Harder (radhermit)]

radhermit    11/02/27 08:29:04

  Modified:             ChangeLog
  Added:                mpg123-1.13.2.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha25/cvs/Linux x86_64)

Revision  Changes    Path
1.236                media-sound/mpg123/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/mpg123/ChangeLog?rev=1.236&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/mpg123/ChangeLog?rev=1.236&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/mpg123/ChangeLog?r1=1.235&r2=1.236

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/mpg123/ChangeLog,v
retrieving revision 1.235
retrieving revision 1.236
diff -u -r1.235 -r1.236
--- ChangeLog	20 Jan 2011 18:57:30 -0000	1.235
+++ ChangeLog	27 Feb 2011 08:29:04 -0000	1.236
@@ -1,6 +1,11 @@
 # ChangeLog for media-sound/mpg123
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/mpg123/ChangeLog,v 1.235 2011/01/20 18:57:30 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/mpg123/ChangeLog,v 1.236 2011/02/27 08:29:04 radhermit Exp $
+
+*mpg123-1.13.2 (27 Feb 2011)
+
+  27 Feb 2011; Tim Harder <radhermit@g.o> +mpg123-1.13.2.ebuild:
+  Version bump.
 
 *mpg123-1.13.1 (20 Jan 2011)
 



1.1                  media-sound/mpg123/mpg123-1.13.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/mpg123/mpg123-1.13.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/mpg123/mpg123-1.13.2.ebuild?rev=1.1&content-type=text/plain

Index: mpg123-1.13.2.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/mpg123/mpg123-1.13.2.ebuild,v 1.1 2011/02/27 08:29:04 radhermit Exp $

EAPI=3
inherit toolchain-funcs libtool

DESCRIPTION="a realtime MPEG 1.0/2.0/2.5 audio player for layers 1, 2 and 3"
HOMEPAGE="http://www.mpg123.org/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2
	http://www.mpg123.org/download/${P}.tar.bz2"

LICENSE="GPL-2 LGPL-2.1"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x86-solaris"
IUSE="3dnow 3dnowext alsa altivec coreaudio ipv6 jack mmx nas oss portaudio pulseaudio sdl sse"

RDEPEND="alsa? ( media-libs/alsa-lib )
	jack? ( media-sound/jack-audio-connection-kit )
	nas? ( media-libs/nas )
	portaudio? ( media-libs/portaudio )
	pulseaudio? ( media-sound/pulseaudio )
	sdl? ( media-libs/libsdl )
	sys-devel/libtool"
DEPEND="${RDEPEND}
	dev-util/pkgconfig"

src_prepare() {
	elibtoolize # for Darwin bundles
}

src_configure() {
	local _audio=dummy
	local _output=dummy
	local _cpu=generic_fpu

	for flag in nas portaudio sdl oss jack alsa pulseaudio coreaudio; do
		if use ${flag}; then
			_audio="${_audio} ${flag/pulseaudio/pulse}"
			_output=${flag/pulseaudio/pulse}
		fi
	done

	use altivec && _cpu=altivec

	if [[ $(tc-arch) == amd64 || ${ARCH} == x64-* ]]; then
		use sse && _cpu=x86-64
	else
		use mmx && _cpu=mmx
		use 3dnow && _cpu=3dnow
		use sse && _cpu=x86
		use 3dnowext && _cpu=x86
	fi

	econf \
		--disable-dependency-tracking \
		--with-optimization=0 \
		--with-audio="${_audio}" \
		--with-default-audio=${_output} \
		--with-cpu=${_cpu} \
		--enable-network \
		$(use_enable ipv6)
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	dodoc AUTHORS ChangeLog NEWS* README
}