[gentoo-commits] repo/gentoo:master commit in: app-arch/zstd/

[Sam James]

commit:     6121cf31cd310cff467f26b6dfcfdd8df6000aa3
Author:     Holger Hoffstätte <holger <AT> applied-asynchrony <DOT> com>
AuthorDate: Sun Sep  4 14:58:25 2022 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sun Sep 25 01:19:54 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=6121cf31

app-arch/zstd: enable threads by default

This follows upstream's default since 1.5.0.

Closes: https://bugs.gentoo.org/868390
Signed-off-by: Holger Hoffstätte <holger <AT> applied-asynchrony.com>
Closes: https://github.com/gentoo/gentoo/pull/27141
Signed-off-by: Sam James <sam <AT> gentoo.org>

 app-arch/zstd/zstd-1.5.2-r3.ebuild | 69 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 69 insertions(+)

diff --git a/app-arch/zstd/zstd-1.5.2-r3.ebuild b/app-arch/zstd/zstd-1.5.2-r3.ebuild
new file mode 100644
index 000000000000..4164ae59fa66
--- /dev/null
+++ b/app-arch/zstd/zstd-1.5.2-r3.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit multilib-minimal toolchain-funcs usr-ldscript
+
+DESCRIPTION="zstd fast compression library"
+HOMEPAGE="https://facebook.github.io/zstd/"
+SRC_URI="https://github.com/facebook/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="|| ( BSD GPL-2 )"
+SLOT="0/1"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="lz4 static-libs"
+
+RDEPEND="
+	app-arch/xz-utils
+	sys-libs/zlib
+	lz4? ( app-arch/lz4 )
+"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	default
+	multilib_copy_sources
+}
+
+mymake() {
+	emake \
+		CC="$(tc-getCC)" \
+		CXX="$(tc-getCXX)" \
+		AR="$(tc-getAR)" \
+		PREFIX="${EPREFIX}/usr" \
+		LIBDIR="${EPREFIX}/usr/$(get_libdir)" \
+		V=1 \
+		"${@}"
+}
+
+multilib_src_compile() {
+	local libzstd_targets=( libzstd{,.a}-mt )
+
+	mymake -C lib ${libzstd_targets[@]} libzstd.pc
+
+	if multilib_is_native_abi ; then
+		mymake HAVE_LZ4="$(usex lz4 1 0)" zstd
+
+		mymake -C contrib/pzstd
+	fi
+}
+
+multilib_src_install() {
+	mymake -C lib DESTDIR="${D}" install
+
+	if multilib_is_native_abi ; then
+		mymake -C programs DESTDIR="${D}" install
+		gen_usr_ldscript -a zstd
+
+		mymake -C contrib/pzstd DESTDIR="${D}" install
+	fi
+}
+
+multilib_src_install_all() {
+	einstalldocs
+
+	if ! use static-libs; then
+		find "${ED}" -name "*.a" -delete || die
+	fi
+}