[gentoo-commits] repo/gentoo:master commit in: app-laptop/ibam/

[Sam James]

commit:     53faa2120a65c5048b37d228f353a21b6a5bbe21
Author:     Thomas Bracht Laumann Jespersen <t <AT> laumann <DOT> xyz>
AuthorDate: Tue May  3 10:00:36 2022 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Fri May 13 20:03:41 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=53faa212

app-laptop/ibam: update EAPI 6 -> 8

Closes: https://bugs.gentoo.org/840323
Signed-off-by: Thomas Bracht Laumann Jespersen <t <AT> laumann.xyz>
Closes: https://github.com/gentoo/gentoo/pull/25290
Signed-off-by: Sam James <sam <AT> gentoo.org>

 app-laptop/ibam/ibam-0.5.2-r5.ebuild | 56 ++++++++++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)

diff --git a/app-laptop/ibam/ibam-0.5.2-r5.ebuild b/app-laptop/ibam/ibam-0.5.2-r5.ebuild
new file mode 100644
index 000000000000..e20f619db816
--- /dev/null
+++ b/app-laptop/ibam/ibam-0.5.2-r5.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PATCH_LEVEL="2.1"
+inherit toolchain-funcs optfeature
+
+DESCRIPTION="Intelligent Battery Monitor"
+HOMEPAGE="http://ibam.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz
+	mirror://debian/pool/main/${PN:0:1}/${PN}/${PN}_${PV}-${PATCH_LEVEL}.diff.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="gkrellm"
+
+RDEPEND="
+	gkrellm? (
+		app-admin/gkrellm:2[X]
+		x11-libs/gdk-pixbuf
+		x11-libs/gtk+:2
+	)"
+DEPEND="
+	${RDEPEND}
+	gkrellm? ( virtual/pkgconfig )"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-build.patch
+	"${WORKDIR}"/${PN}_${PV}-${PATCH_LEVEL}.diff
+	"${S}"/debian/patches/02deviation.dpatch
+	"${S}"/debian/patches/03acpi-check.dpatch
+	"${S}"/debian/patches/05_sysfs_lenovo.dpatch
+)
+
+src_compile() {
+	tc-export CXX PKG_CONFIG
+
+	emake
+	use gkrellm && emake krell
+}
+
+src_install() {
+	dobin ibam
+	dodoc CHANGES README REPORT
+
+	if use gkrellm; then
+		insinto /usr/$(get_libdir)/gkrellm2/plugins
+		doins ibam-krell.so
+	fi
+}
+
+pkg_postinst() {
+	optfeature "using the --plot argument" sci-visualization/gnuplot
+}