[gentoo-commits] repo/gentoo:master commit in: sci-libs/qrupdate/

[Justin Lecher]

commit:     30760ff9f36f69c9959aa8eaed2c8fef6d9a574e
Author:     Justin Lecher <jlec <AT> gentoo <DOT> org>
AuthorDate: Tue Dec 29 09:19:01 2015 +0000
Commit:     Justin Lecher <jlec <AT> gentoo <DOT> org>
CommitDate: Tue Dec 29 10:01:53 2015 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=30760ff9

sci-libs/qrupdate: Bump to EAPI=5

Package-Manager: portage-2.2.26
Signed-off-by: Justin Lecher <jlec <AT> gentoo.org>

 sci-libs/qrupdate/qrupdate-1.1.2-r1.ebuild | 46 ++++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)

diff --git a/sci-libs/qrupdate/qrupdate-1.1.2-r1.ebuild b/sci-libs/qrupdate/qrupdate-1.1.2-r1.ebuild
new file mode 100644
index 0000000..5cf137d
--- /dev/null
+++ b/sci-libs/qrupdate/qrupdate-1.1.2-r1.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit eutils fortran-2 multilib versionator toolchain-funcs
+
+DESCRIPTION="Library for updating of QR and Cholesky decompositions"
+HOMEPAGE="http://sourceforge.net/projects/qrupdate"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~ppc-macos"
+IUSE="static-libs"
+
+RDEPEND="virtual/lapack"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+src_prepare() {
+	epatch \
+		"${FILESDIR}"/${PN}-1.1.1-Makefiles.patch \
+		"${FILESDIR}"/${PN}-1.1.2-install.patch
+	sed -i Makeconf \
+		-e "s:gfortran:$(tc-getFC):g" \
+		-e "s:FFLAGS=.*:FFLAGS=${FFLAGS}:" \
+		-e "s:BLAS=.*:BLAS=$($(tc-getPKG_CONFIG) --libs blas):" \
+		-e "s:LAPACK=.*:LAPACK=$($(tc-getPKG_CONFIG) --libs lapack):" \
+		-e "/^LIBDIR=/a\PREFIX=${EPREFIX}/usr" \
+		-e "s:LIBDIR=lib:LIBDIR=$(get_libdir):" \
+		|| die "Failed to set up Makeconf"
+}
+
+src_compile() {
+	emake solib
+	use static-libs && emake lib
+}
+
+src_install() {
+	emake DESTDIR="${D}" install-shlib
+	dosym libqrupdate.so.$(get_major_version) /usr/$(get_libdir)/libqrupdate.so
+	use static-libs && emake DESTDIR="${D}" install-staticlib
+	dodoc README ChangeLog
+}