[gentoo-commits] gentoo-x86 commit in media-sound/amarok: ChangeLog amarok-2.0.2-r3.ebuild

[Jorge Manuel B. S. Vicetto (jmbsvicetto)]

jmbsvicetto    09/04/24 02:50:24

  Modified:             ChangeLog
  Added:                amarok-2.0.2-r3.ebuild
  Log:
   Bumped amarok-2.0.2 to include a lastfm patch. Thanks to Gustavo Henrique Nihei for poking me about it.
  (Portage version: 2.2_rc30/cvs/Linux x86_64)

Revision  Changes    Path
1.321                media-sound/amarok/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/amarok/ChangeLog?rev=1.321&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/amarok/ChangeLog?rev=1.321&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/amarok/ChangeLog?r1=1.320&r2=1.321

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/amarok/ChangeLog,v
retrieving revision 1.320
retrieving revision 1.321
diff -u -r1.320 -r1.321
--- ChangeLog	23 Apr 2009 17:56:51 -0000	1.320
+++ ChangeLog	24 Apr 2009 02:50:23 -0000	1.321
@@ -1,6 +1,13 @@
 # ChangeLog for media-sound/amarok
 # Copyright 2000-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/amarok/ChangeLog,v 1.320 2009/04/23 17:56:51 jmbsvicetto Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/amarok/ChangeLog,v 1.321 2009/04/24 02:50:23 jmbsvicetto Exp $
+
+*amarok-2.0.2-r3 (24 Apr 2009)
+
+  24 Apr 2009; Jorge Manuel B. S. Vicetto <jmbsvicetto@g.o>
+  +files/amarok-2.0.2-lastfm-authentication.patch, +amarok-2.0.2-r3.ebuild:
+  Bumped amarok-2.0.2 to include a lastfm patch. Thanks to Gustavo Henrique
+  Nihei for poking me about it.
 
   23 Apr 2009; Jorge Manuel B. S. Vicetto <jmbsvicetto@g.o>
   -amarok-2.0.1.1.ebuild, -amarok-2.0.2-r1.ebuild:



1.1                  media-sound/amarok/amarok-2.0.2-r3.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/amarok/amarok-2.0.2-r3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/amarok/amarok-2.0.2-r3.ebuild?rev=1.1&content-type=text/plain

Index: amarok-2.0.2-r3.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/amarok/amarok-2.0.2-r3.ebuild,v 1.1 2009/04/24 02:50:23 jmbsvicetto Exp $

EAPI="2"

KDE_LINGUAS="ar be bg ca cs csb da de el eo es et eu fi fr ga gl he is it ja km
	ko ku lt lv nb nds ne nl nn oc pa pl pt pt_BR ro ru se si sk sl sv th tr uk zh_CN zh_TW"
OPENGL_REQUIRED="optional"
inherit flag-o-matic kde4-base

DESCRIPTION="Advanced audio player based on KDE framework."
HOMEPAGE="http://amarok.kde.org/"

LICENSE="GPL-2"
KEYWORDS="~amd64 ~x86"
SLOT="2"
IUSE="cdaudio daap debug ifp ipod mp3tunes mp4 mtp njb +semantic-desktop"
SRC_URI="mirror://kde/stable/${PN}/${PV}/src/${P}.tar.bz2"

# Blocking amarok:0 until the KDE3 eclasses are updated
# to move misc apps to /usr/kde/3.5
DEPEND="
	!media-sound/amarok:0
	!media-sound/amarok-utils
	>=app-misc/strigi-0.5.7
	|| (
		>=dev-db/mysql-5.0.76-r1[embedded,-minimal]
		>=dev-db/mysql-community-5.0.77-r1[embedded,-minimal]
	)
	>=media-libs/taglib-1.5
	>=kde-base/kdelibs-${KDE_MINIMAL}[opengl?,semantic-desktop?]
	>=kde-base/phonon-kde-${KDE_MINIMAL}
	>=kde-base/plasma-workspace-${KDE_MINIMAL}
	x11-libs/qtscriptgenerator
	cdaudio? (
		>=kde-base/libkcompactdisc-${KDE_MINIMAL}
		>=kde-base/libkcddb-${KDE_MINIMAL}
	)
	ifp? ( media-libs/libifp )
	ipod? ( >=media-libs/libgpod-0.7.0 )
	mp3tunes? (
		dev-libs/libxml2
		dev-libs/openssl
		net-libs/loudmouth
		net-misc/curl
	)
	mp4? ( media-libs/libmp4v2 )
	mtp? ( >=media-libs/libmtp-0.3.0 )
	njb? ( >=media-libs/libnjb-2.2.4 )
"

RDEPEND="${DEPEND}
	app-arch/unzip
	daap? ( www-servers/mongrel )"

# lastfm-authentication-patch was taken from upstream bug 188678.
# commit http://websvn.kde.org/?view=rev&revision=949421
PATCHES=( "${FILESDIR}/${PN}-ipod.patch" "${FILESDIR}/${P}-lastfm-authentication.patch" )

src_configure() {
	append-ldflags -L${KDEDIR}/$(get_libdir) -Wl,--as-needed

	if ! use mp3tunes; then
		sed -e'/mp3tunes/ s:^:#DONOTWANT :' \
			-i "${S}"/src/services/CMakeLists.txt \
			|| die "Deactivating mp3tunes failed."
	fi

	# Remove superfluous QT_WEBKIT
	sed -e 's/ -DQT_WEBKIT//g' \
		-i "${S}"/src/scriptengine/generator/generator/CMakeLists.txt \
		|| die "Removing unnecessary -DQT_WEBKIT failed."
	# Remove qtscript-generator
	sed -e 's:add_subdirectory( src/scriptengine/generator )::g' \
		-i "${S}"/CMakeLists.txt \
		|| die "Removing qtscriptgenerator failed."

	mycmakeargs="${mycmakeargs}
		$(cmake-utils_use_with cdaudio KdeMultimedia)
		$(cmake-utils_use_with ipod Ipod)
		$(cmake-utils_use_with ifp Ifp)
		$(cmake-utils_use_with mp4 Mp4v2)
		$(cmake-utils_use_with mtp Mtp)
		$(cmake-utils_use_with njb Njb)
		$(cmake-utils_use_with semantic-desktop Nepomuk)
		$(cmake-utils_use_with semantic-desktop Soprano)"

	kde4-base_src_configure
}