[gentoo-commits] repo/gentoo:master commit in: sys-apps/flatpak/

[Zac Medico]

commit:     47ec7bcf87397307bd7056b71b03188358bab2ff
Author:     Zac Medico <zmedico <AT> gentoo <DOT> org>
AuthorDate: Sun Oct 10 04:28:43 2021 +0000
Commit:     Zac Medico <zmedico <AT> gentoo <DOT> org>
CommitDate: Sun Oct 10 04:31:29 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=47ec7bcf

sys-apps/flatpak: Re-add stable version 1.10.2

Bug: https://bugs.gentoo.org/816951
Signed-off-by: Zac Medico <zmedico <AT> gentoo.org>

 sys-apps/flatpak/Manifest              |   1 +
 sys-apps/flatpak/flatpak-1.10.2.ebuild | 101 +++++++++++++++++++++++++++++++++
 2 files changed, 102 insertions(+)

diff --git a/sys-apps/flatpak/Manifest b/sys-apps/flatpak/Manifest
index 6a588cd37a0..99756a251bc 100644
--- a/sys-apps/flatpak/Manifest
+++ b/sys-apps/flatpak/Manifest
@@ -1,2 +1,3 @@
+DIST flatpak-1.10.2.tar.xz 1507856 BLAKE2B b19b04d536b43a7bbb7f479e495538137402ff46bee3be5d180d12983c4e69b8726628bb69aea64917163a4722a34987b631a073c94083cae50d79dd7d74db20 SHA512 c932b9aa2803aa5b453917174bf282d82924aca7341d72555e2557fc588ccefa0eaf32b956f75752c17cd8f73b687d4a688ebd64df36680b80b5ff5750468597
 DIST flatpak-1.10.5.tar.xz 1511032 BLAKE2B 704ce0b5828728f1bb438dca2c1cd0b84277547fbb08400fe11abf243f5d9b5a6219c79188b362174f2a61eea42ae548d4279646838f3de3e4e75b8782f3dabe SHA512 8c2e365ce442a092c15178a8b39daecf21bfe162078c9a323e68d53194413f174e329812dd01d8da6bbfba3b0087aeb4d92a44067df3f6fa0253e33014d138ae
 DIST flatpak-1.12.1.tar.xz 1546432 BLAKE2B b7d470526d78ea305b8ef605caa01ddd1aad2f99e2043e7d998d98c37da1ac5f9a7b19c6c164993cabf6f2cac71cee6b6d0eef44dd06487a5298f7451de1d06a SHA512 be0d8eba0d8cdbbdb899a530c4fbb0537b43c22283b6dcb427bc83b414e7ae2a5b176070ab313083cfb33fd281b5ee09c74a5aef9f3c3867d1d85e0c2a424cb1

diff --git a/sys-apps/flatpak/flatpak-1.10.2.ebuild b/sys-apps/flatpak/flatpak-1.10.2.ebuild
new file mode 100644
index 00000000000..62dc9a6edd2
--- /dev/null
+++ b/sys-apps/flatpak/flatpak-1.10.2.ebuild
@@ -0,0 +1,101 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{7,8,9} )
+
+inherit autotools linux-info python-any-r1
+
+SRC_URI="https://github.com/${PN}/${PN}/releases/download/${PV}/${P}.tar.xz"
+DESCRIPTION="Linux application sandboxing and distribution framework"
+HOMEPAGE="https://flatpak.org/"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="amd64 ~arm arm64 ~ppc64 x86"
+IUSE="doc gtk kde introspection policykit seccomp systemd"
+RESTRICT+=" test"
+
+RDEPEND="
+	acct-group/flatpak
+	acct-user/flatpak
+	>=app-arch/libarchive-2.8:=
+	app-arch/zstd:=
+	>=app-crypt/gpgme-1.1.8:=
+	>=dev-libs/appstream-glib-0.5.10:=
+	>=dev-libs/glib-2.56:2=
+	>=dev-libs/libxml2-2.4:=
+	dev-libs/json-glib:=
+	dev-libs/libassuan:=
+	>=dev-util/ostree-2020.8:=[gpg(+)]
+	|| (
+		dev-util/ostree[curl]
+		dev-util/ostree[soup]
+	)
+	>=gnome-base/dconf-0.26:=
+	>=net-libs/libsoup-2.4:=
+	sys-apps/bubblewrap
+	sys-apps/dbus
+	>=sys-fs/fuse-2.9.9:0=
+	sys-apps/xdg-dbus-proxy
+	x11-apps/xauth
+	x11-libs/gdk-pixbuf:2=
+	x11-libs/libXau:=
+	policykit? ( >=sys-auth/polkit-0.98:= )
+	seccomp? ( sys-libs/libseccomp:= )
+	systemd? ( sys-apps/systemd:= )
+"
+
+DEPEND="${RDEPEND}"
+BDEPEND="
+	>=sys-devel/automake-1.13.4
+	>=sys-devel/gettext-0.18.2
+	virtual/pkgconfig
+	dev-util/gdbus-codegen
+	sys-devel/bison
+	introspection? ( >=dev-libs/gobject-introspection-1.40 )
+	doc? (
+		>=dev-util/gtk-doc-1.20
+		dev-libs/libxslt
+	)
+	$(python_gen_any_dep 'dev-python/pyparsing[${PYTHON_USEDEP}]')
+"
+
+PDEPEND="
+	gtk? ( sys-apps/xdg-desktop-portal-gtk )
+	kde? ( kde-plasma/xdg-desktop-portal-kde )
+"
+
+python_check_deps() {
+	has_version -b "dev-python/pyparsing[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	local CONFIG_CHECK="~USER_NS"
+	linux-info_pkg_setup
+	python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+	# This line fails because locales are in /usr/lib/locale/locale-archive.
+	sed -i 's:^cp -r /usr/lib/locale/C.*:#\0:' tests/make-test-runtime.sh || die
+}
+
+src_configure() {
+	local myeconfargs=(
+		--enable-sandboxed-triggers
+		--enable-xauth
+		--localstatedir="${EPREFIX}"/var
+		--with-system-bubblewrap
+		--with-system-dbus-proxy
+		$(use_enable doc documentation)
+		$(use_enable doc gtk-doc)
+		$(use_enable introspection)
+		$(use_enable policykit system-helper)
+		$(use_enable seccomp)
+		$(use_with systemd)
+	)
+
+	econf "${myeconfargs[@]}"
+}